AutoHotkey Community

;Hangman Solver
Top:
InputBox, Input, Hangman Solver, Enter what you have so far`, for letters you don't know use a question mark (?).  Example: Han?m?n
If !Input
  ExitApp
URLDownloadtoFile, http://onelook.com/?w=%Input%&scwo=1&sswo=1, Search.html
FileRead, Html, Search.html
FileDelete, Search.html
Words =
Loop, Parse, HTML, `n, `r
  If RegExMatch(A_LoopField, "\d\. (.*?)>(.*?)</a>", Match)
  {
    Match := RegExReplace(Match, "\d\. (.*?)>")
    StringReplace, Match, Match, </a>
    Words .= Match . "`n"
  }
Msgbox, 0, Posible Matches:, %Words%
Goto, Top

; An updated Hangman Solver script by Frankie
; This script is released into the public domain
; AutoHotkey forum thread: http://www.autohotkey.com/forum/viewtopic.php?t=43482
Default_Text := "w?o?d"

Gui, +Resize
Gui, Margin, 10 5
Gui, Font, s18
Gui, Add, Edit, vInput gInputChange, % Default_Text
Gui, Font, s13
Gui, Add, ListView, r10 vOutput, Matches
LV_ModifyCol(1, "Integer Left")
Gui, Show, w300, H?ngman Solv?r
GuiControlGet, Output, Pos
GoSub, InputChange
return

InputChange:
GuiControlGet, Input
If (Input = Default_Text || Input = "")
{
   Gui, Font, cBBBBBB
   GuiControl, Font, Input
   GuiControl,, Input, % Default_Text
   SendInput {End} ; Hacky, but it works
   return
}
else If InStr(Input, Default_Text)
{   
   Gui, Font, c000000
   GuiControl, Font, Input
   StringReplace, NewText, Input, % Default_Text
   GuiControl,, Input, % NewText
   SendInput {End}
}
else if (InStr(Input, "?") = false)
       && (InStr(Input, "*") = false) || (StrLen(Input) < 3)
   return
Input := RegExReplace(Input, "([^/])\?", "$1%3F")
URLDownloadToFile, http://onelook.com/?w=%Input%&scwo=1&sswo=1, Hangman_Temp_File.html
FileRead, HTML, Hangman_Temp_File.html
FileDelete, Hangman_Temp_File.html
GuiControl, -ReDraw, Output
LV_Delete()
while (Pos>StrLen(Html)||!Pos ? Pos:=1 : Pos) := RegExMatch(HTML
      , "(?P<Index>\d+)\. <.*?>(?P<Word>\w+)(?=</a>)"
      , Match, Pos+StrLen(Match))
   LV_Add("", MatchIndex . ": " MatchWord)
LV_ModifyCol()
GuiControl, +ReDraw, Output
return

GuiSize:
If (A_EventInfo != 1) ; Do nothing when minimized
{
   ; Fit the Input and Output controls to the new window size
   GuiControl, Move, Output
      , % "w" (A_GuiWidth - 20) A_Space "h" (A_GuiHeight - OutputY - 10)
   GuiControl, Move, Input
      , % "w" (A_GuiWidth - 20)
}
return

GuiClose:
ExitApp

SetBatchLines -1
#NoEnv

GoSub, DownloadWordList ; if there isn't a local wordlist.txt for the program to use, download it
Loop
{
   InputBox Pattern,, Regular Expression Pattern,,,,,,,, %Pattern%
   InputBox BadLetters,, Letters not included in the word or phrase (comma delimited),,,,,,,, %BadLetters%
   InputBox NoSuggest,, Letters already in words (comma delimited),,,,,,,, %NoSuggest%
   if ErrorLevel
      Break
   count := {}, PossibleWords := ""
   Loop Read, %WordListFile%
   {
      if !Contains(A_LoopReadLine, BadLetters) and RegExMatch(A_LoopReadLine,"i)^(" Pattern ")$"){ ; if this word is a possible choice
         Loop Parse, A_LoopReadLine ; count up its letters
            if is(A_LoopField, "alpha") and !InStr(NoSuggest, A_LoopField) ; but only count the letters
                  count[A_LoopField] := count[A_LoopField] ? count[A_LoopField] + 1 : 1
         PossibleWords .= A_LoopReadLine . "`n"
      }
   }
   MaxCount := 0
   for letter, LetterCount in count
      if (LetterCount > MaxCount)
         MaxCount := LetterCount, MaxLetter := letter
   MsgBox 4,, I suggest '%MaxLetter%'. Is it included?
   IfMsgBox Yes
      NoSuggest .= (NoSuggest = "" ? "" : ",") . MaxLetter
   IfMsgBox No
      BadLetters .= (BadLetters = "" ? "" : ",") . MaxLetter
}
return

DownloadWordList:
if !FileExist("WordList.txt") {
   URLDownloadToFile http://www.autohotkey.net/~berban/WordList.TXT, Wordlist.txt
   if (ErrorLevel) {
      MsgBox Could not download a word list. Please choose one.
      GoSub, SelectWordList
   }
   else
      WordListFile := "WordList.txt"
}
else
{
   Loop WordList.txt
   {
      WordListFile := A_LoopFileLongPath
      break
   }
   MsgBox, 4,, Found %WordListFile%. Use it?
   IfMsgBox No
      GoSub, SelectWordList
}
return

SelectWordList:
FileSelectFile WordListFile, 11, , Select a word list
if (ErrorLevel)
   ExitApp
return

Contains(a, b){
   if a contains %b%
      return true
   return false
}

is(a, b) {
   if a is %b%
      return true
   return false
}