AutoHotkey Community

;
; Get list of installed printers
;
list := GetInstalledPrinters()
;
; Prompt for default printer
;
;msgbox, % list
Gui, Add, Text, ,Choose new default printer
Gui, Add, DDL, w300 vNewDefault, %list%
Gui, Add, Button, , Save
Gui, Add, Button, , Cancel
gui, show
return



ButtonSave:
Gui, Submit
SetDefaultPrinter(NewDefault)
Msgbox, %NewDefault% is now your default printer
;falls through to exitapp

ButtonCancel:
GuiClose:
exitapp

;Functions
SetDefaultPrinter(sPrinter)
{     
         DllCall(A_WinDir . "\system\winspool.drv\SetDefaultPrinterA", "str", sPrinter)
}

GetInstalledPrinters(Delimiter="|",Default=True)
{
   if (Default = True)
   {
      regread,defaultPrinter,HKCU,Software\Microsoft\Windows NT\CurrentVersion\Windows,device
      stringsplit,defaultName,defaultPrinter,`,
      defaultName := defaultName1
      printerlist =
      loop,HKCU,Software\Microsoft\Windows NT\CurrentVersion\devices
      {
         if (A_LoopRegName = defaultname)
           printerlist = %printerlist%%A_loopRegName%%Delimiter%%Delimiter%
         else
           printerlist = %printerlist%%A_loopRegName%%Delimiter%
      }
   }
   else
   {
      printerlist =
      loop,HKCU,Software\Microsoft\Windows NT\CurrentVersion\devices
      {
         printerlist = %printerlist%%A_loopRegName%%Delimiter%
      }
   }
   StringTrimRight, printerlist, printerlist, StrLen(Delimiter)
   return %printerlist%
}
return