I've updated __getTokenValue() in the "v1.0.48"
download to support objects in variables. However, I haven't updated LowLevel.chm - SymbolType is only accurate for the official AutoHotkey build, and some struct/union members used in AutoHotkey_L aren't documented there.
tinku99 wrote:
Variadic functions could be simulated by calling a variadic bif (such as "dllcall") with one bogus argument plus the arguments meant for the user variadic.
Source: DebugBIF threadThere's no need to use DebugBIF for this. Instead, flag the function as "built-in" and implement it via a callback.
[Note: All code snippets in this post require AutoHotkey_L or a build based on it.]Code:
LowLevel_init()
if !(vf := __findFunc("variadic"))
|| !(cb := RegisterCallback("variadic_callback", "C F", 3))
{
MsgBox FAIL
ExitApp
}
NumPut(true, vf + 49, 0, "char") ; vf.IsBuiltIn := true
NumPut(cb, vf + 4) ; vf.BIF := cb
; Example: Simulate Object(<initializers>).
foo := Object()
bar := variadic(foo, 1, "one", 2, "two")
e := bar._NewEnum()
while e[k, v]
s .= k " = " v "`n"
MsgBox % s "`nfoo " (foo==bar ? "==" : "!=") " bar"
variadic(a=0,b=0,c=0,d=0,e=0,f=0,g=0,h=0,i=0,j=0,k=0,l=0,m=0
,n=0,o=0,p=0,q=0,r=0,s=0,t=0,u=0,v=0,w=0,x=0,y=0,z=0)
{
; The body of this function is never executed.
}
variadic_impl(params)
{
; Example implementation of variadic function:
; Accepts an object and a list of key/value pairs to set.
e := params._NewEnum()
if ! e[_, obj]
return
while e[_, k] && e[_, v]
obj[k] := v
return obj
}
variadic_callback(aResultToken, aParam, aParamCount)
{
; Build array of parameters.
params := Object()
Loop % aParamCount {
params[A_Index] := __getTokenValue(NumGet(aParam+0))
aParam += A_PtrSize
}
; Call implementation function (or do stuff here).
result := variadic_impl(params)
; Store result in result token.
__setResultToken(aResultToken, result)
}
In this example, the function
variadic() must be defined with the maximum number of parameters that will be passed to it. Load-time validation will prevent scripts from passing more than this. Note that the default values are only used if a parameter in the
middle of the list is omitted:
Code:
variadic(1, , 3) ; (1, 0, 3)
Quote:
However, DebugBIF_DefaultHandler falls down on objects.
It relies on __getTokenResult to get a usable value from aParam, which is an array of pointers to ExprTokenType. Try the updated version of LowLevel.
Quote:
Also, how do you get the result of the DebugBIF_DefaultHandler back to the caller of the intentionally faulty bif ?
aResultToken points to an ExprTokenType structure which should hold the return value. Its use is rather involved, so I've written a function for it (used in the example above).
Code:
__setResultToken(rt, r)
{
/* ; This section may cause loss of format, e.g. for r=0xBEEF.
if r is integer
{
; rt.symbol is SYM_INTEGER by default.
NumPut(r, rt+0, 0, "int64") ; rt.value_int64 := r
}
else if r is float
{
NumPut(2, rt+0, 8, "int") ; rt.symbol := SYM_FLOAT
NumPut(r, rt+0, 0, "double") ; rt.value_double := r
}
else
*/
if IsObject(r)
{
DllCall(NumGet(NumGet(&r)+4), "uint", &r) ; r.AddRef()
NumPut(&r, rt+0) ; rt.object := r
NumPut(5, rt+0, 8, "int") ; rt.symbol := SYM_OBJECT
}
else
{
; See TokenSetResult() in script2.cpp for how this works.
if StrLen(r) > 255 {
p := __malloc((StrLen(r) + 1) * (A_IsUnicode ? 2:1))
NumPut(p, rt+12) ; rt.circuit_token := p
NumPut(StrLen(r), rt+4) ; rt.buf := StrLen(r)
} else
p := NumGet(rt+4) ; p := rt.buf
StrPut(r, p)
NumPut(p, rt+0) ; rt.marker := p
NumPut(0, rt+0, 8, "int") ; rt.symbol := SYM_STRING
}
}
Login
Register
FAQ
Search
Sorry about that.