Rajat wrote:
the example script looks complicated and i'm kinda afraid to get my feet wet!
I wanted to have both a simple and a complex example. If you wanted to reduce it to the bare minimum, the following is a fully functional ListView script that displays some files in report view:
Code:
Gui, Add, ListView, r20 w700, Name|Size (KB)
; Gather a list of file names from a folder and put them into the ListView:
Loop, %A_MyDocuments%\*.*
LV_Add("", A_LoopFileName, A_LoopFileSizeKB)
Gui Show
Quote:
i did a li'l research and found that shell32.dll\ExtractAssociatedIcon gives the correct icon
I was wondering how to do that and now I know. Thanks.
I think the following script segment can get the associated icon because ExtractAssociatedIcon() does not seem to strictly require a valid hInstance:
Code:
; Gather a list of file names from a folder and append them to the ListView:
Loop %Folder%\*.*
{
FileName := A_LoopFileFullPath ; Must save to writable variable for use below.
StringReplace, FileName, FileName, \\, \ ; Due to root drive having backslash from FileSelectFolder.
hIcon := DllCall("Shell32\ExtractAssociatedIconA", UInt, 0, str, FileName, UShortP, iIndex)
if hIcon
{
DllCall("ImageList_ReplaceIcon", UInt, ImageListID1, int, -1, UInt, hIcon)
IconNumber := DllCall("ImageList_ReplaceIcon", UInt, ImageListID2, int, -1, UInt, hIcon) + 1 ; +1 to convert to one-based.
DllCall("DestroyIcon", Uint, hIcon) ; Free the memory.
}
else
IconNumber = 1
; Create the new row and assign it an icon number:
LV_Add("Icon" . IconNumber, A_LoopFileName, A_LoopFileDir, A_LoopFileSizeKB)
}
The above is not the most efficient way to do it because it extracts the icon separately for every single file. For non-EXE files, memory and loading time could be reduced by maintaining an array of file extensions along with their associated index in the image list.
Quote:
shouldn't [App.hInstance] be built-in?
If there turns out to be a need for it, perhaps it should become a built-in variable A_hInstance. But perhaps someone knows if there's a function the script can call to discover its own hInstance value.
Thanks.
Edit: Changed one comment to "Due to root drive having backslash from FileSelectFolder."
Login
Register
FAQ
Search
)
