16 replies to this topic

[Verdlin]

Hi! I am working on translating some cool C++ code to AHK code, but I am having difficulty.

 

I am following the tutorial posted here. I do not ask anyone to read through it completely, but simply take a look at the c++ message handler for WM_OnEraseBkgnd, compare it to my ahk OnEraseBkgnd, and see if they can identify where I am going wrong.

 

Actually, I am almost certain the problem is having to do with the ListBox's bitmap, but I am not sure what to do. I think this code/concept is pretty easy to anyone who is well versed in gdip.

 

Thanks in advance

 

Spoiler

pToken := Gdip_Startup()

GUI, New, hwndg_hMain

OnMessage(WM_ERASEBKGND:=20, "OnEraseBkgnd")
;~ OnMessage(WM_PAINT:=15, "OnPaint")
;~ OnMessage(WM_VSCROLL:=277, "OnVScroll")
;~ OnMessage(LBN_SELCHANGE:=1, "OnLbnSelChange")
;~ OnMessage(WM_KEYDOWN:=256, "OnKeyDown")
;~ OnMessage(WM_CHAR:=258, "OnChar")
;~ OnMessage(WM_MOVE, "OnMove")
;~ OnMessage(WM_SIZE:=5, "OnSize")

GUI, Add, Picture, x0 y0 w400 h400 hwndg_hPic, pic.jpg
GUI, Add, ListBox, x0 y0 w200 h200 hwndg_hLB BackgroundTrans AltSubmit gLVProc, One|Two|Three|Four|Five|Six|Seven
GUI, Show, w400 h400

return

OnEraseBkgnd(wParam, lParam, msg, hWnd)
{
	global g_bHasBackground, g_hMain, g_hLB, g_hPic

	if (!g_bHasBackground)
	{
		rect := struct("left;top;right;bottom")
		DllCall("GetClientRect", uint, g_hLB, ptr, rect[])
		DllCall("ClientToScreen", uint, g_hLB, ptr, rect[])
		DllCall("ScreenToClient", uint, g_hMain, ptr, rect[])

		hParentDC := GetDC(g_hMain)
		memdc := CreateCompatibleDC(hParentDC)
		hbm := CreateDIBSection(rect.right, rect.bottom, GetDC(g_hLB))
		hOldBmp := SelectObject(memdc, Gdip_BitmapFromHWND(g_hLB))

		BitBlt(memdc, 0, 0, rect.right, rect.bottom, hParentDC, rect.left, rect.top, SRCCOPY:=13369376)
		SelectObject(memdc, hOldBmp)
		g_bHasBackground := true
		DllCall("ReleaseDC",UInt, g_hMain, UInt, hParentDC)
	}
	return true
}

[Lexikos]

I think you have confused GDI for GDI+.  It's an easy mistake to make since the author of the GDI+ lib for AutoHotkey included GDI functions.

 

SelectObject is a GDI function, and requires that you pass a GDI object, such as a GDI bitmap.  Gdip_BitmapFromHWND() returns a GDI+ Bitmap, which is different to a GDI bitmap.  CreateDIBSection() returns a GDI bitmap.  You've created hbm but never used it; did you intend to pass it instead of calling Gdip_BitmapFromHWND()?

 

You should call ReleaseDC() on the return value of GetDC(g_hLB).  Note that Gdip.ahk (my copy, at least) contains a wrapper for this function, but the parameters are swapped.

 

Window and device context handles are pointer-sized, so you should use ptr rather than uint.  However, it doesn't matter in practice.  It would matter for structs, or if you were passing a pointer to a HWND.

 

If you want to keep the bitmap (referred by hbm), you should store it in a static or global variable.  Otherwise, you should delete it before the function returns.  The same goes for memdc.

[guest3456]

your SelectObject call is wrong like Lex said, you need to use hbm as the 2nd param

the tutorial is using the ERASEBKGND message of the listbox, while your OnMessage captures all messages for the entire script, including your main gui and all. i'm not so sure thats what you want

anyway
from the site:
 

First thing we have to do is copy the parent window's image before the first time the ListBox is drawn, this will give us the background for the listbox. We can do this in the WM_ERASEBKGND message handler. The first time this message is received the ListBox has not yet been drawn, so it is a safe place to take a snapshot of the parent window.

if all he wants you to do is bitblt the image into a memory DC, you can simply do this before you even Gui,Add the listbox, you dont need to capture the ERASEBKGND message to do it

hrm actually nevermind, i guess hes doing all those client to screen coordinates to just copy the cropped area of the image that fits the rectangle of the listbox

[Verdlin]

Thank you both very much! I had no idea about the differences between GDI and GDI+.

 

Here's a revised version. In this version, BitBit fails and returns 1. GetLastError is returning 0 though...

 

Spoiler

pToken := Gdip_Startup()

GUI, New, hwndg_hMain

OnMessage(WM_ERASEBKGND:=20, "OnEraseBkgnd")

GUI, Add, Picture, x0 y0 w400 h400 hwndg_hPic,pic.jpg
GUI, Add, ListBox, x0 y0 w200 h200 hwndg_hLB BackgroundTrans AltSubmit gLVProc, One|Two|Three|Four|Five|Six|Seven
GUI, Show, w400 h400
return

OnEraseBkgnd(wParam, lParam, msg, hWnd)
{
    global g_bHasBackground, g_hMain, g_hLB, g_hPic, g_hBmp

    if (!g_bHasBackground)
    {
        rect := struct("left;top;right;bottom")
        DllCall("GetClientRect", ptr, g_hLB, ptr, rect[])
        DllCall("ClientToScreen", ptr, g_hLB, ptr, rect[])
        DllCall("ScreenToClient", ptr, g_hMain, ptr, rect[])

        hParentDC := GetDC(g_hMain)
        memdc := CreateCompatibleDC(hParentDC)
        hLBDC := GetDC(g_hLB)
        g_hBmp := CreateDIBSection(rect.right, rect.bottom, hLBDC)
        hOldBmp := SelectObject(memdc, g_hBmp)

        Msgbox % BitBlt(memdc, 0, 0, rect.right, rect.bottom, hParentDC, rect.left, rect.top, SRCCOPY:=13369376)
        SelectObject(memdc, hOldBmp)

        ReleaseDC(hParentDC)
        DeleteDC(memdc)
        ReleaseDC(hLBDC, g_hMain)

        g_bHasBackground := true
    }
    return true
}

LVProc:
{
    DllCall("RedrawWindow", uint, hwnd, uint, 0, uint, 0, RDW_INVALIDATE:=1 | RDW_UPDATENOW:=256 | RDW_ERASE:=4)
    return
}

[just me]

Well, partially working. You have to subclass the control, and there is some work remaining:

 

Spoiler

#NoEnv
PicFile := A_WinDir . "\Web\Wallpaper\HP1.jpg"

Gui, New, hwndhMain
Gui, Add, Picture, x0 y0 w400 h400 hwndhPic, %PicFile%
Gui, Add, ListBox, x0 y0 w200 h200 hwndhLB BackgroundTrans AltSubmit gLVProc, One|Two|Three|Four|Five|Six|Seven

LB_CB := RegisterCallback("LB_SubclassProc")
DllCall("Comctl32.dll\SetWindowSubclass", "Ptr", hLB, "Ptr", LB_CB, "Ptr", hLB, "Ptr", hPic)

Gui, Show, w400 h400

