I recently started to write ini file reading/parsing code for one of the scripts I'm working on, but happily deleted it all when I found
GetPrivateProfileSection and related functions.
Here are the wrappers I'm using, in case they're of some use to someone:
Code:
; Reads an entire section of an ini file, excluding comments.
INI_ReadSection(Filename, Section)
{
; Expand relative paths, since GetPrivateProfileSection only searches %A_WinDir%.
Loop, %Filename%, 0
Filename := A_LoopFileLongPath
VarSetCapacity(text, 0x7FFF, 0)
len := DllCall("GetPrivateProfileSection"
, "str", Section, "str", text, "uint", 0x7FFF, "str", Filename)
; Each line within the section is terminated with a null character.
; Replace each delimiting null char with a newline:
Loop, % len-1
if (NumGet(text, A_Index-1, "UChar") = 0)
NumPut(10, text, A_Index-1, "UChar") ; \0 -> \n
; Windows Me/98/95:
; The returned string includes comments.
;
; This removes comments. Also, I'm not sure if leading/trailing space is
; automatically removed on Win9x, so the regex removes that too.
if A_OSVersion in WIN_ME,WIN_98,WIN_95
text := RegExReplace(text, "m`n)^[ `t]*(?:;.*`n?|`n)|^[ `t]+|[ `t]+$")
return text
}
; Replaces the content of a section,
; from [section] to the last key=value line.
INI_WriteSection(Filename, Section, Content)
{
Loop, %Filename%, 0
Filename := A_LoopFileLongPath
if (SubStr(Content,0) != "`n")
Content .= "`n" ; `n -> section null-terminator
Loop, % StrLen(Content)
if (NumGet(Content, A_Index-1, "UChar") = 10)
NumPut(0, Content, A_Index-1, "UChar") ; \n -> \0
; Note: This deletes ALL existing content between [Section] and the last
; key=value line, but not trailing lines which have no '='.
return DllCall("WritePrivateProfileSection"
, "str", Section, "str", Content, "str", Filename)
}
; Gets the names of all sections in an ini file.
INI_GetSectionNames(Filename)
{
; Expand relative paths, since GetPrivateProfileSectionNames only searches %A_WinDir%.
Loop, %Filename%, 0
Filename := A_LoopFileLongPath
VarSetCapacity(text, 0x1000, 0)
len := DllCall("GetPrivateProfileSectionNames", "str", text, "uint", 0x1000, "str", Filename)
; Replace each delimiting null char with a newline:
Loop, % len-1
if (NumGet(text, A_Index-1, "UChar") = 0)
NumPut(10, text, A_Index-1, "UChar") ; \0 -> \n
return text
}
Very little parsing is necessary, as the Win32 API does most of the work.
Login
Register
FAQ
Search
