AutoHotkey Community

; Requires AutoHotkey pre-v1.0.48 beta

Call(FunctionName, p1="__deFault__", p2="__deFault__", p3="__deFault__", p4="__deFault__", p5="__deFault__", p6="__deFault__", p7="__deFault__", p8="__deFault__", p9="__deFault__", p10="__deFault__")
{
    return Call_(FunctionName, p1, p2, p3, p4, p5, p6, p7, p8, p9, p10)
}

Call_(FunctionName, ByRef p1="__deFault__", ByRef p2="__deFault__", ByRef p3="__deFault__", ByRef p4="__deFault__", ByRef p5="__deFault__", ByRef p6="__deFault__", ByRef p7="__deFault__", ByRef p8="__deFault__", ByRef p9="__deFault__", ByRef p10="__deFault__")
{
    static pn:="1,2,3,4,5,6,7,8,9,10", line
        , SYM_INVALID:=56, SYM_VAR:=3, SYM_FUNC:=55, SYM_OPERAND:=4, VAR_ALIAS:=0
    if !arg
        LowLevel_init(), arg := NumGet(NumGet(__findLabel("Call_expression_marker"),4),4)
    if !(func := __findFunc(FunctionName))
        return "", ErrorLevel:=1
    if NumGet(func+16) > 10 ; Give up, requires too many parameters.
        return "", ErrorLevel:=2
   
    ; Get pointer to alias var for use in the loop.
    this_param_var := __getVar(this_param)

    ; postfix must fit one ExprTokenType for each param, followed by a SYM_FUNC token
    ; representing a function call, a SYM_INVALID token terminating the expression and
    ; a DerefType holding a pointer to the function to call.
    VarSetCapacity(postfix, 204, 0) ; 16*(10+2) + 12*1
    this_postfix := &postfix
   
    pc := 0
    Loop, Parse, pn, `,
    {
        ; Ignore any parameters beyond the function's capacity.
        if (pc >= NumGet(func+12))
            break
       
        if (p%A_LoopField% == "__deFault__")
        {
            ; If this parameter is required, just pass empty string.
            if (pc < NumGet(func+16))
                p%A_LoopField% =
            else
                break
        }
       
        var := __getVar(p%A_LoopField%)
        ; Resolve ByRef/alias.
        if (NumGet(var+23,0,"char") = VAR_ALIAS)
            var := NumGet(var+12)
       
        ; Put param var into postfix array.
        NumPut(var, this_postfix+0), NumPut(SYM_VAR, this_postfix+8)
       
        ; Move to next token in postfix array, increment param count.
        this_postfix += 16
        pc++
    }
   
    ; Set up the DerefType at the end of the postfix array.
    func_deref := this_postfix+32
    NumPut(func, func_deref+4)
    NumPut(pc, func_deref+9, 0, "char")
   
    ; Set up SYM_FUNC token.
    NumPut(func_deref, this_postfix+0)
    NumPut(SYM_FUNC, this_postfix+8)
    this_postfix += 16
   
    ; Terminate postfix array.
    NumPut(SYM_INVALID, this_postfix+8)
   
    ; Set postfix array of the first arg of 'return' below.
    NumPut(&postfix, arg+12)
   
    Call_expression_marker:
    return, ("") ; Parentheses to force is_expression=true.
}