Return
GuiClose:
ExitApp

LB_SubclassProc(hWnd, uMsg, wParam, lParam, IdSubclass, RefData) {
   Static WM_ERASEBKGND := 20
   Static bHasBackground := 0
   If (uMsg = WM_ERASEBKGND) {
      If (!bHasBackground)
      {
         hPic := RefData ; we passed the handle of the Pic control via RefData
         VarSetCapacity(Rect, 16, 0)
         DllCall("User32.dll\GetClientRect", "Ptr", hWnd, "Ptr", &Rect)
         DllCall("User32.dll\ClientToScreen", "Ptr", hWnd, "Ptr", &Rect)
         DllCall("User32.dll\ScreenToClient", "Ptr", hPic, "Ptr", &Rect)
         Left := NumGet(Rect, 0, "Int")
         Top := NumGet(Rect, 4, "Int")
         Right := NumGet(Rect, 8, "Int")
         Bottom := NumGet(Rect, 12, "Int")

         hLBDC := DllCall("User32.dll\GetDC", "Ptr", hWnd, "UPtr")
         hPicDC := DllCall("User32.dll\GetDC", "Ptr", hPic, "UPtr")
         DllCall("Gdi32.dll\BitBlt", "Ptr", hLBDC, "Int", 0, "Int", 0, "Int", Right - Left, "Int", Bottom - Top
                                   , "Ptr", hPicDC, "Int", Left, "Int", Top, "UInt", SRCCOPY := 0x00CC0020)

         DllCall("User32.dll\ReleaseDC", "Ptr", hWnd, "Ptr", hLBDC)
         DllCall("User32.dll\ReleaseDC", "Ptr", hPic, "Ptr", hPicDC)

         bHasBackground := True
      }
      Return True
   }
   Return DllCall("Comctl32.dll\DefSubclassProc", "Ptr", hWnd, "UInt", uMsg, "Ptr", wParam, "Ptr", lParam)
}

LVProc:
{
    DllCall("RedrawWindow", "Ptr", g_hLB, "Ptr", 0, "Ptr", 0, "UInt", RDW_INVALIDATE:=1 | RDW_ERASENOW:=0x200 | RDW_ERASE:=4)
    Return
} 

[Lexikos]

In this version, BitBit fails and returns 1.

 

Really?

 

If the function succeeds, the return value is nonzero.

Source: BitBlt function

[Verdlin]

Really?

 

Oh, dear. That is exactly the same place I read about BitBlt, but somehow I read that as, "zero" instead of "nonzero."

[Verdlin]

Oh, that is cool! Thank you! I am guessing (hoping) this is enough to help me get the rest figured out.

 

Well, partially working. You have to subclass the control, and there is some work remaining:

 

Spoiler

#NoEnv
PicFile := A_WinDir . "\Web\Wallpaper\HP1.jpg"

Gui, New, hwndhMain
Gui, Add, Picture, x0 y0 w400 h400 hwndhPic, %PicFile%
Gui, Add, ListBox, x0 y0 w200 h200 hwndhLB BackgroundTrans AltSubmit gLVProc, One|Two|Three|Four|Five|Six|Seven

LB_CB := RegisterCallback("LB_SubclassProc")
DllCall("Comctl32.dll\SetWindowSubclass", "Ptr", hLB, "Ptr", LB_CB, "Ptr", hLB, "Ptr", hPic)

Gui, Show, w400 h400

Return
GuiClose:
ExitApp

LB_SubclassProc(hWnd, uMsg, wParam, lParam, IdSubclass, RefData) {
   Static WM_ERASEBKGND := 20
   Static bHasBackground := 0
   If (uMsg = WM_ERASEBKGND) {
      If (!bHasBackground)
      {
         hPic := RefData ; we passed the handle of the Pic control via RefData
         VarSetCapacity(Rect, 16, 0)
         DllCall("User32.dll\GetClientRect", "Ptr", hWnd, "Ptr", &Rect)
         DllCall("User32.dll\ClientToScreen", "Ptr", hWnd, "Ptr", &Rect)
         DllCall("User32.dll\ScreenToClient", "Ptr", hPic, "Ptr", &Rect)
         Left := NumGet(Rect, 0, "Int")
         Top := NumGet(Rect, 4, "Int")
         Right := NumGet(Rect, 8, "Int")
         Bottom := NumGet(Rect, 12, "Int")

         hLBDC := DllCall("User32.dll\GetDC", "Ptr", hWnd, "UPtr")
         hPicDC := DllCall("User32.dll\GetDC", "Ptr", hPic, "UPtr")
         DllCall("Gdi32.dll\BitBlt", "Ptr", hLBDC, "Int", 0, "Int", 0, "Int", Right - Left, "Int", Bottom - Top
                                   , "Ptr", hPicDC, "Int", Left, "Int", Top, "UInt", SRCCOPY := 0x00CC0020)

         DllCall("User32.dll\ReleaseDC", "Ptr", hWnd, "Ptr", hLBDC)
         DllCall("User32.dll\ReleaseDC", "Ptr", hPic, "Ptr", hPicDC)

         bHasBackground := True
      }
      Return True
   }
   Return DllCall("Comctl32.dll\DefSubclassProc", "Ptr", hWnd, "UInt", uMsg, "Ptr", wParam, "Ptr", lParam)
}

LVProc:
{
    DllCall("RedrawWindow", "Ptr", g_hLB, "Ptr", 0, "Ptr", 0, "UInt", RDW_INVALIDATE:=1 | RDW_ERASENOW:=0x200 | RDW_ERASE:=4)
    Return
} 

[Verdlin]

I'm getting hung up on CPaintDC. How can I handle class objects?

[Verdlin]

Progress.

 

I have taken my shot porting most of the important code from the tutorial. There are a lot of errors in my script below, but I'm not sure what the right way to do it is. Specifically, passing around old bmps and membmps before BitBlt. I did, at one point, have a script that was successfully drawing colored text onto the LV. Also, for OnPaint, the tutorial uses a CPaintDC class object. I have no idea how to use class objects in AHK or find a struct-equivalent.

 

Any help is much appreciated!

 

Spoiler

Gui, New, hwndg_hMain
Gui, Add, Picture, x0 y0 w400 h400 hwndg_hPic, C:\Pic.jpg
Gui, Add, ListBox, x0 y0 w200 h200 hwndg_hLB vvLB gLVProc BackgroundTrans AltSubmit, One|Two|Three|Four|Five

static WM_GETFONT:=0x31
SendMessage WM_GETFONT,0,0,,ahk_id %g_hLB%
g_hFont := ErrorLevel
g_iOffset := 13 ; need to actually get the font height

LB_CB := RegisterCallback("LB_SubclassProc")
DllCall("Comctl32.dll\SetWindowSubclass", "Ptr", g_hLB, "Ptr", LB_CB, "Ptr", g_hLB, "Ptr", g_hPic)

Gui, Show, w400 h400

return

