40 replies to this topic

[Lexikos]

AutoHotkey v1.1.10-alpha4 is now available for testing.
 
Download - includes ANSI, Unicode and x64 exe files.
Source
 
SoundSet/SoundGet
 
These commands now have improved support Windows Vista and later.  As a result, any scripts which already used them on Vista or later may not work the same way or at all.  The syntax is the same as before, but device numbering and component support differs.
 
Each device returned by the audio API gets a different number.  Since the audio architecture on Vista and later is very different to earlier versions of Windows, the device numbering for SoundSet/SoundGet is also different.  Windows may report a separate device for each output or input connector on a physical device (e.g. Speakers, Line In, Microphone, Stereo Mix, etc.).  On Vista and later DeviceNumber defaults to the default playback device, not necessarily device 1.
 
Currently only Volume and Mute controls are supported.  Other control types are supported by Windows, but very few are supported by the sound devices I have at hand - I suspect that those other control types would be very rarely available.
 
As an alternative to the old sound card analysis script, I have written a script which lists all devices, showing the device name and number, and all component and control types it supports.  Volume and Mute can also be adjusted using the Gui (one at a time).  The Endpoint and Adapter names should match up to what you see in the Sound control panel.
 
soundcard.ahk
 
Requires:

• AutoHotkey v1.1.10-alpha1+
• Windows Vista or later
• VA.ahk version 2.2 (which I've just uploaded)

Custom Gui Controls
 
This release includes support for custom Gui controls, by specifying the window class of the control.  For more details see here or ask fincs.
 
 
Documentation
 
...has been updated.  See SoundGet and SoundSet or Custom control.

[Coco]

Cool. Does it mean I can add toolbars, rebars, etc. w/o requiring any external lib? How does it handle events? gLabel? Thanks btw..

[just me]

Played around a bit:

 

• SoundSet/SoundGet work flawlessly on WinVista 32-bit.
   
• Custom Gui Controls seem to work as well, at least for the Scintilla control.

 

Something to play with:

 

Spoiler

#NoEnv
SetBatchLines, -1
SetWorkingDir, %A_ScriptDir%
; Download: http://www.scintilla.org/ScintillaDownload.html
; SciLexer.dll is assumed to be in the script's folder '
DllCall("Kernel32.dll\LoadLibrary", "Str", "SciLexer.dll")
; ----------------------------------------------------------------------------------------------------------------------
BoolLineNumbers := False
Menu, File, Add, Quit, GuiClose
Menu, Settings, Add, Show Line Numbers, ShowLineNumbers
Menu, MenuBar, Add, &File, :File
Menu, MenuBar, Add, &Settings, :Settings
; ----------------------------------------------------------------------------------------------------------------------
Gui, Margin, 20, 20
Gui, Menu, MenuBar
Gui, Font, , Courier New
Gui, Add, Custom, ClassScintilla w600 r20 HwndHSC vSC gSubSCI +E0x20000 ; creates a Scintilla control
Gui, Show, , Custom Scintilla Control
SCI_SetFont(HSC, "Courier New")
Return
; ----------------------------------------------------------------------------------------------------------------------
GuiClose:
ExitApp
; ----------------------------------------------------------------------------------------------------------------------
ShowLineNumbers:
   Menu, %A_ThisMenu%, ToggleCheck, %A_ThisMenuItem%
   SCI_SetLineNumbers(HSC, ((BoolLineNumbers ^= 1) ? "_9999" : ""))
Return
; ----------------------------------------------------------------------------------------------------------------------
SubSCI:
   ; ToolTip, % A_GuiEvent . " - " . (A_GuiEvent == "N" ? NumGet(A_EventInfo, A_PtrSize * 2, "Int") : A_EventInfo)
Return
; ======================================================================================================================
; SCI Functions ========================================================================================================
; ======================================================================================================================
SCI_SetFont(HSCI, FontName, Size := 9) {
   SCI_STYLESETFONT(HSCI, 32, FontName)
   SCI_STYLESETSIZE(HSCI, 32, Size)
}
; ----------------------------------------------------------------------------------------------------------------------
SCI_SetLineNumbers(HSCI, NumStr := "_99999") {
   Return SCI_SETMARGINWIDTHN(HSCI, 0, StrLen(NumStr) ? SCI_TEXTWIDTH(HSCI, 33, NumStr) : 0)
}
; ======================================================================================================================
; SCI Messages =========================================================================================================
; ======================================================================================================================
SCI_STYLESETFONT(HSCI, StyleIndex, FontName) {
   ; SCI_STYLESETFONT = 2056
   Return DllCall("User32.dll\SendMessageA", "Ptr", HSCI, "Int", 2056, "Ptr", StyleIndex, "AStr", FontName, "Int")
}
; ----------------------------------------------------------------------------------------------------------------------
SCI_STYLESETSIZE(HSCI, StyleIndex, Size) {
   ; SCI_STYLESETSIZE = 2055
   Return DllCall("User32.dll\SendMessage", "Ptr", HSCI, "Int", 2055, "Ptr", StyleIndex, "Int", Size, "Int")
}
; ----------------------------------------------------------------------------------------------------------------------
SCI_SETMARGINWIDTHN(HSCI, MarginIndex, Width) {
   ; SCI_SETMARGINWIDTHN = 2242
   Return DllCall("User32.dll\SendMessage", "Ptr", HSCI, "Int", 2242, "Ptr", MarginIndex, "Ptr", Width, "Int")
}
; ----------------------------------------------------------------------------------------------------------------------
SCI_TEXTWIDTH(HSCI, StyleIndex, String) {
   ; SCI_TEXTWIDTH = 2276
   Return DllCall("User32.dll\SendMessageA", "Ptr", HSCI, "Int", 2276, "Ptr", StyleIndex, "AStr", String, "Int")
}

 

 

Edit: Forgot to say: Thanks! 

[Coco]

Here's my take on ComboBoxEx:

 

Spoiler

Gui, Add, Custom, classComboBoxEx32 HwndhCBoxEx 0x0002 ; CBS_DROPDOWN = 0x0002

hIL := IL_Create()
Loop, 12
	IL_Add(hIL, "imageres.dll" , A_Index+4)

SetImageList(hCBoxEx, hIL)
for a, b in ["January", "February", "March", "April", "May", "June", "July", "August", "September", "October", "November", "December"]
	InsertItem(hCBoxEx, b, a, a, a)
SetCurSel(hCBoxEx, "January", false)

Gui, Show
return

GuiClose:
ExitApp

SetImageList(hwnd, hIL) {
	static CBEM_SETIMAGELIST := 0x0402

	SendMessage, % CBEM_SETIMAGELIST, 0, hIL,, % "ahk_id " hwnd
	return ErrorLevel
}

InsertItem(hwnd, text, pos:="", IconNormal:="", IconSel:="") {
	static CBEM_INSERTITEMW := 0x040B , CBEM_INSERTITEMA := 0x0401
	
	pos :=  pos ? pos-1 : GetCount(hwnd) ; Append to last if pos is not specified | Zero-based index
	, IconNormal := IconNormal <> "" ? IconNormal-1 : IconNormal
	, IconSel := IconSel <> "" ? IconSel-1 : IconSel
	, cchTextMax := false ; If text information is being set, this member is ignored.
	, iOverlay := 1
	
	; SET STRUCTURE
	CBEI_STRUCT(COMBOBOXEXITEM, text, cchTextMax, pos, IconNormal, IconSel, iOverlay)
	
	SendMessage, % A_IsUnicode ? CBEM_INSERTITEMW : CBEM_INSERTITEMA, 0, &COMBOBOXEXITEM,, % "ahk_id " hwnd
}

SetCurSel(hwnd, PosOrText:=1, ByIndex:=true) {
	static CB_SETCURSEL := 0x014E , CB_FINDSTRINGEXACT := 0x0158 ;, CB_SELECTSTRING := 0x014D ; Doesn't work
	
	if ByIndex {
		SendMessage, % CB_SETCURSEL, % PosOrText-1, 0,, % "ahk_id " hwnd
		idx := ErrorLevel
	} else {
		SendMessage, % CB_FINDSTRINGEXACT, -1, &PosOrText,, % "ahk_id " hwnd
		SendMessage, % CB_SETCURSEL, % ErrorLevel, 0,, % "ahk_id " hwnd
		idx := ErrorLevel
	}
	return (idx == "FAIL" ? false : idx+1)
}

GetCount(hwnd) {
	static CB_GETCOUNT := 0x0146
	
	SendMessage, % CB_GETCOUNT, 0, 0,, % "ahk_id " hwnd
	return (ErrorLevel == "FAIL" ? false : ErrorLevel)
}

CBEI_STRUCT(ByRef COMBOBOXEXITEM, ByRef pszText, ByRef cchTextMax, ByRef iItem, ByRef iImage, ByRef iSelectedImage, ByRef iOverlay, ByRef iIndent:=0) {
	static CBEIF_TEXT := 0x00000001 , CBEIF_IMAGE := 0x00000002 , CBEIF_SELECTEDIMAGE := 0x00000004 , CBEIF_OVERLAY := 0x00000008 
			, CBEIF_INDENT := 0x00000010 , CBEIF_LPARAM := 0x00000020 , CBEIF_DI_SETITEM := 0x10000000
	
	; SET MASK
	mask := CBEIF_TEXT | (iImage <> "" ? CBEIF_IMAGE : 0) | (iSelectedImage <> "" ? CBEIF_SELECTEDIMAGE : 0)
	
	;~ CREATE STRUCTURE
	VarSetCapacity(COMBOBOXEXITEM, 36, 0)
	, NumPut(mask , COMBOBOXEXITEM , 0) ; mask
	, Numput(iItem, COMBOBOXEXITEM , 4) ; iItem
	, Numput(&pszText, COMBOBOXEXITEM , 8) ; pszText
	, Numput(cchTextMax, COMBOBOXEXITEM , 12) ; cchTextMax - If text information is being set, this member is ignored.
	, NumPut(iImage, COMBOBOXEXITEM , 16) ; iImage
	, NumPut(iSelectedImage, COMBOBOXEXITEM , 20) ; iSelectedImage
	, Numput(iOverlay, COMBOBOXEXITEM , 24) ; iOverlay
	, Numput(iIndent, COMBOBOXEXITEM , 28) ; iIndent
	;~ , NumPut(CBEIF_LPARAM , COMBOBOXEXITEM , 32) ; lParam
	
} 

 

Note: Assigning a g-Label causes AHK to hang

[fincs]

Heh, I thought my custom Gui control stuff would not get accepted

Cool. Does it mean I can add toolbars, rebars, etc. w/o requiring any external lib? How does it handle events? gLabel? Thanks btw..

Yes, and yes. Read the pull request.

Note: Assigning a g-Label causes AHK to hang

This may happen for some controls because of this:

// This is a WM_NOTIFY handler and thus we need to set A_GuiEvent to 'N'. Due to the nature
// of WM_NOTIFY messages we cannot use PostMessage because otherwise the NMHDR pointer becomes toast.

Any suggestions on how to work around this?

[Coco]

Heh, I thought my custom Gui control stuff would not get accepted

It's one of the features I wished to be supported internally, thank you very much.

 

In my test, ComboBoxEx sends its notification via WM_COMMAND. I tried putting just "return" but AHK still hangs..

 

Any suggestions on how to work around this?

Hmm, how does AHK handle ListView notifications?

[fincs]

In my test, ComboBoxEx sends its notification via WM_COMMAND. I tried putting just "return" but AHK still hangs.

My own test shows that ComboBoxEx is using WM_NOTIFY.

Hmm, how does AHK handles ListView notifications?

When AHK receives any kind of Gui event, it PostMessages itself a message that later executes the g-label. This is unacceptable for WM_NOTIFY as otherwise the NMHDR pointer becomes invalid, so for that particular case I tried to use SendMessage.

EDIT: found a 64-bit bug in application.cpp, here's a fix:

Spoiler

@@ -219,11 +219,12 @@ bool MsgSleep(int aSleepDuration, MessageMode aMode)
 	Hotstring *hs;
 	GuiType *pgui; // This is just a temp variable and should not be referred to once the below has been determined.
 	GuiControlType *pcontrol, *ptab_control;
 	GuiIndexType gui_control_index;
 	GuiEventType gui_action;
-	DWORD gui_event_info, gui_size;
+	DWORD_PTR gui_event_info;
+	DWORD gui_size;
 	bool *pgui_label_is_running, event_is_control_generated;
 	Label *gui_label;
 	HDROP hdrop_to_free;
 	DWORD tick_before, tick_after;
 	LRESULT msg_reply;
@@ -665,11 +666,11 @@ bool MsgSleep(int aSleepDuration, MessageMode aMode)
 					// whose msg number happens to be AHK_GUI_ACTION.  Do this *only* when HWND isn't recognized,
 					// not when msg content is invalid, because dispatching a msg whose HWND is one of our own
 					// GUI windows might cause GuiWindowProc to fwd it back to us, creating an infinite loop.
 					goto break_out_of_main_switch; // Goto seems preferably in this case for code size & performance.
 				
-				gui_event_info =    (DWORD)msg.lParam;
+				gui_event_info =    (DWORD_PTR)msg.lParam;
 				gui_action =        LOWORD(msg.wParam);
 				gui_control_index = HIWORD(msg.wParam); // Caller has set it to NO_CONTROL_INDEX if it isn't applicable.
 
 				if (gui_action == GUI_EVENT_RESIZE) // This section be done after above but before pcontrol below.
 				{

[Coco]

My own test shows that ComboBoxEx is using WM_NOTIFY.

You are correct, just checked MSDN. My previous ComboBoxEx class doesn't listen to WM_NOTIFY but instead I filtered out CBN_EDITCHANGE notification which is sent via WM_COMMAND....that's why..

When AHK receives any kind of Gui event, it PostMessages itself a message that later executes the g-label. This is unacceptable for WM_NOTIFY as otherwise the NMHDR pointer becomes invalid, so for that particular case I tried to use SendMessage.

Is this the same case for ListViews, UpDowns, TreeViews? Are they sent via SendMessage? or PostMessage? 

[fincs]

Are they sent via SendMessage? or PostMessage?

Everything is sent via PostMessage except for my Custom control's WM_NOTIFY stuff.

[Coco]

Is it possible to replicate AHK's built-in controls' behavior? I mean, they're sent via WM_NOTIFY as well...how does AHK preserve the NMHDR struct pointer for controls that send its notifications via WM_NOTIFY? 

[fincs]

how does AHK preserve the NMHDR struct pointer for controls

It is not preserved, data is extracted from it (such as the notification type); which is what then gets PostMessaged. It is not possible to replicate this due to the fact that controls expect you to parse the NMHDR structure (which is most of the time followed in memory by control specific data you're supposed to use).

[Coco]

I see...a workaround would be to parse it(for selected controls, e.g. Windows common controls not built-in in AHK) and then PostMessage the extracted data..this requires work though..

[fincs]

a workaround would be to parse it(for selected controls, e.g. Windows common controls not built-in in AHK)

No, because this is supposed to be used with controls AutoHotkey does not know anything about. Remember the structure is variable and it can contain extra control-specific fields.

[Coco]

Is this possible?:

Upon receipt of notification, get the control's class via "hwndFrom" member of the NMHDR struct. Check if class is in internal list of supported controls(e.g.: controls with similar fields), if yes, parse it then PostMessage the data..if not(e.g. Scintilla or other custom control not in User32.dll or Comctl32.dll), SendMessage it and let the user extract the data from the NMHDR struct represented by A_EventInfo.

[fincs]

That would mean unnecessary code complexity and bloat. I'm currently thinking about instead executing the label directly in a way similar to OnMessage.