Word wrap simulator
HiEdit control doesn't support
word wrap. At least, not yet. Here is the way I imagined to overpass this limitation.
Be sure your content have only Windows standard break lines (CR+LF), then press
Ctrl+W to begin. A dialog box will appear. Type the line length you want, then press
Enter. The content will be displayed at the length asked for without any cut within a word. To get back the original line length, press
Ctrl+W, then type zero (
0) followed by
Enter and that's it.
How does it work?
The mechanism is based on the fact that a Windows standard break line (CR+LF) and a Unix-like break line (LF) have
exactly the same aspect in a HiEdit control.
Suppose you asked for a 72 characters line lenght. For each line longer than 72 characters, the program will check if it's possible to cut at the position asked for. If yes, a sole line feed character (LF) will be used to make the cut. If no, the program go to the previous position and do the same check, and so on, until a cut will be possible.
To prevent cut within a word, a cut is considered possible only after a
space or one of the following characters:
!$%),./:;>?]}…»
By doing so, it will be easy to remove this kind of break line (LF) without removing the other (CR+LF). And so, get the content back to the original line length.
Code:
^W:: ; Press Ctrl+W (like word wrap)
Gui,-MaximizeBox -MinimizeBox ; to get the dialog box.
Gui,Add,Text,,How many characters:
Gui,Add,Edit,vLL Number Limit4 W54 ys ; LL stands for line length.
Gui,Add,Button,W81 H24 xs y+16 Default,OK
Gui,Show,,Line length
Return
GuiEscape: ; Closing the dialog box
GuiClose: ; or pressing Escape key
Gui,Destroy ; will destroy the GUI.
Return
ButtonOK: ; Pressing the OK button
Gui,Submit ; first, submit the GUI
Gui,Destroy ; then, destroy it.
If (LL<>0 && LL<20) ; To prevent a too short line length.
Return
T:=HE_GetTextRange(hEdit,0,-1)
T:=RegExReplace(T,"(\S)\n","$1 ",1) ; Replace all Unix-like break line
T:=RegExReplace(T," \n"," ",1) ; by a space... and only one.
SendMessage,0xB1,0,-1,,ahk_id %hEdit% ; By doing so, you get back the
SendMessage,0xC2,,&T,,ahk_id %hEdit% ; original line length.
If LL=0
Return
FR= ; Clear Final Result's variable.
L=1 ; Start at the first line.
Val:=LL ; Start with the line length asked for.
TLN:=HE_GetLineCount(hEdit) ; Get the number of lines in the control.
Loop,%TLN% ; For each line...
{ ; Get the line's text.
ControlGet,TLC,Line,%L%,,ahk_id %hEdit%
If StrLen(TLC)<Val ; If it's shorter than the line length
FR.=TLC ; asked for, keep it entirely and go to
Else ; the next line.
{
Cisor:
cut:=LL-1
Loop ; If it's not, verify if it's possible to
{ ; cut at the current position.
StringMid,CCC,TLC,cut,1
If CCC Not In ,,, ,!,$,`%,),.,/,:,;,>,?,],},…,»
cut-- ; If not, check for the previous...
Else ; ...and so on,
Break ; until it will be...
}
StringLeft,CG,TLC,cut ; ...then do it...
FR.=CG . "`n"
StringTrimLeft,TLC,TLC,cut ; ...and do the same thing
If StrLen(TLC)<Val ; with the rest of the line until
FR.=TLC ; its length will be less than
Else ; the line length asked for.
GoTo,Cisor
}
L++ ; Then, do the same with the next line...
If L=TLN ; ...except if this was the last.
Break
}
FR:=RegExReplace(FR,"([^ ])(`n) ","$1$2",1) ; Remove all trailing space.
SendMessage,0xB1,0,-1,,ahk_id %hEdit% ; Then, select all and
SendMessage,0xC2,,&FR,,ahk_id %hEdit% ; replace it with Final
Return ; Result's contents.
EditTo cut a line manually, a command that inserts a single line feed (LF) character may be useful.
Here it is:
Code:
!Enter::Send {Asc 010} ; Alt+Enter
Login
Register
FAQ
Search