LB_SubclassProc(hWnd, uMsg, wParam, lParam, IdSubclass, RefData)
{
    global g_hLB, g_hMain, g_hLB, g_hPic, g_hFont, g_iOffset
    static WM_ERASEBKGND := 20, WM_PAINT := 15, s_bHasBackground := false

    If (uMsg = WM_ERASEBKGND)
    {
        If (!s_bHasBackground)
        {
            hPic := RefData ; we passed the handle of the Pic control via RefData
            VarSetCapacity(Rect, 16, 0)
            DllCall("User32.dll\GetClientRect", "Ptr", hWnd, "Ptr", &Rect)
            DllCall("User32.dll\ClientToScreen", "Ptr", hWnd, "Ptr", &Rect)
            DllCall("User32.dll\ScreenToClient", "Ptr", hPic, "Ptr", &Rect)
            Left := NumGet(Rect, 0, "Int")
            Top := NumGet(Rect, 4, "Int")
            Right := NumGet(Rect, 8, "Int")
            Bottom := NumGet(Rect, 12, "Int")

            hLBDC := DllCall("User32.dll\GetDC", "Ptr", hWnd, "UPtr")
            hPicDC := DllCall("User32.dll\GetDC", "Ptr", hPic, "UPtr")

            DllCall("Gdi32.dll\BitBlt", "Ptr", hLBDC, "Int", 0, "Int", 0, "Int", Right - Left, "Int", Bottom - Top
                            , "Ptr", hPicDC, "Int", Left, "Int", Top, "UInt", SRCCOPY := 0x00CC0020)

            DllCall("User32.dll\ReleaseDC", "Ptr", hWnd, "Ptr", hLBDC)
            DllCall("User32.dll\ReleaseDC", "Ptr", hPic, "Ptr", hPicDC)
            DllCall("User32.dll\DeleteDC", "Ptr", memdc)

            s_bHasBackground := True
        }
            return true
    }
    return DllCall("Comctl32.dll\DefSubclassProc", "Ptr", hWnd, "UInt", uMsg, "Ptr", wParam, "Ptr", lParam)
}

MyOnPaint()
{
	global g_hLB, g_hMain, g_hLB, g_hPic, g_hFont, g_iOffset
	static WM_ERASEBKGND := 20, WM_PAINT := 15, s_bHasBackground := false

	VarSetCapacity(ClientRect, 16, 0)
	DllCall("User32.dll\GetClientRect", "Ptr", g_hLB, "Ptr", &ClientRect)
	Left := NumGet(ClientRect, 0, "Int")
	Top := NumGet(ClientRect, 4, "Int")
	Right := NumGet(ClientRect, 8, "Int")
	Bottom := NumGet(ClientRect, 12, "Int")
	iW := Right - Left
	iH := Bottom - Top

	hPicDC := DllCall("User32.dll\GetDC", "Ptr", g_hPic, "UPtr")
	hLBDC := DllCall("User32.dll\GetDC", "Ptr", g_hLB, "UPtr")
	memdc := DllCall("CreateCompatibleDC", "Ptr", hLBDC)

	memBmp := DllCall("Gdi32.dll\CreateCompatibleBitmap", "ptr", hLBDC, "uint", iW, "uint", iH)
	hOldMemBmp := DllCall("SelectObject", "Ptr", memdc, "Ptr", membmp)

	; Paint the background bitmap on the memory dc
	hOldBmp := DllCall("SelectObject", "Ptr", hLBDC, "Ptr", hPicDC)
	DllCall("Gdi32.dll\BitBlt", "Ptr", memdc, "Int", 0, "Int", 0, "Int", iW, "Int", iH
				, "Ptr", hPicDC, "Int", Left, "Int", Top, "UInt", SRCCOPY := 0x00CC0020)
	DllCall("SelectObject", "Ptr", hLBDC, "Ptr", hOldBmp)

	NumPut(0, ClientRect, 0, "int")
	NumPut(0, ClientRect, 4, "int")
	NumPut(iW, ClientRect, 8, "int")
	NumPut(iH + g_iOffset, ClientRect, 12, "int")

	ControlGet, sItems, List,,, ahk_id %g_hLB%
	StringSplit, aItems, sItems, `n, `r

	SendMessage, LB_GETCURSEL:=392, 0, 0,, ahk_id %g_hLB%
	iCurSel := ErrorLevel + 1
	SendMessage, LB_GETCOUNT:=395, 0, 0,, ahk_id %g_hLB%
	iCnt := ErrorLevel
	Loop %iCnt%
	{
		if (iCnt * g_iOffset > Bottom)
			break

		MyDrawItem(memdc, ClientRect, A_Index, A_Index == iCurSel)
		DllCall("OffsetRect", "ptr", &ClientRect, "uint", 0, "uint", g_iOffset)
	}

	DllCall("Gdi32.dll\BitBlt", "Ptr", hLBDC, "Int", 0, "Int", 0, "Int", iW, "Int", iH
				, "Ptr", memdc, "Int", Left, "Int", Top, "UInt", SRCCOPY := 0x00CC0020)
	DllCall("SelectObject", "Ptr", memdc, "Ptr", hOldMemBmp)
	return
}

MyDrawItem(hDC, Rect, iCurSelNdx, bSelected)
{
	global g_hLB, g_hMain, g_hLB, g_hPic, g_hFont, g_iOffset
	static WM_ERASEBKGND := 20

	VarSetCapacity(RectCopy, 16, 0)
	Left := NumGet(Rect, 0, "Int")
	Top := NumGet(Rect, 4, "Int")
	Right := NumGet(Rect, 8, "Int")
	Bottom := NumGet(Rect, 12, "Int")
	NumPut(Left, RectCopy, 0, "int")
	NumPut(Top, RectCopy, 4, "int")
	NumPut(Right RectCopy, 8, "int")
	NumPut(Bottom, RectCopy, 12, "int")

	DllCall("SetBMode", "ptr", hDC, "uint", TRANSPARENT:=1)
	memdc := DllCall("CreateCompatibleDC", "Ptr", hDC)

	hOldFont := DllCall("SelectObject", "Ptr", hDC, "Ptr", g_hFont)
	hOldBmp := DllCall("SelectObject", "Ptr", memdc, "Ptr", hPicDC)

	DllCall("Gdi32.dll\BitBlt", "Ptr", hDC, "Int", 0, "Int", 0, "Int", Right - Left, "Int", Bottom - Top
					, "Ptr", memdc, "Int", Left, "Int", Top, "UInt", SRCCOPY := 0x00CC0020)

	ControlGet, sCurSel, Choice,,, ahk_id %g_hLB%

	; if (m_Shadow)
	VarSetCapacity(colorref, 24, 0)
	NumPut(255, colorref, 0, "char")
	NumPut(255, colorref, 8, "char")
	NumPut(255, colorref, 16, "char")

	DllCall("SetTextColor", "Ptr", hDC, "Ptr", &colorref)

	DllCall("OffsetRect", "ptr", &RectCopy, "uint", 0, "uint", (g_iOffset * iCurSelNdx) - 2)
	DllCall("DrawText", "ptr", hDC, "str", sCurSel, "uint", StrLen(sCurSel), "Ptr", &RectCopy, "uint", DT_LEFT:=0|DT_EXPANDTABS:=64|DT_NOPREFIX:=2048)
	DllCall("OffsetRect", "ptr", &RectCopy, "uint", 0, "uint", -(g_iOffset * iCurSelNdx) + 2)

	DllCall("SelectObject", "Ptr", hDC, "Ptr", hOldFont)
	DllCall("SelectObject", "Ptr", memdc, "Ptr", g_hOldBmp)

	DllCall("User32.dll\DeleteDC", "Ptr", memdc)
	return
}

