AutoHotkey Community

;
; Language:       English
; Platform:       WinAll
; Author:         Bartimus
;
; Script Function:
;   Phone Log Script
;   Generates a CSV file to log incoming calls based on date, time, and user. 
;


#SingleInstance, Force
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.


Loop, read, \\Server\share$\Phone-Log-lists.csv
{
    LineNumber = %A_Index%
    Loop, parse, A_LoopReadLine, CSV
    {
   If (A_Index = 1)
     If (A_LoopField <> "")
      LstWho .= A_LoopField "|"

   If (A_Index = 2)
     If (A_LoopField <> "")
      LstWhat .= A_LoopField "|"

    }
}


WinPosx := (A_ScreenWidth)-(360)
WinPosy := (A_ScreenHeight)-(166)

Gui -system
Gui, Color, EEAA99
Gui, Font, s16, Verdana
Gui, Add, Text, Center  x0 w325, Log a Phone Call
Gui, Font, s11, Tahoma

Gui, Add, Text, w115 y45 x5 Right,Person Calling:
Gui, Add, ComboBox, yp-5 x120 w155 vWho, %LstWho%

Gui, Add, Text, w115 x5 Right, Reason for Call:
Gui, Add, ComboBox, yp-5 x120 w155 vWhat,%lstWhat%

Gui, Add, Button, x275 y40 w60 h60 default gSubmit, &Submit`nCall

Gui, Show, w345 h105 x%WinPosx% y%WinPosy%, I.T. Phone Log

Gui +LastFound



return

Submit:
  Gui, Submit, NoHide
  Gui, Destroy

FileAppend, %A_YYYY%-%A_MMM%-%A_DD%`,%A_Hour%:%A_Min%:%A_Sec%`,%A_username%`,%who%`,%what%`n, \\Server\share$\Phone-Log.csv

  IfNotInString, LstWho, %Who%
  {
    FileAppend, %who%, \\Server\share$\Phone-Log-lists.csv
  }

  IfNotInString, LstWhat, %What%
  {
    FileAppend, `,%what%, \\Server\share$\Phone-Log-lists.csv
  }


    FileAppend, `n, \\Server\share$\Phone-Log-lists.csv



TrayTip, I.T. Phone Log, %A_username%`,`nAn entry was made on`n%A_YYYY%-%A_MMM%-%A_DD% at %A_Hour%:%A_Min%:%A_Sec%, 10, 1
Soundbeep, 1500,500
sleep 10000

GuiEscape:
GuiClose:
ExitApp

Gui, 2:Add, DropDownList, Sort , List|List1|WaterMelon