AutoHotkey Community

SERVICE_STOPPED          = 0x00000001
SERVICE_START_PENDING    = 0x00000002
SERVICE_STOP_PENDING     = 0x00000003
SERVICE_RUNNING          = 0x00000004
SERVICE_CONTINUE_PENDING = 0x00000005
SERVICE_PAUSE_PENDING    = 0x00000006
SERVICE_PAUSED           = 0x00000007

MsgBox % GetServiceState("LanmanWorkstation")

GetServiceState(szDisplayName)
{
  dwCurrentState =
  ; open service manager with sufficient rights
  scManager := DllCall("advapi32\OpenSCManagerA", uint, 0, uint, 0, uint, 0x0002002f)
  if scManager
  {
    ; open the service
    scService := DllCall("advapi32\OpenServiceA", uint, scManager, str, szDisplayName, uint, 0x000200ff)
    if not scService
    {
      szServiceName =
      VarSetCapacity(szServiceName,1024,0)
      VarSetCapacity(dwLen,4,0)
      InsertInteger(1024,dwLen)
      ; try to find the service name from the display name
      DllCall("advapi32\GetServiceKeyNameA", uint, scManager, str, szDisplayName, str, szServiceName, uint, &dwLen)
      scService := DllCall("advapi32\OpenServiceA", uint, scManager, str, szServiceName, uint, 0x000200ff)
    }
    ; is service found
    if scService
    {
      VarSetCapacity(serviceStatus,28,0)
      /*
        typedef struct _SERVICE_STATUS
        {
          DWORD dwServiceType;
          DWORD dwCurrentState;
          DWORD dwControlsAccepted;
          DWORD dwWin32ExitCode;
          DWORD dwServiceSpecificExitCode;
          DWORD dwCheckPoint;
          DWORD dwWaitHint;
        } SERVICE_STATUS, *LPSERVICE_STATUS;
      */
      ; SERVICE_CONTROL_INTERROGATE = 0x00000004
      DllCall("advapi32\ControlService", uint, scService, uint, 0x00000004, str, serviceStatus)
      dwCurrentState := ExtractInteger(serviceStatus, 4)
      ; close the service
      DllCall("advapi32\CloseServiceHandle", int, scService)
    }
  }
  ; close the service manager
  DllCall("advapi32\CloseServiceHandle", int, scManager)

  return dwCurrentState
}

ExtractInteger(ByRef pSource, pOffset = 0, pIsSigned = false, pSize = 4)
; pSource is a string (buffer) whose memory area contains a raw/binary integer at pOffset.
; The caller should pass true for pSigned to interpret the result as signed vs. unsigned.
; pSize is the size of PSource's integer in bytes (e.g. 4 bytes for a DWORD or Int).
; pSource must be ByRef to avoid corruption during the formal-to-actual copying process
; (since pSource might contain valid data beyond its first binary zero).
{
   Loop %pSize%  ; Build the integer by adding up its bytes.
      result += *(&pSource + pOffset + A_Index-1) << 8*(A_Index-1)
   if (!pIsSigned OR pSize > 4 OR result < 0x80000000)
      return result  ; Signed vs. unsigned doesn't matter in these cases.
   ; Otherwise, convert the value (now known to be 32-bit) to its signed counterpart:
   return -(0xFFFFFFFF - result + 1)
}

InsertInteger(pInteger, ByRef pDest, pOffset = 0, pSize = 4)
; The caller must ensure that pDest has sufficient capacity.  To preserve any existing contents in pDest,
; only pSize number of bytes starting at pOffset are altered in it.
{
   Loop %pSize%  ; Copy each byte in the integer into the structure as raw binary data.
      DllCall("RtlFillMemory", "UInt", &pDest + pOffset + A_Index-1, "UInt", 1, "UChar", pInteger >> 8*(A_Index-1) & 0xFF)
}