; I believe LVProc is a substitute for OnPaint
LVProc:
{
	;~ DllCall("RedrawWindow", "Ptr", g_hLB, "Ptr", 0, "Ptr", 0, "UInt", RDW_INVALIDATE:=1 | RDW_ERASENOW:=0x200 | RDW_ERASE:=4)

	MyOnPaint()
	return
}

[Verdlin]

Ah! I believe I found a way around using CPaintDC. See this MSND CWnd::Begin/EndPaint.

 

Edit: Updated link from CWnd::BeginPaint to BeginPaint function

Edited by Verdlin, 20 August 2013 - 02:30 PM.

[Verdlin]

Another update: in this version, I believe I have properly worked around CPaintDC; however, I cannot figure out why hOldBmp is blank (from a SelectObject call); for all this script I've added, there is actually no visible change to the ListBox. I am hoping this is related to my problem with hOldBmp

 

Spoiler

Gui, New, hwndg_hMain
Gui, Add, Picture, x0 y0 w400 h400 hwndg_hPic, C:\Pic.jpg
Gui, Add, ListBox, x0 y0 w200 h200 hwndg_hLB vvLB gLVProc BackgroundTrans AltSubmit, One|Two|Three|Four|Five

SendMessage WM_GETFONT:=0x31,0,0,,ahk_id %g_hLB%
g_hFont := ErrorLevel
g_iOffset := 13 ; need to actually get the font height

LB_CB := RegisterCallback("LB_SubclassProc")
DllCall("Comctl32.dll\SetWindowSubclass", "Ptr", g_hLB, "Ptr", LB_CB, "Ptr", g_hLB, "Ptr", g_hPic)

Gui, Show, w400 h400

return

LB_SubclassProc(hWnd, uMsg, wParam, lParam, IdSubclass, RefData)
{
	global g_hLB, g_hMain, g_hLB, g_hPic, g_hFont, g_iOffset, g_hBmp
	static WM_ERASEBKGND := 20, WM_PAINT := 15, s_bHasBackground := false

	If (uMsg = WM_ERASEBKGND)
	{
		If (!s_bHasBackground)
		{
			hPic := RefData ; we passed the handle of the Pic control via RefData
			VarSetCapacity(Rect, 16, 0)
			DllCall("User32.dll\GetClientRect", "Ptr", hWnd, "Ptr", &Rect)
			DllCall("User32.dll\ClientToScreen", "Ptr", hWnd, "Ptr", &Rect)
			DllCall("User32.dll\ScreenToClient", "Ptr", hPic, "Ptr", &Rect)
			Left := NumGet(Rect, 0, "Int")
			Top := NumGet(Rect, 4, "Int")
			Right := NumGet(Rect, 8, "Int")
			Bottom := NumGet(Rect, 12, "Int")

			hLBDC := DllCall("User32.dll\GetDC", "Ptr", hWnd, "UPtr")
			hPicDC := DllCall("User32.dll\GetDC", "Ptr", hPic, "UPtr")

			DllCall("Gdi32.dll\BitBlt", "Ptr", hLBDC, "Int", 0, "Int", 0, "Int", Right - Left, "Int", Bottom - Top
							, "Ptr", hPicDC, "Int", Left, "Int", Top, "UInt", SRCCOPY := 0x00CC0020)

			g_hBmp := DllCall("Gdi32.dll\CreateCompatibleBitmap", "ptr", hPicDC, "uint", Right - Left, "uint", Bottom - Top)

			DllCall("User32.dll\ReleaseDC", "Ptr", hWnd, "Ptr", hLBDC)
			DllCall("User32.dll\ReleaseDC", "Ptr", hPic, "Ptr", hPicDC)
			DllCall("User32.dll\DeleteDC", "Ptr", memdc)

			s_bHasBackground := True
		}
			return true
	}
	return DllCall("Comctl32.dll\DefSubclassProc", "Ptr", hWnd, "UInt", uMsg, "Ptr", wParam, "Ptr", lParam)
}

MyOnPaint()
{
	global g_hLB, g_hMain, g_hLB, g_hPic, g_hFont, g_iOffset, g_hBmp
	static WM_ERASEBKGND := 20, WM_PAINT := 15, s_bHasBackground := false

	;~ HDC hdc; A_PtrSize
	;~ BOOL fErase; 4
	;~ RECT rcPaint; 16
	;~ BOOL fRestore; 4
	;~ BOOL fIncUpdate; 4
	;~ BYTE rgbReserved[32]; 32

	VarSetCapacity(hPaint, A_PtrSize + 4 + 16 + 4 + 4 + 32)
	hPaintDC := DllCall("BeginPaint", "ptr", g_hLB, "ptr", &hPaint)

	VarSetCapacity(ClientRect, 16, 0)
	DllCall("User32.dll\GetClientRect", "Ptr", g_hLB, "Ptr", &ClientRect)
	Left := NumGet(ClientRect, 0, "Int")
	Top := NumGet(ClientRect, 4, "Int")
	Right := NumGet(ClientRect, 8, "Int")
	Bottom := NumGet(ClientRect, 12, "Int")
	iW := Right - Left
	iH := Bottom - Top

	; Create memory DC's
	memdc := DllCall("CreateCompatibleDC", "Ptr", hPaintDC)
	memBmp := DllCall("Gdi32.dll\CreateCompatibleBitmap", "ptr", hPaintDC, "uint", iW, "uint", iH)

	hOldMemBmp := DllCall("SelectObject", "Ptr", memdc, "Ptr", membmp)

	; Paint the background bitmap on the memory dc
	hOldBmp := DllCall("SelectObject", "Ptr", hPaintDC, "Ptr", g_hBmp)
	Msgbox %hOldBmp%
	DllCall("Gdi32.dll\BitBlt", "Ptr", memdc, "Int", 0, "Int", 0, "Int", iW, "Int", iH
				, "Ptr", hPaintDC, "Int", 0, "Int", 0, "UInt", SRCCOPY := 0x00CC0020)
	DllCall("SelectObject", "Ptr", hPaintDC, "Ptr", hOldBmp)

	NumPut(0, ClientRect, 0, "int")
	NumPut(0, ClientRect, 4, "int")
	NumPut(iW, ClientRect, 8, "int")
	NumPut(iH + g_iOffset, ClientRect, 12, "int")

	ControlGet, sItems, List,,, ahk_id %g_hLB%
	StringSplit, aItems, sItems, `n, `r

	SendMessage, LB_GETCURSEL:=392, 0, 0,, ahk_id %g_hLB%
	iCurSel := ErrorLevel + 1
	SendMessage, LB_GETCOUNT:=395, 0, 0,, ahk_id %g_hLB%
	iCnt := ErrorLevel
	Loop %iCnt%
	{
		if (iCnt * g_iOffset > Bottom)
			break

		MyDrawItem(memdc, ClientRect, A_Index, A_Index == iCurSel)
		DllCall("OffsetRect", "ptr", &ClientRect, "uint", 0, "uint", g_iOffset - 2)
	}

	DllCall("Gdi32.dll\BitBlt", "Ptr", hPaintDC, "Int", 0, "Int", 0, "Int", iW, "Int", iH
				, "Ptr", memdc, "Int", Left, "Int", Top, "UInt", SRCCOPY := 0x00CC0020)
	DllCall("SelectObject", "Ptr", memdc, "Ptr", hOldMemBmp)

	DllCall("EndPaint", "ptr", g_hLB, "ptr", &hPaint)

	DllCall("User32.dll\DeleteDC", "Ptr", hPaintDC)
	DllCall("User32.dll\DeleteDC", "Ptr", memdc)

	return
}

