18 replies to this topic

[deanhill1971]

Maybe someone has already created a function like the following, but it's hard to meaningfully search the forum for "run", "switch", etc.

The following function will run a program or switch to it if already running. It shows a tray tip showing whether a run or switch is being done.

Also listed are examples where I've defined a bunch of Windows+Letter keys to open my favorite programs. So I just hit Win+T to always get to Total Commander. I think it is very handy.

; ===========================================================================
; Run a program or switch to it if already running.
;    Target - Program to run. E.g. Calc.exe or C:\Progs\Bobo.exe
;    WinTitle - Optional title of the window to activate.  Programs like
;       MS Outlook might have multiple windows open (main window and email
;       windows).  This parm allows activating a specific window.
; ===========================================================================
RunOrActivate(Target, WinTitle = "")
{
	; Get the filename without a path
	SplitPath, Target, TargetNameOnly

	Process, Exist, %TargetNameOnly%
	If ErrorLevel > 0
		PID = %ErrorLevel%
	Else
		Run, %Target%, , , PID

	; At least one app (Seapine TestTrack wouldn't always become the active
	; window after using Run), so we always force a window activate.
	; Activate by title if given, otherwise use PID.
	If WinTitle <> 
	{
		SetTitleMatchMode, 2
		WinWait, %WinTitle%, , 3
		TrayTip, , Activating Window Title "%WinTitle%" (%TargetNameOnly%)
		WinActivate, %WinTitle%
	}
	Else
	{
		WinWait, ahk_pid %PID%, , 3
		TrayTip, , Activating PID %PID% (%TargetNameOnly%)
		WinActivate, ahk_pid %PID%
	}


	SetTimer, RunOrActivateTrayTipOff, 1500
}

; Turn off the tray tip
RunOrActivateTrayTipOff:
	SetTimer, RunOrActivateTrayTipOff, off
	TrayTip
Return




; Example uses...
#b::RunOrActivate("C:\Program Files\Seapine\TestTrack Pro\TestTrack Pro Client.exe")
#c::RunOrActivate("control panel")
#d::RunOrActivate("cmd.exe")
#g::RunOrActivate("regedit.exe")
#i::Run, iexplore.exe
#n::RunOrActivate("uedit32.exe")

; Outlook can have multiple child windows, so specify which window to activate
#o::RunOrActivate("C:\Program Files\Microsoft Office\OFFICE11\OUTLOOK.EXE", "Microsoft Outlook")

#p::RunOrActivate("C:\Program Files\Perforce\P4Win.exe")
#q::RunOrActivate("C:\Program Files\Microsoft Visual Studio\COMMON\MSDev98\Bin\MSDEV.EXE", "Microsoft Visual")
#t::RunOrActivate("C:\Program Files\totalcmd\totalcmd.exe")
#y::RunOrActivate("wmplayer.exe")
#-::RunOrActivate("mspaint.exe")
#=::RunOrActivate("calc.exe")

[ahoover]

This is a great script. I ran into one little problem when I wanted to run or activate a specific file that is open. For example, when I am editing the Autohotkey.ahk file, and other scripts in notepad, I had trouble getting it to go to the correct script I wanted. So, I added another optional input variable for the parameters to open.

; ===========================================================================
; Run a program or switch to it if already running.
;    Target - Program to run. E.g. Calc.exe or C:\Progs\Bobo.exe
;    WinTitle - Optional title of the window to activate.  Programs like
;    MS Outlook might have multiple windows open (main window and email
;    windows).  This parm allows activating a specific window.
; ===========================================================================

RunOrActivate(Target, WinTitle = "", Parameters = "")
{
   ; Get the filename without a path
   SplitPath, Target, TargetNameOnly

   Process, Exist, %TargetNameOnly%
   If ErrorLevel > 0
      PID = %ErrorLevel%
   Else
      Run, %Target% "%Parameters%", , , PID

   ; At least one app (Seapine TestTrack wouldn't always become the active
   ; window after using Run), so we always force a window activate.
   ; Activate by title if given, otherwise use PID.
   If WinTitle <> 
   {
      SetTitleMatchMode, 2
      WinWait, %WinTitle%, , 3
      TrayTip, , Activating Window Title "%WinTitle%" (%TargetNameOnly%)
      WinActivate, %WinTitle%
   }
   Else
   {
      WinWait, ahk_pid %PID%, , 3
      TrayTip, , Activating PID %PID% (%TargetNameOnly%)
      WinActivate, ahk_pid %PID%
   }


   SetTimer, RunOrActivateTrayTipOff, 1
}

; Turn off the tray tip
RunOrActivateTrayTipOff:
   SetTimer, RunOrActivateTrayTipOff, off
   TrayTip
Return

;example to run or activate the specific script, "Autohotkey"
^!+a::RunorActivate("notepad.exe", "AutoHotkey", "C:\Documents and Settings\ahoover.autotool\My Documents\AutoHotkey.ahk")

[Laszlo]

You don't have to turn off TrayTip: it disappears by itself at most after 30 sec.

[s.newave]

Really great script although i am trying to add a feature whereby if the the window is active and focused and the hotkey is pressed again then another instance of that target is launched. For example sometimes i prefer to launch another firefox browser window instead of using the same one so i would hit the hotkey to activate/launch firefox and then hit it again to launch a second window etc.. Should be very simple although with ahk and cant get this to work:

; ===========================================================================
; Run a program or switch to it if already running.
;    Target - Program to run. E.g. Calc.exe or C:\Progs\Bobo.exe
;    WinTitle - Optional title of the window to activate.  Programs like
;    MS Outlook might have multiple windows open (main window and email
;    windows).  This parm allows activating a specific window.
; ===========================================================================

RunOrActivate(Target, WinTitle = "", Parameters = "")
{
   ; Get the filename without a path
   SplitPath, Target, TargetNameOnly
	 
    IfWinActive, %WinTitle%
     {
     Run %Target%
     Return
     }
	 
   Process, Exist, %TargetNameOnly%
   If ErrorLevel > 0
      PID = %ErrorLevel%
   Else
      Run, %Target% "%Parameters%", , , PID

   ; At least one app (Seapine TestTrack wouldn't always become the active
   ; window after using Run), so we always force a window activate.
   ; Activate by title if given, otherwise use PID.
   If WinTitle <>
   {
      SetTitleMatchMode, 2
      WinWait, %WinTitle%, , 3
      ;TrayTip, , Activating Window Title "%WinTitle%" (%TargetNameOnly%)
      WinActivate, %WinTitle%
   }
   Else
   {
      WinWait, ahk_pid %PID%, , 3
      ;TrayTip, , Activating PID %PID% (%TargetNameOnly%)
      WinActivate, ahk_pid %PID%
   }


   ;SetTimer, RunOrActivateTrayTipOff, 1
}

; Turn off the tray tip
RunOrActivateTrayTipOff:
   SetTimer, RunOrActivateTrayTipOff, off
   TrayTip
Return

;example to run or activate the specific script, "Autohotkey"
;^!+a::RunorActivate("notepad.exe", "AutoHotkey", "C:\Documents and Settings\ahoover.autotool\My Documents\AutoHotkey.ahk")
#;::RunOrActivate("C:\Program Files\Mozilla Firefox\firefox.exe", "Mozilla Firefox", "")

Any ideas?

[greynite]

SetTitleMatchMode, 2

is your bugaboo. It's set down in line 15 or so -- set it instead before your IfWinActive

Cheers,
Shawn

[s.newave]

That was it. Thx!!

[sanitizer]

hi, i want to launch "my document" so i want to put like:

runoractivate(%A_MyDocuments%)

but it gives me error

Run, %Target% "Parameters%",,,PID

I don't want to use the long path because I thought on using on another computer.

Thanks

[sanitizer]

nah nervermind...

i used

Run %A_MyDocuments%

instead.

[Meetloaf]

I want to thank you for this GEM! It is especially useful when running older applications.

For me, it's MoffSoftCalculator, kept throwing me an error about an instance already running. I said to myself...I wonder if there's an AHK remedy for that?

...voila

Thanks again!

[comvox]

I would like a modified version of this script that will switch between multiple open instances if the hotkey is pressed again. For example, suppose you have 2 firefox instances open. Pressing the hotkey once will switch to one of the instances, and pressing it again will switch to the next one. Does this exist, or is there an easy way to modify this script to do it?

The WinActivateBottom command is made to order for this. It is described as

Same as WinActivate except that it activates the bottommost (least recently active) matching window rather than the topmost.

See http://www.autohotke...ivateBottom.htm.

For example, if you want to rotate between several different instances of wordpad, one could have something like the following somewhere in one's script (use the hotkey you want)

^!x::
If Instr(Title,"WordPad")>0
      WinActivateBottom, WordPad
Return

This type of thing could be integrated with the other code. One could have something like the following:

SetTitleMatchMode,2
^!x::
WinGetActiveTitle, Title

If Instr(Title,"WordPad")>0
      WinActivateBottom, WordPad
Else
      RunOrActivate("WordPad.exe","WordPad")
Return

; Then the coding for the RunOrActivate function, taken from the earlier postings.

RunOrActivate(Target, WinTitle = "") 
{ 
   ; Get the filename without a path 
   SplitPath, Target, TargetNameOnly 

   Process, Exist, %TargetNameOnly% 
   If ErrorLevel > 0 
      PID = %ErrorLevel% 
   Else 
      Run, %Target%, , , PID 

   ; At least one app (Seapine TestTrack wouldn't always become the active 
   ; window after using Run), so we always force a window activate. 
   ; Activate by title if given, otherwise use PID. 
   If WinTitle <> 
   { 
      SetTitleMatchMode, 2 
      WinWait, %WinTitle%, , 3 
      TrayTip, , Activating Window Title "%WinTitle%" (%TargetNameOnly%) 
      WinActivate, %WinTitle% 
   } 
   Else 
   { 
      WinWait, ahk_pid %PID%, , 3 
      TrayTip, , Activating PID %PID% (%TargetNameOnly%) 
      WinActivate, ahk_pid %PID% 
   } 


   SetTimer, RunOrActivateTrayTipOff, 1500 
} 

; Turn off the tray tip 
RunOrActivateTrayTipOff: 
   SetTimer, RunOrActivateTrayTipOff, off 
   TrayTip 
Return