10 replies to this topic

[Learning one]

WARNING: This is old thread. It is continued here.
[object] QPX()
- tests how fast functions and/or subroutines run and diplays results in a window. When you are in doubt which coding approach/style will do specific job fastest, this test will give you the answer.
- no globals, encapsulated
- simple usage
- based on SKAN's QPX() function
 
QPX window preview. Click here to see explanation.

Left edit = Summary with average run time for each item in test collection + percentages + fastest tested item mark (<<)
Right edit = Details with minimum (fastest), average, maximum (slowest) and total run times for each item in test collection + percentages
 
Basic usage concept.

QPX.Add("MyFunc")                          ; adds MyFunc function to the test collection
QPX.Add("AnotherFunc", "param1", "param2") ; adds AnotherFunc function to the test collection and passes 2 parameters to that function
QPX.Add("MySub")                           ; adds MySub subroutine to the test collection
QPX.Add("AnotherSub")                      ; adds AnotherSub subroutine to the test collection
QPX.Test()                                 ; starts test and displays results in a window. Left edit = Summary. Right edit = Details.
return

 
Download.
QPX.ahk - includes [QPX object] + [example, documentation, etc. in comments]
 
 
Credits.
Thanks to SKAN for his QPX() function.
 
See also.
- QPX() by SKAN
- AutoHotkey Benchmarks by Uberi
- Minimal Benchmark by R3gX

[Learning one]

Updated to version 1.02
- added percentages and fastest tested item mark (<<)

[m3nth0l]

Very nice! Thanks for this.

[Learning one]

Thanks!

Added one more example (in QPX.ahk comments)

[R3gX]

Woooaaahhh !!! 

learning_one_great_scripts++

I really like this script!

 

I have a little question : How can I use your script with some of my functions that expect ByRef parameters ?

[Learning one]

Hi R3gX,

you can test functions with ByRef param, however, that param and the caller's variable will both refer to the same contents in memory only in the moment when you add such function to the test collection via .Add() method, and later, when the function is really called in the testing loop (started via .Test() method), you won't have ByRef effect.

To have real ByRef testing effect, use this trick; make subroutines which will execute functions with ByRef parameters.

Like this (adapted Example script 1);

;===Auto-execute===
Loop, 100        ; makes a comma delimited list for testing; "1,2,3, ...etc."
    List .= A_Index ","
List := RTrim(List, ",")

QPX.Add("Sub1", List)    ; adds Sub1 subroutine to a test collection
QPX.Add("Sub2", List)    ; adds Sub2 subroutine to a test collection
QPX.Test()                ; starts test and displays results in a window
return

;===Hotkeys===
F1::QPX.Test(50)                ; starts test again, but this time with 50 iterations (instead of 10 - default)
Esc::ExitApp

;===Subroutines===
Sub1:    ; executes function with ByRef parameter
ReverseList1(List)
;MsgBox,,, % List, 0.3    ; just a proof that ByRef List really reverses
return

Sub2:    ; executes function with ByRef parameter
ReverseList2(List)
;MsgBox,,, % List, 0.3    ; just a proof that ByRef List really reverses
return

;===Functions===
#Include QPX.ahk    ; by Learning one
ReverseList1(ByRef List, Delimiter=",") {
    StringSplit, p, List, % Delimiter
    Loop, % p0
    {
        CurItemNum := (A_Index = 1) ? p0 : p0 - A_Index + 1
        OutList .= p%CurItemNum% Delimiter
    }
    List := RTrim(OutList, Delimiter)
}
ReverseList2(ByRef List, Delimiter=",") {    ; from the Sort command documentation in AHK kelp
    Sort, List, F ReverseList2_Helper D%Delimiter%  ; Reverses the list so that it contains 4,3,2,1
}
ReverseList2_Helper(a1, a2, offset) { ; a helper function
    return offset  ; Offset is positive if a2 came after a1 in the original list; negative otherwise.
}

Uncomment MsgBoxes to have a proof that ByRef List really reverses on each testing loop.

[MasterFocus]

Just wanted to say: thanks L1, great work! 

[R3gX]

Hi everyone!

 

@Learning one : TTHHHANNNK YYYOOOOUUUU !!! It works very well !

