AutoHotkey Community

;; check for files that ARE on h:\ that are NOT on g:\
;; does NOT perform a copy ! only informs what WOULD be copied :)

RunWait , %comspec% /c xcopy h:\*.* g:\*.* /s /y /d /l >> difference.txt , , hide

msgbox Done

;~ dir1 = D:\www\ZC-1.3.7\includes\languages\english
;~ dir2 = D:\www\ZC-1.3.7\includes\languages\french
dir1 = E:\javalib1
dir2 = E:\javalib2
;~ fileMask = *.php
fileMask = *.jar

Loop %dir1%\%fileMask%
{
   fileList1 .= A_LoopFileName . "`n"
   fnb1 := A_Index
}
StringTrimRight fileList1, fileList1, 1

Loop %dir2%\%fileMask%
{
   fileList2 .= A_LoopFileName . "`n"
   fnb2 := A_Index
}
StringTrimRight fileList2, fileList2, 1

Sort fileList1
Sort fileList2
StringSplit files_1_, fileList1, `n
StringSplit files_2_, fileList2, `n
idxF1 := idxF2 := 1

Loop
{
   If (files_1_%idxF1% = files_2_%idxF2%)
   {
      ; We are in synch
      list1 .= files_1_%idxF1% . "|"
      idxF1++
      list2 .= files_2_%idxF2% . "|"
      idxF2++
   }
   Else
   {
      ; Either file at idxF1 or at idxF3 is missing, we must find which one
      If (files_1_%idxF1% > files_2_%idxF2%)
      {
         ; Missing in first list
         list1 .= " |"   ; Empty
         list2 .= files_2_%idxF2% . "|"
         idxF2++
      }
      Else
      {
         ; Missing in second list
         list1 .= files_1_%idxF1% . "|"
         idxF1++
         list2 .= " |"   ; Empty
      }
   }
   If (idxF1 > fnb1)
   {
      Loop % fnb2 - idxF2 + 1
      {
         list1 .= " |"   ; Empty
         list2 .= files_2_%idxF2% . "|"
         idxF2++
      }
      Break
   }
   If (idxF2 > fnb2)
   {
      Loop % fnb1 - idxF1 + 1
      {
         list1 .= files_1_%idxF1% . "|"
         idxF1++
         list2 .= " |"   ; Empty
      }
      Break
   }
}

StringTrimRight list1, list1, 1
Gui Add, ListBox, w200 r20 vfiles1, %list1%
StringTrimRight list2, list2, 1
Gui Add, ListBox, x+20 w200 r20 vfiles2, %list2%

Gui Add, Button, w50 gGuiOK default, OK
Gui Add, Button, x+50 w50 gGuiClose, Cancel
Gui Show, w500
Return

GuiOK:
GuiClose:
GuiEscape:
ExitApp