MyDrawItem(ByRef hDC, ByRef Rect, iCurSelNdx, bSelected)
{
	global g_hLB, g_hMain, g_hLB, g_hPic, g_hFont, g_iOffset, g_hBmp
	static WM_ERASEBKGND := 20

	VarSetCapacity(RectCopy, 16, 0)
	Left := NumGet(Rect, 0, "Int")
	Top := NumGet(Rect, 4, "Int")
	Right := NumGet(Rect, 8, "Int")
	Bottom := NumGet(Rect, 12, "Int")
	NumPut(Left, RectCopy, 0, "int")
	NumPut(Top, RectCopy, 4, "int")
	NumPut(Right, RectCopy, 8, "int")
	NumPut(Bottom, RectCopy, 12, "int")
	Left2 := NumGet(RectCopy, 0, "Int")
	Right2 := NumGet(RectCopy, 8, "Int")

	DllCall("SetBMode", "ptr", hDC, "uint", TRANSPARENT:=1)
	memdc := DllCall("CreateCompatibleDC", "Ptr", hDC)

	hOldFont := DllCall("SelectObject", "Ptr", hDC, "Ptr", g_hFont)
	hOldBmp := DllCall("SelectObject", "Ptr", memdc, "Ptr", g_hBmp)
	DllCall("Gdi32.dll\BitBlt", "Ptr", hDC, "Int", Left, "Int", Top, "Int", Right - Left, "Int", Bottom - Top
					, "Ptr", memdc, "Int", Left, "Int", Top, "UInt", SRCCOPY := 0x00CC0020)

	ControlGet, sCurSel, Choice,,, ahk_id %g_hLB%

	VarSetCapacity(colorref, 24, 0)
	NumPut(255, colorref, 0, "char")
	NumPut(255, colorref, 8, "char")
	NumPut(255, colorref, 16, "char")
	DllCall("SetTextColor", "Ptr", hDC, "Ptr", &colorref)

	DllCall("DrawText", "ptr", hDC, "str", sCurSel, "uint", StrLen(sCurSel), "Ptr", &RectCopy, "uint", DT_LEFT:=0|DT_EXPANDTABS:=64|DT_NOPREFIX:=2048)

	DllCall("SelectObject", "Ptr", hDC, "Ptr", hOldFont)
	DllCall("SelectObject", "Ptr", memdc, "Ptr", hOldBmp)

	DllCall("User32.dll\DeleteDC", "Ptr", memdc)
	return
}

; I believe LVProc is a substitute for OnPaint
LVProc:
{
	;~ DllCall("RedrawWindow", "Ptr", g_hLB, "Ptr", 0, "Ptr", 0, "UInt", RDW_INVALIDATE:=1 | RDW_ERASENOW:=0x200 | RDW_ERASE:=4)

	MyOnPaint()
	return
}

[Verdlin]

Another update. hOldBmp was failing because I was trying to select the bitmap into a non-memory DC. Now that appears to be fixed, and I am successfully drawing text onto the ListBox.

Still, I cannot seem to copy the picture's bmp over when I draw the text, though.

 

I realize I'm doing some pretty messy, and in some cases, unnecessary stuff. I'm just trying to get a working example and then clean up the script from there.

 

Spoiler

GUI, New, hwndg_hMain
GUI, Add, Picture, x0 y0 w400 h400 hwndg_hPic, C:\Pic.jpg
GUI, Add, ListBox, x0 y0 w200 h200 hwndg_hLB vvLB gLVProc BackgroundTrans AltSubmit, One|Two|Three|Four|Five

SendMessage, WM_GETFONT:=0x31,0,0,,ahk_id %g_hLB%
g_hFont := ErrorLevel
g_iOffset := 13 ; need to actually get the font height

LB_CB := RegisterCallback("LB_SubclassProc")
DllCall("Comctl32.dll\SetWindowSubclass", "Ptr", g_hLB, "Ptr", LB_CB, "Ptr", g_hLB, "Ptr", g_hPic)

GUI, Show, w400 h400
MyOnPaint()
return

LB_SubclassProc(hWnd, uMsg, wParam, lParam, IdSubclass, RefData)
{
    global g_hLB, g_hMain, g_hLB, g_hPic, g_hFont, g_iOffset, g_hBmp
    static WM_ERASEBKGND := 20, WM_PAINT := 15, s_bHasBackground := false

    If (uMsg = WM_ERASEBKGND)
    {
        If (!s_bHasBackground)
        {
            hPic := RefData ; we passed the handle of the Pic control via RefData
            VarSetCapacity(Rect, 16, 0)
            DllCall("User32.dll\GetClientRect", "Ptr", hWnd, "Ptr", &Rect)
            DllCall("User32.dll\ClientToScreen", "Ptr", hWnd, "Ptr", &Rect)
            DllCall("User32.dll\ScreenToClient", "Ptr", hPic, "Ptr", &Rect)
            Left := NumGet(Rect, 0, "Int")
            Top := NumGet(Rect, 4, "Int")
            Right := NumGet(Rect, 8, "Int")
            Bottom := NumGet(Rect, 12, "Int")

            hLBDC := DllCall("User32.dll\GetDC", "Ptr", hWnd, "UPtr")
            hPicDC := DllCall("User32.dll\GetDC", "Ptr", hPic, "UPtr")

            ; Save the old bitmap *before* we draw over it
            g_hBmp := DllCall("Gdi32.dll\CreateCompatibleBitmap", "ptr", hPicDC, "int", Right - Left, "int", Bottom - Top)

            DllCall("Gdi32.dll\BitBlt", "Ptr", hLBDC, "Int", 0, "Int", 0, "Int", Right - Left, "Int", Bottom - Top
                            , "Ptr", hPicDC, "Int", Left, "Int", Top, "UInt", SRCCOPY := 0x00CC0020)

            DllCall("User32.dll\ReleaseDC", "Ptr", hWnd, "Ptr", hLBDC)
            DllCall("User32.dll\ReleaseDC", "Ptr", hPic, "Ptr", hPicDC)
            DllCall("User32.dll\DeleteDC", "Ptr", MemDC)

            s_bHasBackground := true
        }
            return true
    }
    return DllCall("Comctl32.dll\DefSubclassProc", "Ptr", hWnd, "UInt", uMsg, "Ptr", wParam, "Ptr", lParam)
}

