AutoHotkey Community

;*************from the help file**************
Gui, Add, ListView, r20 w700 Checked vlist1, Name|Size (KB)
; Gather a list of file names from a folder and put them into the ListView:
Loop, %A_MyDocuments%\*.*
    LV_Add("", A_LoopFileName, A_LoopFileSizeKB)
;****************************************
Gui,Add,Button, ggo, go
Gui, Show
return

go:
   toggle := !toggle
   if(toggle)
   {   gosub getLVchecks
      GuiControl,-LV0x4,SysListView321   ;turn off checks
   }
   Else
   {   GuiControl,+LV0x4,SysListView321   ;turn on checks
      gosub setLVchecks
   }
Return

setLVchecks:   ;read setting from LV
   Loop,parse, LV,CSV
   {   If(A_LoopField = A_Index)   ;Weird! Empties return next one that's checked!
      {   LV_Modify(A_Index, "Check")   ; Must make sure it's the right one.
      }
   }
   LV=
Return

getLVchecks:   ;save setting to LV var
   Loop % LV_GetCount()
   {   LV .= LV_GetNext(A_Index-1,"C") . ","
   }
Return

guiClose:
   ExitApp
Return

LVM_SETITEMSTATE = 4139
/*
typedef struct _LVITEM {
    UINT mask;
    int iItem;
    int iSubItem;
    UINT state;     -> offset 12
    UINT stateMask; -> offset 16
    LPTSTR pszText;
    int cchTextMax;
    int iImage;
    LPARAM lParam;
#if (_WIN32_IE >= 0x0300)
    int iIndent;
#endif
#if (_WIN32_WINNT >= 0x560)
    int iGroupId;
    UINT cColumns; // tile view columns
    PUINT puColumns;
#endif
#if (_WIN32_WINNT >= 0x0600)
    int* piColFmt;
    int iGroup;
#endif
} LVITEM, *LPLVITEM;
*/
VarSetCapacity(LVItem, 36, 0)

;*************from the help file**************
Gui, Add, ListView, r20 w700 Checked vlist1, Name|Size (KB)
; Gather a list of file names from a folder and put them into the ListView:
Loop, %A_MyDocuments%\*.*
    LV_Add("", A_LoopFileName, A_LoopFileSizeKB)
;****************************************
Gui,Add,Button, gGo, Go!
Gui, Show
return

Go:
   SetInteger(LVItem, 0xF000, 16)  ; LVITEM->stateMask = LVIS_STATEIMAGEMASK
   Loop % LV_GetCount()
   {
      m := Mod(A_Index, 3)
      If (m = 0)
      {
         SetInteger(LVItem, 0x0000, 12)  ; LVITEM->state = disabled
      }
      Else If (m = 1)
      {
         SetInteger(LVItem, 0x1000, 12)  ; LVITEM->state = unchecked
      }
      Else If (m = 2)
      {
         SetInteger(LVItem, 0x2000, 12)  ; LVITEM->state = checked
      }
      SendMessage LVM_SETITEMSTATE, A_Index - 1, &LVItem, SysListView321, A
   }
Return

GuiClose:
ExitApp

SetInteger(ByRef @dest, _integer, _offset = 0, _size = 4)
{
   Loop %_size%  ; Copy each byte in the integer into the structure as raw binary data.
   {
      DllCall("RtlFillMemory"
            , "UInt", &@dest + _offset + A_Index-1
            , "UInt", 1
            , "UChar", (_integer >> 8*(A_Index-1)) & 0xFF)
   }
}

Gui,+LastFound
guiID := WinExist()
SysGet, SM_CXVSCROLL, 2   ;width of vert scrollbar - to fudge the width of the checkbox of listview

;*************from the help file**************
Gui, Add, ListView, r20 w700 Checked vFILEINFORMATION glistClick AltSubmit, Name|Size (KB)   ;AltSubmit
; Gather a list of file names from a folder and put them into the ListView:
Loop, %A_MyDocuments%\*.*
{   LV_Add("", A_LoopFileName, A_LoopFileSizeKB)
}
LV_ModifyCol() 
;****************************************
Gui,Add,Checkbox, vLVdisable gLVdisable, Listbox Disable
Gui, Show
OnMessage(0x201,"WM_LBUTTONDOWN")
return

listClick:
   If(A_GuiEvent = "I")
   {   If(fake=1)   ;try to ignore events we've created
      {   fake=0
         Return
      }
      MouseGetPos,lx
      ControlGetPos,ox,,,,SysListView321,ahk_id %guiID%
      ControlGet, LVf, List, Count Focused, SysListView321
      xc := SM_CXVSCROLL+ox+10   ;guesstimate the width of the check
      ;if the row with focus is the same as in eventinfo and not too far right and disabled
      If((A_EventInfo = LVf) and lx <= xc) and (LVdisable)
      {   LVc := LV_GetNext(LVf-1,"C")
         If(LVc = LVf)
         {   fake=1
            LV_Modify(LVf, "-Check")
         }
         Else
         {   fake=1
            LV_Modify(LVf, "Check")
         }
      }
   }
Return

WM_LBUTTONDOWN()   ;this just selects the row if checkbox clicked
{
   global
   MouseGetPos,lx,ly,outW,outK
   if(outW = guiID) and (outK = "SysListView321")   ;over the listview
   {   ControlGetPos,ox,oy,,,SysListView321,ahk_id %guiID%
      cx := ox + 50
      cy := ly
      fake=1
      ControlClick,x%cx% y%cy%,ahk_id %guiID%
   }
}

LVdisable:
   Gui, Submit, NoHide
Return

guiClose:
   ExitApp
Return