I have my own script to test scripts but I really like yours.

(sorry for the late)

[Learning one]

@MasterFocus: Thanks!
@R3gX: Thanks! If you posted your script, let me know where it is, and I'll put a link to it in See also section.

[R3gX]

Hi Learning one !
 
For my own benchmarks script, I didn't post the code but here is a new version

Spoiler

#Include MBM.ahk

MBM(["SleepCMD_2", "SleepCMD_10", "SleepCMD_6"], 1000)
MBM(["SleepDLL_2", "SleepDLL_10", "SleepDLL_6"], 1000)
Return

SleepCMD_2:
Sleep, 2
Return

SleepCMD_10:
Sleep, 10
Return

SleepCMD_6:
Sleep, 6
Return

SleepDLL_2:
DllCall("Sleep", "UInt", 2)
Return

SleepDLL_10:
DllCall("Sleep", "UInt", 10)
Return

SleepDLL_6:
DllCall("Sleep", "UInt", 6)
Return 

Spoiler

/*
Name      : MBM - Minimal Benchmark
Version   : v0.2
Author    : R3gX
Thanks to : just me & SKAN for QPC and QPX codes
*/

; INITIALIZE GUI
MBM_GUI_Init()

MBM(subs="", iterations="")
{
	global MBM_GUI_ID
	static BMCount := 0 , PrevBM := ""

	; CHECK PARAMETERS
	If (not IsObject(subs) && not IsLabel(subs))
		Return
	Else If (not IsObject(subs) && IsLabel(subs))
		subs := [subs]
	If not (iterations~="^\d+$")
		iterations := MBM_Vars("iterations")

	; SET LOOP'S VARS
	BatchLines := A_BatchLines
	If MBM_Vars("MaxSpeed")
		SetBatchLines, -1
	BMCount++ , BMHeader := "BENCHMARK #" BMCount , BM := ""
	WinSetTitle, % "ahk_id " MBM_GUI_ID,, % BMHeader

	Loop, % iterations
	{
		iteration := A_Index , log := ""
		For i,sub in subs
		{
			If !IsLabel(sub)
				Continue

			; BENCHMARK
			MBM_Times(sub)
			GoSub, % sub
			times := MBM_Times(sub, iteration)

			; FORMAT THE BENCHMARK TEXT
			step := "[" iteration "." A_Index "]"
			log  .= sub "`t" times.average "`n"
			BM   := BMCount>1 ? PrevBM BMHeader "`n" : ""
			BM   .= step "`n" log "`n"
			MBM_GUI( BM )
			DllCall("Sleep", "UInt", 10)
		}
	}
	; SAVE PREVIOUS BENCHMARK TEXT TO PREPEND IT LATER
	PrevBM .= BMHeader "`n" step "`n" log "`n"

	; RESTORE SCRIPT'S DEFAULT SPEED
	SetBatchLines, % BatchLines

	WinSetTitle, % "ahk_id " MBM_GUI_ID,, % BMHeader "  -  ENDED!"
}

MBM_Vars(key="", value="")
{
	static vars :=	{ "iterations"  : 10
					, "MaxSpeed"    : 1
					, "FormatTime"  : 1
					, "DisplayHour" : 0
					, "SaveOnExit"  : 1
					, "OutputFile"  : A_ScriptDir "\MBM_Logs.txt" }
	If !vars.HasKey(key)
		Return

	If (   (key="iterations"  and value~="^\d+$")
		or (key="MaxSpeed"    and value~="^[01]$")
		or (key="FormatTime"  and value~="^[01]$")
		or (key="DisplayHour" and value~="^[01]$")
		or (key="SaveOnExit"  and value~="^[01]$")   )
		Return, (vars[key] := value)
	Else
		Return, vars[key]
}

MBM_Times(sub="", iter="")
{
	static IsStarted := {} , tot := {}
	If not IsStarted[sub]
		IsStarted[sub] := MBM_QPT()
	Else If (IsStarted[sub] && iter~="^\d+$")
	{
		IsStarted[sub] := 0
		elapsed := MBM_QPT()
		tot[sub] ? (tot[sub]+=elapsed) : (tot[sub]:=elapsed)
		average := tot[sub]/iter
		If MBM_Vars("FormatTime")
			elapsed := MBM_FormatTime(elapsed)
			, average := MBM_FormatTime(average)
		Return, { "elapsed" : elapsed , "average" : average }
	}
}

