11 replies to this topic

[engunneer]

This is an extremelly common question. What search terms did you use?

you need on ly a slight variation on the code from this recent thread: <!-- m -->http://www.autohotke... ... light=loop<!-- m -->

Loop, 
{
if (BreakLoop = 1)
  break 
;rest of loop code

}

elsewhere

Esc::
BreakLoop = 1
return

This will break on Escape key.


Also search for the word Suspend, it may help you.

[ScottEdge]

For future reference I found I had to put a sleep in my loop for this to work.

LOOP
{
if (BreakLoop = 1) 
  break 
SEND,{END}
SEND,{SPACE}
SEND,{DOWN}
}

Esc would not break this loop.

LOOP
{
if (BreakLoop = 1) 
  break 
SEND,{END}
SEND,{SPACE}
SEND,{DOWN}
sleep,100
}

Escape would break this loop

[tic]

I dont think thats what he actually asked (even though he appears to have gone now).

I would like to execute a loop infinitely, but I would like this loop to stop as soon as a key (any random key) is pressed.

so he wants a loop to break on any key being pressed, not esc.

I think he meant something like this:

#Persistent
SetBatchLines, -1
SetKeyDelay, -1
OnExit, HandleExit

SetFormat, Integer, Hex

ThreadID := DllCall("GetCurrentThreadId")
VarSetCapacity(State, 256)
SetTimer, MonitorKeyboard, 30

Loop
{
   Sleep, 100
   If BreakLoop
   Break
   Tooltip, We are in the loop
}
Tooltip, The loop has been broken by a keypress
Return

;################################################################################

MonitorKeyboard:
TID := DllCall("GetWindowThreadProcessId", "UInt", WinActive("A"), "UInt", 0)

If (TID != TIDOld)
{
   DllCall("AttachThreadInput", "UInt", ThreadID, "UInt", TIDOld, "Int", 0)
   DllCall("AttachThreadInput", "UInt", ThreadID, "UInt", TID, "Int", 1)
   TIDOld := TID
}
DllCall("GetKeyboardState", "UInt", &State)

State := ""
Loop, 254
{
	If (*(&State+A_Index) & 0x80)
	State := A_Index
}

If State
{
   If State not in 0x1,0x2,0x4
   BreakLoop = 1
}
Return

;################################################################################

HandleExit:
DllCall("AttachThreadInput", "UInt", ThreadID, "UInt", TIDOld, "Int", 0)
ExitApp

so run that and the tooltip will inform you that youre in a loop, and when you press any key itll break. have only specified that left/right/middleclick on mouse dont break the loop. any other mouse buttons would need to be added

Edit: Maybe he didnt mean that :wink: i hate it when people ask something and then just leave, and dont even say thank you or "that worked" or "that didnt work" !

[kenn]

Thank you Tariq, your posts still help people.

[torp]

Loop, 
{
if (BreakLoop = 1)
  break 
;rest of loop code

}

elsewhere

Esc::
BreakLoop = 1
return

This will break on Escape key.

Hmmm... This is what I want to do but the code snippet does not seem to work. What would a working example look like? I've tried this (starting with your example):

Esc::
BreakLoop = 1 
return

Loop,
{
  if (BreakLoop = 1)
    break
  MsgBox Hello
  Sleep 1000
}

Exit

What I want is to see the MsgBox come up once per iteration of the loop, but, if I hit the hotkey (Esc), then the program will exit.

My observation is that the loop never runs...

It seems like defining the hotkey stops all execution of the script. Even this simpler script never shows the messsage box:

Esc::return
MsgBox Hello

Thanks for helping me understand this...

[girlgamer]

The first hotkey or hotstring definition is the presumptive end of the autoexecute section of the script. assuming, of course, that a return is not encountered first. What that basically means is that once you define a hotkey in your script every command after that has to either be a) part of the autoexecute section, in a hotkey/hotstring definition, c) inside a function, d) in a named subroutine, or e) be an AutoHotkey system command (usually starting with a #) or it will not be executed. Anything outside those structures is considered "orphan" code.

[MasterFocus]

Just like girlgamer said:
The Top of the Script (the Auto-execute Section) - <!-- m -->http://www.autohotke...cripts.htm#auto<!-- m -->

[engunneer]

i would go one of a few ways with your script. You are technically calling the loop label every millisecond, and each loop label also has an infinite loop inside.

In the first version we remove settimer, since the loop will loop itself

MyState = 0 ; initial state

Gosub, Loop

Esc::BreakLoop=1

F1::MyState=1
F2::MyState=2

Loop:
Loop {
  if ( BreakLoop = 1 )
    exitApp
  MsgBox % MyState
  Sleep 1000
}
Return

or you can use settimer to set the action into motion every second. This is different in that the previous version has a 1 second delay between when you cliock ok in a box and the next one pops up. This version instead pops up a msgbox every second.

MyState = 0 ; initial state

SetTimer, Loop, 1000   ;Call loop every 1000 ms

Esc::BreakLoop=1

F1::MyState=1
F2::MyState=2

Loop:
  if ( BreakLoop = 1 )
    exitApp
  MsgBox % MyState
Return

If you start your loop before you define hotkeys, you don't need any acrobatics

MyState = 0 ; initial state

Loop {
  if ( BreakLoop = 1 )
    exitApp
  MsgBox % MyState
  Sleep 1000
}
Return   ;End of auto-execute section

Esc::BreakLoop=1

F1::MyState=1
F2::MyState=2

I would usually say that exitapp is not a nice way to break a loop, but if you want the script to close, that will certainly do it. I also would use Tooltip instead of Msgbox when called in a loop to reduce clicking OK buttons

MyState = 0 ; initial state

Loop {
  Tooltip % MyState
  Sleep 1000
}
Return

Esc::ExitApp

F1::MyState=1
F2::MyState=2

and this reduces down to this basic version with settimer

MyState = 0 ; initial state
SetTimer, ShowMyState, 1000
Return

ShowMyState:
  Tooltip % MyState
Return

Esc::ExitApp

F1::MyState=1
F2::MyState=2

Hope this illustrates some different ideas for you.