175 replies to this topic

[Chris]

Thanks for clarifying. I'm sure someone could help you do that. If you describe its importance and what you might use it for, that might help attract a volunteer.

[jonny]

I used to actually use this, and my experience was that it was ridiculously easy to remember and use after a few hours. Have you actually tried learning it without visual assistance yet?

[shader]

Great!! The only pros I've encountered are than you cant do Alt hotkeys(to acces menus), they are activated/deactivated at the same time.

[Chris]

if I bind anything more to it (such as for making the left hand keys equal a numpad key and arrow and home keys) then the keys won't work when the modifier is held down. It will work the first time but needs a subsequent depress in order to work again, instead of working when held down the whole time.

Adding the line #InstallKeybdHook to the top of the combined script might fix this, but it's a long shot.

If you can't get it working, I'd probably have to see the complete combined script so that I could experiment with it a little. If you want, you can mail it to <!-- e --><a href="mailto:[email protected]">[email protected]</a><!-- e -->

[Chris]

I used a program called keytweak to change the capslock key to a numpadenter so that my capslock won't activate ever.

The following should also work in case you evern need an alternative that can re-enable your Capslock key without rebooting:

SetCapslockState, AlwaysOff
Capslock::Send {NumpadEnter}

You have to repress all the keys for each key you want to modify, instead of being able to hold down the thumb button and press several keys without having to repress the thumb button each time.

I merged the two scripts and they seem to work without this symptom you described. For example, I can hold down Control+Alt and then type "qwe" and get "poi". However, I'm using the real Ctrl-Alt, not a mouse to simulate it, so maybe there is a difference somehow.

Thanks for posting your scripts, which will hopefully help others with similar goals.

[RG]

I'm still tweaking this script: I remapped the following keys for convenience:

Enter key --> Capslock Key
Backspace --> ` key (backquote)
Home --> CTRL+1
End --> CTRL+2
Delete --> CTRL+3

capslock::
     send,{Return}
     return

`::
     send,{Backspace}
     return

^1::
     send,{Home}
     return

^2::
     send,{End}
     return

^3::
     send,{Del}
     return

Things to do:
#1: I can't decide how to map keys like [ ] - = and \
If you're a programmer or if you use the command line much, these keys are a MUST. But where to put them on the lefthand side?
I suppose ALT+1, ALT+2, etc. might work...
But that means more memorization.

#2: It would be nice to figure out some other key whic was easier to hit than spacebar to flip the keyboard. I like Assistive Tech's idea of a foot switch. But it sounds too hardware-dependent. I also like the idea presented here of holding down mouse button(s) to flip the keyboard.

Overall I love this script. I've been wanting to do something like this for a long time but never got around to it. Thanks for writing a useful piece of code!

My only problem is that if my spacebar is pressed too far on the left side, it sticks and doesn't depress smoothly. I've got a Microsoft (gasp!) Natural Keyboard Pro, so go figure.

Here's the entire script for convenience, with my modifications...

; Autohotkey.com forum: http://autohotkey.com/forum/viewtopic.php?t=1326
; Many thanks to Chris for helping me out with this script.

; Modified by RG


mirror_1 = 0
mirror_2 = 9
mirror_3 = 8
mirror_4 = 7
mirror_5 = 6
mirror_q = p
mirror_w = o
mirror_e = i
mirror_r = u
mirror_t = y
mirror_a = `;
mirror_s = l
mirror_d = k
mirror_f = j
mirror_g = h
mirror_z = /
mirror_x = .
mirror_c = ,
mirror_v = m
mirror_b = n
mirror_6 = 5
mirror_7 = 4
mirror_8 = 3
mirror_9 = 2
mirror_0 = 1
mirror_y = t
mirror_u = r
mirror_i = e
mirror_o = w
mirror_p = q
mirror_h = g
mirror_j = f
mirror_k = d
mirror_l = s
mirror_n = b
mirror_m = v

return


; This key may help, as the space-on-up may get annoying, especially if you type fast.
Control & Space::Suspend

`::
	Send,{Backspace}
	return

