25 replies to this topic

[Learning one]

Not perfect, high CPU usage, but saves your eyes health. I wanted simplicity (no magnifiers, etc.), just invert colors.
Based on Sean's and Wingfat's scripts. Thank you guys!
Obsolete for Win7 users --> there is a built in Color inversion function in magnifier.

Default Hotkeys:
F9 toggles Invert screen colors
Escape ExitApp

/*===Description=========================================================================

Invert screen colors

Put together by Learning one
Based on Sean's and Wingfat's scripts
Sean: http://www.autohotkey.com/forum/topic18167.html
Wingfat: http://www.autohotkey.com/forum/topic49265.html
Thanks: Sean, Wingfat

Not perfect, high CPU usage, but saves your eyes health.
Obsolete for Win7 users --> there is a built in Color inversion function in magnifier
*/


;===Settings============================================================================
Hotkey = F9				; toggles Invert screen colors
RepaintPeriod = 80		; repaint screen period (don't set it too low! --> heavy CPU load)

 
;===Auto-execute continuation===========================================================
#SingleInstance ignore
OnExit ExitSub
Gui, +AlwaysOnTop +ToolWindow +E0x00000020 
Gui, color, black
Gui, Show, na X0 Y0 W%A_ScreenWidth% H%A_ScreenHeight%, InvertScreenColors
WinSet, Transparent, 255, InvertScreenColors
Gui, -Caption

WinGet, PrintSourceID, id
hdd_frame := DllCall("GetDC", UInt, PrintSourceID)
WinGet, PrintScreenID,  id, InvertScreenColors
hdc_frame := DllCall("GetDC", UInt, PrintScreenID)
DllCall("gdi32.dll\SetStretchBltMode", "uint", hdc_frame, "int", 4)
SetTimer, Repaint, %RepaintPeriod%
Hotkey, %Hotkey%, ISC
Return      ;===Auto-execute ends here===


;===Subroutines=========================================================================
Repaint:
DllCall("gdi32.dll\StretchBlt", UInt, hdc_frame, Int, 0, Int, 0, Int, A_ScreenWidth, Int, A_ScreenHeight, UInt, hdd_frame, Int, 0, Int, 0, Int, A_ScreenWidth, Int, A_ScreenHeight, UInt, 0x330008) 
Return

ISC:
ISC ++
if ISC = 1
{
	SetTimer, Repaint, off
	Gui, hide
}
Else
{
	SetTimer, Repaint, %RepaintPeriod%
	Gui, show, na
	ISC = 0
}
Return

ExitSub:
DllCall("gdi32.dll\DeleteDC", UInt, hdc_frame)
DllCall("gdi32.dll\DeleteDC", UInt, hdd_frame)
ExitApp

;===Exit Hotkey==========================================================================
Escape::ExitApp

[HotKeyIt]

That is quite nice, thank you
Can you make it work for all monitors?

[Learning one]

Thanks. Unfortunately, I don't have any experience with multiple monitors.

[TheGood]

Obsolete for Win7 users --> there is a built in Color inversion function in magnifier.

Isn't there also one in Windows XP's Magnifier?

[Learning one]

Yes, but Windows XP's Magnifier can't show full screen inverted - half is the maximum. Win7 Magnifier can show full screen inverted.
You can also press alt + shift + print screen to switch to high contrast display, but this looks bad (for my taste)

I'm still on Win XP. I hope I'll upgrade to Win7 soon.

[berban]

This is really really nice!! although as you mentioned, autohotkey.exe using 17% of system resources... not a usual occurrence haha

[Learning one]

@lastnikita: I'm on Win XP SP3, using this script daily, and it works fine for me...

[Learning one]

I have no idea so I can't help you

[automaticman]

Not perfect, high CPU usage

Same with low CPU usage would be just perfect! Is this possible somehow in Windows XP, even without ahk, maybe some other external tool? The idea is simple and great already.

[x79animal]

Obsolete for Win7 users --> there is a built in Color inversion function in magnifier.

This is true, however having the window open is always an annoyance.(and i would like to add it to my autohotkey master script)

do you know of any way to run it with inversion and then hide it?

such as

Run, Magnifier.exe -inverted
WinWait, Magnifier
WinHide

does anyone know what the parameter is to run it through? to get inverted

[x79animal]

repost~? ok i found it out, this works

Run, Magnify.exe -invert
WinWait, Magnifier
WinHide

:D