It seems most of the flickering is actually caused by GuiControl
invalidating the GUI itself. Try using STM_SETICON (0x170) or STM_SETIMAGE (0x172) to set the icon/bitmap instead. You'll probably find that it flickers much less, but still occasionally flickers. LoadImage() can be used to get a HICON from file.
Quote:
improved the examples so they flicker less
I'm curious... how?
Sometimes the only way to remove flicker entirely is to do all the drawing yourself (i.e. handle WM_PAINT.) For some controls you can cheat by printing the control into a buffer (an in-memory bitmap) using PrintWindow or WM_PRINT, then painting the buffer onto the window.
Edit: The remaining flicker happens because the picture control paints the background each time it paints the icon. Since it does both operations directly on the window, occasionally the window updates after the background is drawn, but before the icon is finished. The solution is to override WM_PAINT.
The following example should be entirely flicker-free:
Code:
Gui, Add, Picture, vIcon hwndhPic w256 h256 icon4, %A_AhkPath%
WindowProcNew := RegisterCallback("WindowProc")
WindowProcOld := DllCall("SetWindowLong","uint",hPic,"int",-4,"int",WindowProcNew,"uint")
Gui, Show
SetTimer, switch, 100
Return
switch:
; Load an icon from the current executable.
hicon := DllCall("LoadImage","uint",DllCall("GetModuleHandle","uint",0)
,"uint",(s:=!s) ? 208:207,"uint",1,"int",256,"int",256,"uint",0)
if !hicon
return
; Set the icon.
SendMessage, 0x170, hicon,,, ahk_id %hPic%
; Destroy the previous icon.
if ErrorLevel
DllCall("DestroyIcon","uint",ErrorLevel)
return
GuiClose:
ExitApp
WindowProc(hwnd, uMsg, wParam, lParam)
{
global WindowProcOld
Critical 500 ; Must ensure AutoHotkey doesn't check for messages.
if (uMsg = 0x14)
return 1
if (uMsg = 0xF)
{
WinGetPos,,, w, h, ahk_id %hwnd%
VarSetCapacity(ps,64,0)
DllCall("BeginPaint","uint",hwnd,"uint",&ps)
hdc := NumGet(ps,0)
if hicon := CallWindowProc(WindowProcOld, hwnd, 0x171,0,0) ; STM_GETICON
{
; Get a brush to be used as the background.
hbr := DllCall("GetSysColorBrush","int",15)
; DrawIconEx draws the background and icon into a temporary buffer,
; then draws the buffer onto the window. (It draws directly onto the
; window if hbr is not a valid brush handle.)
DllCall("DrawIconEx","uint",hdc,"int",0,"int",0,"uint",hicon
,"int",w,"int",h,"uint",0,"uint",hbr,"uint",0x3)
}
DllCall("EndPaint","uint",hwnd,"uint",&ps)
return 0
}
res := CallWindowProc(WindowProcOld, hwnd, uMsg, wParam, lParam)
return res
}
CallWindowProc(wndProc, hwnd, uMsg, wParam, lParam) {
return DllCall("CallWindowProc","uint",wndProc,"uint",hwnd,"uint",uMsg,"uint",wParam,"uint",lParam)
}
If you comment out these two lines:
Code:
WindowProcNew := RegisterCallback("WindowProc")
WindowProcOld := DllCall("SetWindowLong","uint",hPic,"int",-4,"int",WindowProcNew,"uint")
...it should flicker less than it would with GuiControl, but still occasionally "blink."
A typical control paints everything in WM_PAINT, but if you find it easier to pre-generate the icon and paint only that from WM_PAINT, you may as well.
Login
Register
FAQ
Search
It hadn't occurred to me since I used the icons in a ListView instead of the tray...