/*
	sligthly modified version from 'just me'
	>> http://www.autohotkey.com/board/topic/
		82483-fileread-vs-loop-read/page-2#entry524667
	---------------------------------------------------------------
	See also QPX() from 'SKAN'
	>> http://www.autohotkey.com/board/topic/
		91860-object-qpx-test-how-fast-the-code-runs/#entry579284
	---------------------------------------------------------------
	See also QPX() from 'Learning one'
	>> http://www.autohotkey.com/board/topic/
		91860-object-qpx-test-how-fast-the-code-runs/?hl=qpx
*/
MBM_QPT()
{
   Static Frequency := 0 , Previous := 0
   If !(Frequency)
      DllCall("Kernel32.dll\QueryPerformanceFrequency", "Int64P", Frequency)
   DllCall("Kernel32.dll\QueryPerformanceCounter", "Int64P", Counter)
   Interval := (Counter-Previous)/Frequency , Previous := Counter
   Return Interval
}

MBM_FormatTime(_secs)
{
	hour     := _secs//3600
	hour_mod := Mod(_secs, 3600)
	min      := hour_mod//60
	min_mod  := Mod(hour_mod, 60)
	sec      := min_mod//1
	sec_mod  := Mod(min_mod, 1)
	msec     := (sec_mod*1000)//1
	msec_mod := ((sec_mod*1000)-msec)*1000

	FloatFormat := A_FormatFloat
	SetFormat, Float, % 02
	hour += 0 , min += 0 , sec += 0
	SetFormat, Float, % 03
	msec += 0 , msec_mod += 0
	SetFormat, Float, % FloatFormat

	Time := MBM_Vars("DisplayHour")==1 ? hour ":" : ""
	Return,  Time .= min ":" sec ":" msec "." msec_mod
}

MBM_GUI_Init()
{
	global MBM_GUI_ID, MBM_GUI_edit
	GuiStyles := "+LabelMBM_GUI_ +LastFound +HwndMBM_GUI_ID"
	GuiStyles .= " +Resize +AlwaysOnTop +ToolWindow"
	Gui, MBM_GUI:Destroy
	Gui, MBM_GUI:New, % GuiStyles
	Gui, MBM_GUI:Margin, 0, 0
	Gui, MBM_GUI:Font,, DejaVu Sans Mono
	Gui, MBM_GUI:Add, Edit, w400 h200 vMBM_GUI_edit +ReadOnly +Multi
	Gui, MBM_GUI:Show, x0 yCenter, MBM
	Gui, 1:Default

	Menu, Tray, Add, Show GUI, MBM_GUI_Show
}

MBM_GUI(Text="")
{
	GuiControl, MBM_GUI:, MBM_GUI_edit, % Text
}

MBM_GUI_Show()
{
	MBM_GUI_Show:
	Gui, MBM_GUI:Show,, MBM
	Return
}

MBM_GUI_Escape()
{
	MBM_GUI_Escape:
	Gui, MBM_GUI:Submit
	Return
}

MBM_GUI_Size()
{
	MBM_GUI_Size:
	GuiControl, MBM_GUI:Move, MBM_GUI_edit, % "w" A_GuiWidth " h" A_GuiHeight
	Return
}

MBM_GUI_Close()
{
	MBM_GUI_Close:
	MsgBox, 262436, EXIT:, Exit script?, 1
	IfMsgBox No
		Return
	If MBM_Vars("SaveOnExit")
	{
		GuiControlGet, BM, MBM_GUI:, MBM_GUI_edit
		Header := "===== BENCHMARK " A_Now " ====="
		Footer := "===================================="
		BM := "`n" Header "`n" Trim(BM, " `t`n") "`n" Footer "`n"
		FileAppend, % "`n" BM, % MBM_Vars("OutputFile")
	}
	ExitApp
	Return
} 

[Learning one]

Nice. I added a link to your work.