MyOnPaint()
{
    global g_hLB, g_hMain, g_hLB, g_hPic, g_hFont, g_iOffset, g_hBmp
    static WM_ERASEBKGND := 20, WM_PAINT := 15, s_bHasBackground := false

    ;~ HDC hdc; A_PtrSize
    ;~ BOOL fErase; 4
    ;~ RECT rcPaint; 16
    ;~ BOOL fRestore; 4
    ;~ BOOL fIncUpdate; 4
    ;~ BYTE rgbReserved[32]; 32

    VarSetCapacity(hPaint, A_PtrSize + 4 + 16 + 4 + 4 + 32)
    hPaintDC := DllCall("BeginPaint", "ptr", g_hLB, "ptr", &hPaint)

    VarSetCapacity(ClientRect, 16, 0)
    DllCall("User32.dll\GetClientRect", "Ptr", g_hLB, "Ptr", &ClientRect)
    Left := NumGet(ClientRect, 0, "Int")
    Top := NumGet(ClientRect, 4, "Int")
    Right := NumGet(ClientRect, 8, "Int")
    Bottom := NumGet(ClientRect, 12, "Int")
    iW := Right - Left
    iH := Bottom - Top

    ;~ hPicDC := DllCall("User32.dll\GetDC", "Ptr", g_hPic, "UPtr")
    hLBDC := DllCall("User32.dll\GetDC", "Ptr", g_hLB, "UPtr")

    ; Create memory DC's
    MemDC := DllCall("CreateCompatibleDC", "Ptr", hPaintDC)
    MemBmp := DllCall("Gdi32.dll\CreateCompatibleBitmap", "ptr", hPaintDC, "int", iW, "int", iH)

    hOldMemBmp := DllCall("SelectObject", "Ptr", MemDC, "Ptr", MemBmp)

    ; Paint the background bitmap on the memory dc
    hOldBmp := DllCall("SelectObject", "Ptr", MemDC, "Ptr", g_hBmp)
    DllCall("Gdi32.dll\BitBlt", "Ptr", MemDC, "Int", 0, "Int", 0, "Int", iW, "Int", iH
                , "Ptr", hPaintDC, "Int", 0, "Int", 0, "UInt", SRCCOPY := 0x00CC0020)
    DllCall("SelectObject", "Ptr", hPaintDC, "Ptr", hOldBmp)

    NumPut(0, ClientRect, 0, "int")
    NumPut(0, ClientRect, 4, "int")
    NumPut(iW, ClientRect, 8, "int")
    NumPut(iH + g_iOffset, ClientRect, 12, "int")

    SendMessage, LB_GETCURSEL:=392, 0, 0,, ahk_id %g_hLB%
    iCurSel := ErrorLevel + 1
    SendMessage, LB_GETCOUNT:=395, 0, 0,, ahk_id %g_hLB%
    iCnt := ErrorLevel
    Loop %iCnt%
    {
        if (iCnt * g_iOffset > Bottom)
            break

        MyDrawItem(hLBDC, hOldBmp, ClientRect, A_Index, A_Index == iCurSel)
        DllCall("OffsetRect", "ptr", &ClientRect, "uint", 0, "uint", g_iOffset )
    }

    DllCall("Gdi32.dll\BitBlt", "Ptr", hPaintDC, "Int", 0, "Int", 0, "Int", iW, "Int", iH
                , "Ptr", MemDC, "Int", 0, "Int", 0, "UInt", SRCCOPY := 0x00CC0020)

    DllCall("SelectObject", "Ptr", MemDC, "Ptr", hOldMemBmp)

    DllCall("EndPaint", "ptr", g_hLB, "ptr", &hPaint)

    DllCall("User32.dll\DeleteDC", "Ptr", hPaintDC)
    DllCall("User32.dll\DeleteDC", "Ptr", hOldMemDC)
    DllCall("User32.dll\DeleteDC", "Ptr", MemDC)

    return
}

MyDrawItem(ByRef hDC, ByRef hOldBmp, ByRef Rect, iCurSelNdx, bSelected)
{
    global g_hLB, g_hMain, g_hLB, g_hPic, g_hFont, g_iOffset, g_hBmp
    static WM_ERASEBKGND := 20

    VarSetCapacity(RectCopy, 16, 0)
    Left := NumGet(Rect, 0, "Int")
    Top := NumGet(Rect, 4, "Int")
    Right := NumGet(Rect, 8, "Int")
    Bottom := NumGet(Rect, 12, "Int")
    NumPut(Left, RectCopy, 0, "int")
    NumPut(Top, RectCopy, 4, "int")
    NumPut(Right, RectCopy, 8, "int")
    NumPut(Bottom, RectCopy, 12, "int")

    DllCall("SetBkMode", "ptr", hDC, "uint", TRANSPARENT:=1)
    MemDC := DllCall("CreateCompatibleDC", "Ptr", hDC)

    hOldFont := DllCall("SelectObject", "Ptr", hDC, "Ptr", g_hFont)
    DllCall("Gdi32.dll\BitBlt", "Ptr", hDC, "Int", Left, "Int", Top, "Int", Right - Left, "Int", Bottom - Top
                    , "Ptr", MemDC, "Int", Left, "Int", Top, "UInt", SRCCOPY := 0x00CC0020)

    ControlGet, sCurSel, Choice,,, ahk_id %g_hLB%
    ControlGet, sItems, List,,, ahk_id %g_hLB%
    StringSplit, aItems, sItems, `n, `r
    sCurItem := aItems%iCurSelNdx%

    ; if (m_Shadow)
    VarSetCapacity(colorref, 24, 0)
    NumPut(255, colorref, 0, "char")
    NumPut(255, colorref, 8, "char")
    NumPut(255, colorref, 16, "char")
    DllCall("SetTextColor", "Ptr", hDC, "Ptr", &colorref)

    ;~ DllCall("OffsetRect", "ptr", &RectCopy, "uint", 0, "uint", (g_iOffset * iCurSelNdx) - 2)
    ;~ Msgbox % DllCall("DrawText", "ptr", hDC, "str", sCurSel, "uint", StrLen(sCurSel), "Ptr", &RectCopy, "uint", DT_LEFT:=0|DT_EXPANDTABS:=64|DT_NOPREFIX:=2048) "`n" iCurSelNdx "`n" sCurSel "`n" Left "`n" Right "`n" Top "`n" Bottom "`n" hDC "`n" MemDC "`n" holdfont "`n" hOldbmp
    DllCall("DrawText", "ptr", hDC, "str", sCurItem, "uint", StrLen(sCurItem), "Ptr", &RectCopy, "uint", DT_LEFT:=0|DT_EXPANDTABS:=64|DT_NOPREFIX:=2048)
    ;~ DllCall("OffsetRect", "ptr", &RectCopy, "uint", 0, "uint", -(g_iOffset * iCurSelNdx) + 2)

    DllCall("SelectObject", "Ptr", hDC, "Ptr", hOldFont)
    DllCall("SelectObject", "Ptr", MemDC, "Ptr", hOldBmp)

    DllCall("User32.dll\DeleteDC", "Ptr", hOldMemDC)
    DllCall("User32.dll\DeleteDC", "Ptr", MemDC)
    return
}

; I believe LVProc is a substitute for OnPaint
LVProc:
{
    ;~ DllCall("RedrawWindow", "Ptr", g_hLB, "Ptr", 0, "Ptr", 0, "UInt", RDW_INVALIDATE:=1 | RDW_ERASENOW:=0x200 | RDW_ERASE:=4)
    MyOnPaint()
    ;~ Winset, Redraw,, ahk_id %g_hMain%
    return
}

 

@

 

Only if you don't mind, would you mind taking a look at this revised version?

Edited by Verdlin, 21 August 2013 - 06:04 PM.

[Verdlin]

Bumping for visibility. I admit, I haven't spent much time on this since the last revision; however, I am hoping this will catch someone's interest who is willing to take a stab at it

[just me]

Well, I've spent some time again and it seems that I made some progress. The following seems to work pretty stable, but there are some restrictions:

1. The ListBox is very static. You must not change the position, the size, or the contents after creating the instance.
    
2. I had to suppress some messages, so the gLabel is rather useless.
    
3. You cannot move using Down or Up keys so far.

