Smart Word Wrap Toggle For Notepad
One of the problems (read: pet peeves) with toggling Word Wrap in Notepad is that the program loses track of where you were in the document. It's not a big deal if you just opened the document or if you're working on the first few lines, but if you were working far into the document, it can be very irritating.
This script provide two basic features:
- Context-sensitive hotkey. This code will only fire if a Notepad window is active. Uses Ctrl+W (patterned after PSPad) but change it to whatever you want.
- Preserve caret position or selection. If typing just before the hotkey is used, you can resume typing immediately afterwards. If text was selected before the hotkey is used, the same text will be selected afterwards.
Here's the code (needs the
Edit library of course):
Code:
;[=============]
;[ Ctrl+W ]
;[ [Notepad] ]
;[=============]
#IfWinActive ahk_class Notepad
^w::
#IfWinActive
;-- Get current handle to the Edit control
if Edit_GetActiveHandles(hEdit)
{
;-- Get current select positions
Edit_GetSel(hEdit,$StartSelPos,$EndSelPos)
;-- Toggle word wrap
SendMessage 0x111,32,0 ;-- 0x111=WM_COMMAND
;-- Collect new handle to the Edit control
Edit_GetActiveHandles(hEdit)
;-- Set caret
Edit_SetSel(hEdit,$StartSelPos,$StartSelPos)
Edit_ScrollCaret(hEdit)
;-- Initial selection and scroll. This makes sure that the leftmost
; position of the selection is showing.
;-- Re-select if necessary
if ($StartSelPos<>$EndSelPos)
{
Edit_SetSel(hEdit,$StartSelPos,$EndSelPos)
;-- Show as much of the selection as possible
$FirstVisibleLine :=Edit_GetFirstVisibleLine(hEdit)
$LastVisibleLine :=Edit_GetLastVisibleLine(hEdit)
$FirstSelectedLine:=Edit_LineFromChar(hEdit,$StartSelPos)
$LastSelectedLine :=Edit_LineFromChar(hEdit,$EndSelPos)
;-- Last line showing?
if ($LastSelectedLine>$LastVisibleLine)
if ($LastSelectedLine-$LastVisibleLine<$FirstSelectedLine-$FirstVisibleLine)
Edit_LineScroll(hEdit,0,($LastVisibleLine-$LastSelectedLine)*-1)
else
Edit_LineScroll(hEdit,0,($FirstVisibleLine-$FirstSelectedLine)*-1)
}
}
return
I hope that someone finds this useful.
Login
Register
FAQ
Search
substitutes. I'll try to rewrite this section to avoid confusion. Thank you for your feedback. 