Shift & Space::send,{space}
     
space::
	Send {space}
	return


CapsLock::
	Send,{Return}
	return

space & Capslock::
	Send,{'}
	return

space & +Capslock::
	Send,{"}
	return	

^1::
	Send,{home}
	return

^2::
	Send,{end}
	return

^3::
	Send,{Del}
	return


space & 1::
space & 2::
space & 3::
space & 4::
space & 5::
space & q::
space & w::
space & e::
space & r::
space & t::
space & a::
space & s::
space & d::
space & f::
space & g::
space & z::
space & x::
space & c::
space & v::
space & b::
space & `;::
space & ,::
space & .::
space & /::
space & 6::
space & 7::
space & 8::
space & 9::
space & 0::
space & y::
space & u::
space & i::
space & o::
space & p::
space & h::
space & j::
space & k::
space & l::
space & n::
space & m::


; Determine the mirror key, if there is one:
if A_ThisHotkey = space & `;
   MirrorKey = a
else if A_ThisHotkey = space & ,
   MirrorKey = c
else if A_ThisHotkey = space & .
   MirrorKey = x
else if A_ThisHotkey = space & /
   MirrorKey = z
else  ; To avoid runtime errors due to invalid var names, do this part last.
{
   StringRight, ThisKey, A_ThisHotkey, 1
   StringTrimRight, MirrorKey, mirror_%ThisKey%, 0  ; Retrieve "array" element.
   if MirrorKey =  ; No mirror, script probably needs adjustment.
      return
}

Modifiers =
GetKeyState, state1, LWin
GetKeyState, state2, RWin
state = %state1%%state2%
if state <> UU  ; At least one Windows key is down.
   Modifiers = %Modifiers%#
GetKeyState, state1, Control
if state1 = D
   Modifiers = %Modifiers%^
GetKeyState, state1, Alt
if state1 = D
   Modifiers = %Modifiers%!
GetKeyState, state1, Shift
if state1 = D
   Modifiers = %Modifiers%+
Send %Modifiers%{%MirrorKey%}
return

[RG]

Here's a problem. I wanted to map the ' character to Capslock. However, if I enter the following, AHK gives an error "Shift & Capslock is not a valid hotkey name..."

Space & Capslock::send,'
Space & Shift & Capslock::send,"

And if I use the + modifier instead, the ' is never recognized, always " instead:

Space & Capslock::send,'
Space & +Capslock::send,"

the " is always sent, regardless of whether the SHIFT is depressed or not.

:?: :?: :?:

[jonny]

Hotkeys with two or more non-modifiers are not officially supported yet; you would have to add in the last non-modifier(s) using something like KeyWait or GetKeyState.

[Decarlo110]

I also like the idea presented here of holding down mouse button(s) to flip the keyboard.

Solution:

; Autohotkey.com forum: http://autohotkey.com/forum/viewtopic.php?t=1326 
; Many thanks to Chris for helping me out with this script. 

; Modified by RG and Dec

mirror_1 = 0 
mirror_2 = 9 
mirror_3 = 8 
mirror_4 = 7 
mirror_5 = 6 
mirror_q = p 
mirror_w = o 
mirror_e = i 
mirror_r = u 
mirror_t = y 
mirror_a = `; 
mirror_s = l 
mirror_d = k 
mirror_f = j 
mirror_g = h 
mirror_z = / 
mirror_x = . 
mirror_c = , 
mirror_v = m 
mirror_b = n 
mirror_6 = 5 
mirror_7 = 4 
mirror_8 = 3 
mirror_9 = 2 
mirror_0 = 1 
mirror_y = t 
mirror_u = r 
mirror_i = e 
mirror_o = w 
mirror_p = q 
mirror_h = g 
mirror_j = f 
mirror_k = d 
mirror_l = s 
mirror_n = b 
mirror_m = v 

return 


; This key may help, as the space-on-up may get annoying, especially if you type fast. 
Control & Space::Suspend 

`:: 
   Send,{Backspace} 
   return 

Shift & Space::send,{space} 
      
space:: 
   Send {space} 
   return 

CapsLock:: 
   Send,{Return} 
   return 

space & Capslock:: 
   Send '       ; dont use brackets
   return 

+Capslock:: 
   Send "       ; dont use brackets
   return    

^1:: 
   Send,{home} 
   return 

^2:: 
   Send,{end} 
   return 

^3:: 
   Send,{Del} 
   return 

~LButton::       ; substitute with preferred key throughout
   sleep 200      ; necessary to avoid keywait overlap 
   KeyWait, LButton, D t0.4 
   If ErrorLevel=0 
         State0=D2 
   else State0=D1
   KeyWait, LButton
   State0=
   return


1:: 
2:: 
3:: 
4:: 
5:: 
q:: 
w:: 
e:: 
r:: 
t:: 
a:: 
s:: 
d:: 
f:: 
g:: 
z:: 
x:: 
c:: 
v:: 
b:: 
`;:: 
,:: 
.:: 
/:: 
6:: 
7:: 
8:: 
9:: 
0:: 
y:: 
u:: 
i:: 
o:: 
p:: 
h:: 
j:: 
k:: 
l:: 
n:: 
m:: 

if State0=D1       ; this block is for the primary configuration
{
   ; Determine the mirror key, if there is one: 
   if A_ThisHotkey = `;
      MirrorKey = a 
   else if A_ThisHotkey = , 
      MirrorKey = c 
   else if A_ThisHotkey = . 
      MirrorKey = x 
   else if A_ThisHotkey = / 
      MirrorKey = z 
   else  ; To avoid runtime errors due to invalid var names, do this part last. 
   { 
      StringTrimRight, MirrorKey, mirror_%A_ThisHotkey%, 0  ; Retrieve "array" element. 
      if MirrorKey =  ; No mirror, script probably needs adjustment. 
         return 
   } 
}

;else if State0=D2       ; this block is for the secondary configuration
; uncomment this block if assigning a configuration to a double-click-hold
; {
;       [code goes here, parallel to the block above]
; }
; define the MirrorKey2 list for a second keyboard configuration

else return

Modifiers = 
GetKeyState, state1, LWin 
GetKeyState, state2, RWin 
state = %state1%%state2% 
if state <> UU  ; At least one Windows key is down. 
   Modifiers = %Modifiers%# 
GetKeyState, state1, Control 
if state1 = D 
   Modifiers = %Modifiers%^ 
GetKeyState, state1, Alt 
if state1 = D 
   Modifiers = %Modifiers%! 
GetKeyState, state1, Shift 
if state1 = D 
   Modifiers = %Modifiers%+ 
Send %Modifiers%{%MirrorKey%} 
return

I can't decide how to map keys like [ ] - = and \

Using this modified script frees up the spacebar to modify and re-use any keys of your choice. You could also use the double-click secondary keyboard-config feature as well.

[lcamara]

I want to use this with AutoCAD to type notes in our drawings, so I can keep my right hand on the mouse. It looks promising, but I've come across a significant roadblock:

While one of our clients requires mixed-case text, the industry standard (and our standard) is to use all capital letters. Consequently, we draft with the caps lock on.

I commented out the caps lock line, but when I'm using the space-bar to mirror the keys, I'm only getting lower-case letters. I notice that the Caps Lock light is flickering when I type the mirrored keys.

I tried doing it manually, but discovered that the hotkeys aren't case sensitive (when trying to map shift & A to something different than shift & a, I got an error saying it was already defined).

Any help on this would be appreciated.

[Chris]

I don't know for sure if it will solve this case, but try putting the following line near the top of the script:

SetStoreCapslockMode off