There might be other issues I didn't notice as yet. I will try to make things more comfortable and publish the class in 'Scripts' as soon as it seems to be reliable.

 

Spoiler

#NoEnv
PicFile := A_WinDir . "\Web\Wallpaper\Blaues Fenster.jpg" ; German Win XP
Content := "One|Two|Three|Four|Five|Six|Seven|Eight|Nine|Ten|Eleven|Twelve|Thirteen"
; PicFile := A_WinDir . "\Web\Wallpaper\HP1.jpg" ; HP Win 7
; LBS_OWNERDRAWFIXED = 0x0010
; LBS_HASSTRINGS     = 0x0040
Gui, New, hwndhMain
Gui, Add, Picture, x0 y0 w600 h400 hwndhPic, %PicFile%
Gui, Add, ListBox, x50 y50 w200 r6 Choose1, %Content%
Gui, Add, ListBox, x+100 yp wp hp hwndhLB vLB Choose1, %Content%
Gui, Add, Button, x350 y+20 gSelection, Selected?
TLB := New TransparentListBox(hLB, hPic, 0xFFFFFF, 0xFFFF00) ; Colors have to be BGR
Gui, Show, w600 h400, Transparent ListBox
Return

GuiClose:
ExitApp

Selection:
GuiControlGet, LB
MsgBox, 0, You selected:, %LB%
Return

