precision pixel checker

Press the Arrow keys to move your mouse 1 pixel away from your mouse location to see its pixel color for a more precis pixel checker,Press C key to copy the information to the Clipboard.

ESC to exit the tool.

Picture:

code:

/*

Name: Precision Pixel Checker
Update time: 15/08/2015
Made by: SnowFlake & Xtra
Tested on: Windows 7 64 bit & Vista Home Premium 32-bit
AHK Ver: v1.1.22.03
Link: http://www.autohotkey.com/board/topic/148127-precision-pixel-checker/

Hokeys:
Press the arrow keys to move around.
C to copy.
ESC to exit the tool.
*/

#NoEnv
#SingleInstance force
Precision_Pixel := new PPG
return
;===============Hotkeys=================
UP::
Down::
Right::
Left::Precision_Pixel.Move(A_ThisHotkey)

C::Precision_Pixel.Copy()

Esc::ExitApp
;=======================================

class PPG
{
    __New()
    {
static
Gui, Add, Progress, x0 y0 w38 h38 hwndRGBColor, 100
     this.RGBColor := RGBColor
        Gui, Add, Text, x40 y15 w55 hwndBGRColor
     this.BGRColor := BGRColor
        Gui, Add, Text, x2 y40 w50 hwndXPos
     this.XPos := XPos
        Gui, Add, Text, x2 yp+13 w50 hwndYPos
     this.YPos := YPos 
        Gui, Add, Text, x2 y+15 w600 hwndWindowId
     this.WindowId := WindowId
        Gui, Add, Text, x2 y+10 w100, Press C to Copy
        Gui, +AlwaysOnTop -Caption -border +Disabled +ToolWindow
        Gui, Color, ffffca
            this.init := 0
        ToolTip, Press a Arrow key.,0,0
    }
    Move(d)
    {
this.init := 1
ToolTip
CoordMode, Mouse, Relative
CoordMode, Pixel, Relative
MouseMove, % d="Right" ? 1 : d="Left" ? -1 : 0
   , % d="Up" ? -1 : d="Down" ? 1 : 0,, R
MouseGetPos, x, y
GuiControl,, % this.XPos, % "X : " this.x := x
GuiControl,, % this.YPos, % "Y : " this.y := y
PixelGetColor, BGR, x, y
GuiControl,, % this.BGRColor, % this.BGR := BGR
PixelGetColor, RGB, x, y, RGB
GuiControl, % "+cb" SubStr(RGB,3), % this.RGBColor
WinGetActiveStats, winid, windowW, windowH, windowX, windowY
GuiControl,, % this.WindowId, % this.winid := winid
GuiControl, Move, this.WindowId, % "w" w := StrLen(winid)*5
guiW := (w<90 ? 90 : w) , Dz := 100 ; Deadzone
Gui, Show, % "NoActivate x" (x>windowW/2+Dz ? x-15-guiW : x+15) " y" (y>windowH/2+Dz ? y-135 : y+15) " w" guiW " h120"
    }
    Copy()
    {
if (this.init = 1)
{
     SoundBeep
            Clipboard :=
            Clipboard := "X Coordinates: " this.x "`r`nY Coordinates: " this.y "`r`n  Pixel Color: " this.BGR "`r`n Window Title: " this.winid
            ClipWait, 2
            ToolTip, %Clipboard% `r`n`r`nInfo copied to the clipboard`r`n->> To paste press Ctrl+V <<--
     sleep 5000
            ExitApp
}
     ToolTip, ---------->          Press a Arrow key!         <-----------,0,0
    }
}

Sign In