AutoHotkey Community

Gui Add, Edit, r5 w160 vScript, MsgBox `% %A_Space%
Gui Add, Button, w70, &Run
Gui Add, Button, w70 x+20 yp, &Cancel

#!z::Gui Show

ButtonRun:
   Gui Submit

   Script:=chr(0xef) . chr(0xbb) . chr(0xbf) . Script ; AHK needs leading UTF-8 BOM ""

   pipe_name := A_Now   ; unique to prevent collision
   pip2 := CreateNamedPipe(pipe_name, 2) ; AHK calls GetFileAttributes() = close pipe. Create 2nd pipe
   pipe := CreateNamedPipe(pipe_name, 2) ; 1st instance seems to reliably be "opened" first
   if (pipe=-1 or pip2=-1) {
       MsgBox CreateNamedPipe failed.
       ExitApp
   }

   Run %A_AhkPath% "\\.\pipe\%pipe_name%"

   DllCall("ConnectNamedPipe","uint",pip2,"uint",0) ; Wait for AHK to connect via GetFileAttributes()
   DllCall("CloseHandle","uint",pip2)               ; Not needed any more
   DllCall("ConnectNamedPipe","uint",pipe,"uint",0) ; Wait for AHK to connect to open the "file"

   If !DllCall("WriteFile","uint",pipe,"str",Script,"uint",StrLen(Script)+1,"uint*",0,"uint",0)
       MsgBox WriteFile failed: %ErrorLevel%/%A_LastError%

   DllCall("CloseHandle","uint",pipe)
Return

ButtonCancel:
   Gui Destroy
Return

CreateNamedPipe(Name, OpenMode=3, PipeMode=0, MaxInstances=255) {
    Return DllCall("CreateNamedPipe","str","\\.\pipe" Name,"uint",OpenMode
        ,"uint",PipeMode,"uint",MaxInstances,"uint",0,"uint",0,"uint",0,"uint",0)
}

pipe := DllCall("CreateNamedPipe","str","\\.\pipe\ahkilibpipe","uint",3
        ,"uint",0,"uint",255,"uint",0,"uint",0,"uint",0,"uint",0)

Run, "%A_AhkPath%" /iLib \\.\pipe\ahkilibpipe "%A_ScriptFullPath%"

DllCall("ConnectNamedPipe", "uint", pipe, "uint", 0)
Loop {
    VarSetCapacity(buf, 4095)
    DllCall("ReadFile","uint",pipe,"str",buf,"uint",4095,"uint*",bytesRead:=0,"uint",0)
    NumPut(0, buf, bytesRead, "char") ; terminate the string
    VarSetCapacity(buf, -1)
    text .= buf
    if bytesRead < 4095
        break
}
MsgBox %text%

#include *i \\.\pipe\pipename