Class TransparentListBox {
   ; -------------------------------------------------------------------------------------------------------------------
   ; Constructor
   ; -------------------------------------------------------------------------------------------------------------------
   __New(HLB, HBG, TxtColor, SelColor) {
      ; ----------------------------------------------------------------------------------------------------------------
      ; HLB      : HWND of the ListBox
      ; HBG      : HWND of the control containing the background
      ; TxtColor : text color (BGR integer value, e.g. 0xBBGGRR)
      ; SelColor : selected text color (BGR integer value, e.g. 0xBBGGRR)
      ; ----------------------------------------------------------------------------------------------------------------
      Static LB_GETITEMHEIGHT := 0x01A1
      Static WM_GETFONT       := 0x0031
      Static SRCCOPY := 0x00CC0020
      This.HLB := HLB
      This.HBG := HBG
      This.TxtColor  := TxtColor
      This.SelColor  := SelColor
      SendMessage, %LB_GETITEMHEIGHT%, 0, 0, , ahk_id %HLB%
      This.ItemHeight := ErrorLevel
      SendMessage, %WM_GETFONT%, 0, 0, , ahk_id %HLB%
      This.Font := ErrorLevel
      This.HasBackground := False
      This.TopIndex := -1
      This.CurSel   := -1
      ; LBS_OWNERDRAWFIXED = 0x0010, LBS_HASSTRINGS = 0x0040, LBS_NOSEL = 0x4000
      WinSet, Style, +0x4050, ahk_id %HLB%
      SCCB := RegisterCallback("TransparentListBox.SubClassCallback")
      DllCall("Comctl32.dll\SetWindowSubclass", "Ptr", HLB, "Ptr", SCCB, "Ptr", HLB, "Ptr", Object(This))
      This.SCCB := SCCB
   }
   ; -------------------------------------------------------------------------------------------------------------------
   ; Destructor
   ; -------------------------------------------------------------------------------------------------------------------
   __Delete() {
      If (This.Font) {
         DllCall("Gdi32.dll\DeleteObject", "Ptr", This.FONT)
         This.Font := 0
      }
      If (This.BMPDC) {
         DllCall("Gdi32.dll\DeleteDC", "Ptr", This.BMPDC)
         DllCall("Gdi32.dll\DeleteObject", "Ptr", This.HBMP)
         This.BMPDC := This.HBMP := 0
      }
      If (This.MEMDC) {
         DllCall("Gdi32.dll\DeleteDC", "Ptr", This.MEMDC)
         DllCall("Gdi32.dll\DeleteObject", "Ptr", This.HMEM)
         This.MEMDC := This.HMEM := 0
      }
      If (This.HLB) {
         DllCall("Comctl32.dll\RemoveWindowSubclass", "Ptr", This.HLB, "Ptr", This.SCCB, "Ptr", This.HLB)
         This.HLB := 0
      }
   }
   ; -------------------------------------------------------------------------------------------------------------------
   ; Subclass callback function
   ; -------------------------------------------------------------------------------------------------------------------
   SubClassCallback(uMsg, wParam, lParam, IdSubclass, RefData) {
      Critical 50
      hWnd := This ; first parameter 'hWnd' is passed as 'This'
      Return Object(RefData).SubClassProc(hWnd, uMsg, wParam, lParam)
   }
   ; -------------------------------------------------------------------------------------------------------------------
   ; Subclassproc
   ; -------------------------------------------------------------------------------------------------------------------
   SubClassProc(hWnd, uMsg, wParam, lParam) {
      Static LB := {GETCOUNT: 0x018B, GETCURSEL: 0x0188, GETITEMRECT: 0x0198, GETTEXT: 0x0189,GETTEXTLEN: 0x018A
                  , GETTOPINDEX: 0x018E, ITEMFROMPOINT: 0x01A9, SETCURSEL: 0x0186}
      Static WM := {DESTROY: 0x0002, DRAWITEM: 0x002B, LBUTTONDBLCLK: 0x0203, ERASEBKGND: 0x0014, KEYDOWN: 0x0100
                  , KILLFOCUS: 0x0008, LBUTTONDOWN: 0x0201, LBUTTONUP: 0x0202, MOUSEWHEEL: 0x020A, PAINT: 0x000F
                  , SETFOCUS: 0x0007, SETREDRAW: 0x000B, VSCROLL: 0x0115}
      Static SRCCOPY := 0x00CC0020
      ; WM_PAINT message -----------------------------------------------------------------------------------------------
      If (uMsg = WM.PAINT) { ; fully processed
         VarSetCapacity(PAINTSTRUCT, A_PtrSize + (4 * 7) + 32 + (A_PtrSize - 4), 0)
         LBDC := DllCall("USer32.dll\BeginPaint", "Ptr", This.HLB, "Ptr", &PAINTSTRUCT, "UPtr")
         SendMessage, % LB.GETCOUNT, 0, 0, , ahk_id %hWnd%
         IC := ErrorLevel ; item count
         SendMessage, % LB.GETCURSEL, 0, 0, , ahk_id %hWnd%
         CS := ErrorLevel ; current selection
         SendMessage, % LB.GETTOPINDEX, 0, 0, , ahk_id %hWnd%
         TI := ErrorLevel ; top index
         If (TI <> This.TopIndex) || (CS <> This.CurSel) {
            This.TopIndex := TI
            This.CurSel := CS
            DllCall("Gdi32.dll\BitBlt", "Ptr", This.MEMDC, "Int", 0, "Int", 0, "Int", This.Width, "Int", This.Height
                                      , "Ptr", This.BMPDC, "Int", 0, "Int", 0, "UInt", SRCCOPY)
            OFONT := DllCall("Gdi32.dll\SelectObject", "Ptr", This.MEMDC, "Ptr", This.Font, "UPtr")
            DllCall("Gdi32.dll\SetBkMode", "Ptr", This.MEMDC, "Int", 1) ; TRANSPARENT
            VarSetCapacity(RECT, 16, 0)
            SendMessage, % LB.GETITEMRECT, %TI%, &RECT, , ahk_id %hWnd%
            NumPut(NumGet(RECT, 0, "Int") + 3, RECT, 0, "Int")
            While (TI < IC) && (NumGet(RECT, 12, "Int") <= This.Height) {
               SendMessage, % LB.GETTEXTLEN, %TI%, 0, , ahk_id %hWnd%
               TL := ErrorLevel
               VarSetCapacity(TXT, TL << !!A_IsUnicode, 0)
               SendMessage, % LB.GETTEXT, %TI%, &TXT, , ahk_id %hWnd%
               TextColor := (TI = CS ? This.SelColor : This.TxtColor)
               DllCall("Gdi32.dll\SetTextColor", "Ptr", This.MEMDC, "UInt", TextColor)
               DllCall("User32.dll\DrawText", "Ptr", This.MEMDC, "Ptr", &TXT, "Int", TL, "Ptr", &RECT, "UInt", 0)
               DllCall("User32.dll\OffsetRect", "Ptr", &RECT, "Int", 0, "Int", This.ItemHeight)
               TI++
            }
            DllCall("Gdi32.dll\SelectObject", "Ptr", MEMDC, "Ptr", OFONT, "UPtr")
         }
         DllCall("Gdi32.dll\BitBlt", "Ptr", LBDC, "Int", 0, "Int", 0, "Int", This.Width, "Int", This.Height
                                   , "Ptr", This.MEMDC, "Int", 0, "Int", 0, "UInt", SRCCOPY)
         DllCall("User32.dll\EndPaint", "Ptr", &PAINTSTRUCT)
         Return 0
      }
      ; WM_DRAWITEM message --------------------------------------------------------------------------------------------
      If (uMsg = WM.DRAWITEM) ; not processed
         Return True
      ; WM_LBUTTONDOWN and WM_LBUTTONDBLCLK messages -------------------------------------------------------------------
      If (uMsg = WM.LBUTTONDOWN) Or (uMsg = WM.LBUTTONDBLCLK) { ; partially processed
         ControlFocus, , ahk_id %hWnd%
         Return 0
      }
      ; WM_MOUSEWHEEL message ------------------------------------------------------------------------------------------
      If (uMsg = WM.MOUSEWHEEL) { ; partially processed
         PostMessage, % WM.VSCROLL, % ((wParam >> 16) > 0x7FFF ? 1 : 0), 0, , ahk_id %hWnd%
         Return 0
      }
      ; WM_KILLFOCUS and WM_SETFOCUS messages --------------------------------------------------------------------------
      If (uMsg = WM.KILLFOCUS) Or (uMsg = WM.SETFOCUS) ; not processed
         Return 0
      ; WM_KEYDOWN message --------------------------------------------------------------------------------------------
      If (uMsg = WM.KEYDOWN) ; not processed
         Return 0
      ; WM_LBUTTONUP message -------------------------------------------------------------------------------------------
      If (uMsg = WM.LBUTTONUP) { ; partially processed
         SendMessage, % LB.ITEMFROMPOINT, 0, %lParam%, , ahk_id %hWnd%
         Item := ErrorLevel
         If !(Item & 0xFFFF0000) {
            SendMessage, % WM.SETREDRAW, 0, 0, , ahk_id %hWnd%
            SendMessage, % LB.SETCURSEL, %Item%, 0, , ahk_id %hWnd%
            SendMessage, % WM.SETREDRAW, 1, 0, , ahk_id %hWnd%
            DllCall("User32.dll\RedrawWindow", "Ptr", hWnd, "Ptr", 0, "Ptr", 0, "UInt", 0x0501)
         }
         Return 0
      }
      ; WM_VSCROLL message ---------------------------------------------------------------------------------------------
      If (uMsg = WM.VSCROLL) { ; partially processed
         SendMessage, % WM.SETREDRAW, 0, 0, , ahk_id %hWnd%
         DllCall("Comctl32.dll\DefSubclassProc", "Ptr", hWnd, "UInt", uMsg, "Ptr", wParam, "Ptr", lParam)
         SendMessage, % WM.SETREDRAW, 1, 0, , ahk_id %hWnd%
         SendMessage, % LB.GETTOPINDEX, 0, 0, , ahk_id %hWnd%
         DllCall("User32.dll\RedrawWindow", "Ptr", hWnd, "Ptr", 0, "Ptr", 0, "UInt", 0x0501)
         Return 0
      }
      ; WM_ERASEBKGND message ------------------------------------------------------------------------------------------
      If (uMsg = WM.ERASEBKGND) {
         If (!This.HasBackground) { ; processed for first message
            VarSetCapacity(RECT, 16, 0)
            DllCall("User32.dll\GetClientRect", "Ptr", This.HLB, "Ptr", &RECT)
            This.Width := W := NumGet(RECT, 8, "Int")
            This.Height := H := NumGet(RECT, 12, "Int")
            DllCall("User32.dll\ClientToScreen", "Ptr", This.HLB, "Ptr", &RECT)
            DllCall("User32.dll\ScreenToClient", "Ptr", This.HBG, "Ptr", &RECT)
            This.Left := NumGet(RECT, 0, "Int")
            This.Top := NumGet(RECT, 4, "Int")
            BGDC := DllCall("User32.dll\GetDC", "Ptr", This.HBG, "UPtr")
            BMPDC := DllCall("Gdi32.dll\CreateCompatibleDC", "Ptr", BGDC, "UPtr")
            HBMP := DllCAll("Gdi32.dll\CreateCompatibleBitmap", "Ptr", BGDC, "Int", W, "Int", H, "UPtr")
            DllCall("Gdi32.dll\SelectObject", "Ptr", BMPDC, "Ptr", HBMP)
            MEMDC := DllCall("Gdi32.dll\CreateCompatibleDC", "Ptr", BGDC, "UPtr")
            HMEM := DllCAll("Gdi32.dll\CreateCompatibleBitmap", "Ptr", BGDC, "Int", W, "Int", H, "UPtr")
            DllCall("Gdi32.dll\SelectObject", "Ptr", MEMDC, "Ptr", HMEM)
            DllCall("Gdi32.dll\BitBlt", "Ptr", BMPDC, "Int", 0, "Int", 0, "Int", W, "Int", H
                                      , "Ptr", BGDC, "Int", This.Left, "Int", This.Top, "UInt", SRCCOPY)
            DllCall("User32.dll\ReleaseDC", "Ptr", This.HBG, "Ptr", BGDC)
            This.BMPDC := BMPDC
            This.HBMP := HBMP
            This.MEMDC := MEMDC
            This.HMEM := HMEM
            LBDC := DllCall("User32.dll\GetDC", "Ptr", hWnd, "UPtr")
            DllCall("Gdi32.dll\BitBlt", "Ptr", LBDC, "Int", 0, "Int", 0, "Int", W, "Int", H
                                      , "Ptr", This.BMPDC, "Int", 0, "Int", 0, "UInt", SRCCOPY)
            DllCall("User32.dll\ReleaseDC", "Ptr", hWnd, "Ptr", LBDC)
            This.HasBackground := True
         }
         Return True
      }
      ; WM_DESTROY message ---------------------------------------------------------------------------------------------
      If (uMsg = WM.DESTROY) { ; fully processed
         This.__Delete()
      }
      Return DllCall("Comctl32.dll\DefSubclassProc", "Ptr", hWnd, "UInt", uMsg, "Ptr", wParam, "Ptr", lParam)
   }
}