AutoHotkey Community
It is currently May 27th, 2012, 6:10 am

View unanswered posts | View active topics


Board index » AutoHotkey » Scripts

All times are UTC [ DST ]



Post new topic Reply to topic  Page 1 of 3
  [ 37 posts ]  Go to page 1, 2, 3  Next
  Print view | E-mail friend Previous topic | Next topic 
Author Message
shajul
PostPosted: October 28th, 2009, 12:35 pm 
Offline

Joined: September 15th, 2006, 10:25 am
Posts: 567
Lib compliant script to Elevate privileges of compiled/non-compiled scripts with/without parameters.

Just put this script to your Standard Library and put this function at the top of the script, as simple as that.
Code:
RunAsAdmin()


Download : RunAsAdmin.ahk


History:
To check if the user has Administrator rights and elevate it if needed by the script, i stumbled upon the help doc, which states that
Quote:
..this would need to be enhanced to work for compiled scripts and/or to pass parameters..
on page http://www.autohotkey.com/docs/Variables.htm#BuiltIn..

The code given is..

Code:
if not A_IsAdmin
{
   DllCall("shell32\ShellExecuteA", uint, 0, str, "RunAs", str, A_AhkPath
      , str, """" . A_ScriptFullPath . """", str, A_WorkingDir, int, 1)
   ExitApp
}


To run for any scripts, compiled or not, with params use this code instead..

Code:
Loop, %0%  ; For each parameter:
  {
    param := %A_Index%  ; Fetch the contents of the variable whose name is contained in A_Index.
    params .= A_Space . param
  }
ShellExecute := A_IsUnicode ? "shell32\ShellExecute":"shell32\ShellExecuteA"
   
if not A_IsAdmin
{
    If A_IsCompiled
       DllCall(ShellExecute, uint, 0, str, "RunAs", str, A_ScriptFullPath, str, params , str, A_WorkingDir, int, 1)
    Else
       DllCall(ShellExecute, uint, 0, str, "RunAs", str, A_AhkPath, str, """" . A_ScriptFullPath . """" . A_Space . params, str, A_WorkingDir, int, 1)
    ExitApp
}


Edit1: Now it should work with both Basic AHK, Ansi and Unicode Autohotkey_L
Edit2: Shorter code, thanks Lexikos.
Edit3: Lib compliant version.


Also, why not use this code in the help file and docs also, so that any noob like me can benefit?[/url]


Last edited by shajul on January 12th, 2011, 8:01 am, edited 4 times in total.

Report this post
Top
 Profile  
Reply with quote  
Guest
 Post subject:
PostPosted: January 31st, 2010, 10:29 am 
So that code will not work for compiled (.exe) scripts? What can I do to make it work on compiled scripts?


Report this post
Top
  
Reply with quote  
Lexikos
 Post subject:
PostPosted: February 1st, 2010, 10:49 am 
Offline

Joined: October 17th, 2006, 4:15 pm
Posts: 7503
Location: Australia
In theory, your script can be simplified as commented below:
Code:
SetWorkingDir %A_ScriptDir%
Loop, %0%  ; No need for the intermediary variable 'param':
    params .= A_Space . """" . %A_Index% . """"
if not A_IsAdmin  ; Check this first to reduce repetition.
{
    if A_IsCompiled
        DllCall("shell32\ShellExecuteA", uint, 0, str, "RunAs", str, A_ScriptFullPath
            , str, SubStr(params,2) , str, A_WorkingDir, int, 1)
    else
        DllCall("shell32\ShellExecuteA", uint, 0, str, "RunAs", str, A_AhkPath
            , str, """" . A_ScriptFullPath . """" . params, str, A_WorkingDir, int, 1)
    ExitApp
}
...however, I haven't tested it. Note the changes I've made to compensate for the extra space at the beginning of the params, and spaces in parameters (i.e. in case the script was invoked as script.ahk "one param" "two params").

I would vote to update the example to demonstrate the difference between compiled and uncompiled scripts, but leave parameters as an exercise for the readers.
Anonymous wrote:
What can I do to make it work on compiled scripts?
I think you missed the point of shajul's post...


Report this post
Top
 Profile  
Reply with quote  
aaffe
 Post subject:
PostPosted: February 1st, 2010, 11:29 am 
Offline

Joined: May 17th, 2007, 12:07 pm
Posts: 1004
Location: Germany - Deutschland
I think the second one must also just Substr:
Code:
SetWorkingDir %A_ScriptDir%
Loop, %0%  ; No need for the intermediary variable 'param':
    params .= A_Space . """" . %A_Index% . """"
if not A_IsAdmin  ; Check this first to reduce repetition.
{
    if A_IsCompiled
        DllCall("shell32\ShellExecuteA", uint, 0, str, "RunAs", str, A_ScriptFullPath
            , str, SubStr(params,2) , str, A_WorkingDir, int, 1)
    else
        DllCall("shell32\ShellExecuteA", uint, 0, str, "RunAs", str, A_AhkPath
            , str, """" . A_ScriptFullPath . """" . SubStr(params,2), str, A_WorkingDir, int, 1)
    ExitApp
}


Edit: Sorry, I saw that the leading space MUST be there in the second one. So forget my changing.


Report this post
Top
 Profile  
Reply with quote  
shajul
 Post subject: Updated..
PostPosted: November 2nd, 2010, 5:55 am 
Offline

Joined: September 15th, 2006, 10:25 am
Posts: 567
Just updated my code so that it runs on Autohotkey_L also (unicode)

Also, Lexikos version of the same will also just need the modification of
Quote:
DllCall("shell32\ShellExecuteA"
to be changed to
Quote:
DllCall("shell32\ShellExecute"
as ShellExecuteA expects an Ansi string..

The documentation supplied with Autohotkey_L be changed so that all ansi functions are replaced. I can help in whatever way possible by me.


Report this post
Top
 Profile  
Reply with quote  
Lexikos
 Post subject:
PostPosted: November 3rd, 2010, 9:28 am 
Offline

Joined: October 17th, 2006, 4:15 pm
Posts: 7503
Location: Australia
I'll update the documentation. However, in AutoHotkey_L this is possible:
Code:
if not A_IsAdmin
{
    Run *RunAs "%A_ScriptFullPath%"
    ExitApp
}
This will work with compiled or uncompiled scripts (though the latter only works if AutoHotkey is installed). Unfortunately Run *verb "file" parameters isn't supported... yet.

Edit 2011-01-17: Hmm, apparently doesn't work with uncompiled scripts?? Wonder what I was thinking.


Last edited by Lexikos on January 16th, 2011, 3:45 pm, edited 1 time in total.

Report this post
Top
 Profile  
Reply with quote  
shajul
 Post subject: Good.
PostPosted: November 3rd, 2010, 9:39 am 
Offline

Joined: September 15th, 2006, 10:25 am
Posts: 567
I just moved over to AutoHotkey_L, and was updating my scripts to run with it.. The extra features are cool.. Thanks.

Lexikos wrote:
I'll update the documentation. However, in AutoHotkey_L this is possible:
Code:
if not A_IsAdmin
{
    Run *RunAs "%A_ScriptFullPath%"
    ExitApp
}
This will work with compiled or uncompiled scripts (though the latter only works if AutoHotkey is installed). Unfortunately Run *verb "file" parameters isn't supported... yet.


Report this post
Top
 Profile  
Reply with quote  
hotkeyd
 Post subject:
PostPosted: November 23rd, 2010, 2:04 pm 
Using standard AHK, which version of the above scripts is correct for compiled and un-compiled scripts ?


Report this post
Top
  
Reply with quote  
shajul
 Post subject: for ansi & unicode
PostPosted: November 23rd, 2010, 2:55 pm 
Offline

Joined: September 15th, 2006, 10:25 am
Posts: 567
hotkeyd wrote:
Using standard AHK, which version of the above scripts is correct for compiled and un-compiled scripts ?


Use this..
Code:
RunAsAdmin:
params := ""
if 0>0
{
    Loop, %0%  ; For each parameter:
    {
        param := %A_Index%  ; Fetch the contents of the variable whose name is contained in A_Index.
        params .= A_Space . param
    }
}
ShellExecute := A_IsUnicode ? "shell32\ShellExecute":"shell32\ShellExecuteA"
   
If A_IsCompiled
{
    if not A_IsAdmin
    {
       DllCall(ShellExecute, uint, 0, str, "RunAs", str, A_ScriptFullPath, str, params , str, A_WorkingDir, int, 1)
       ExitApp
    }
}
Else
{
    if not A_IsAdmin
    {
       DllCall(ShellExecute, uint, 0, str, "RunAs", str, A_AhkPath, str, """" . A_ScriptFullPath . """" . A_Space . params, str, A_WorkingDir, int, 1)
       ExitApp
    }
}


Report this post
Top
 Profile  
Reply with quote  
hotkeyd
 Post subject:
PostPosted: November 23rd, 2010, 3:10 pm 
cheers I'll try this later.

Should this allow my script to write ini files and machines where they don't have admin access ?


Report this post
Top
  
Reply with quote  
aaffe
 Post subject:
PostPosted: November 23rd, 2010, 3:28 pm 
Offline

Joined: May 17th, 2007, 12:07 pm
Posts: 1004
Location: Germany - Deutschland
*Deleted* Sorry, didnt read that you cant overgive parameters via *Runas...


Report this post
Top
 Profile  
Reply with quote  
shajul
 Post subject: Admin Script..
PostPosted: November 23rd, 2010, 4:37 pm 
Offline

Joined: September 15th, 2006, 10:25 am
Posts: 567
I have created a scheduled task to run a small script that runs as administrator at logon..
That script spawns all my other scripts, so that they all run with administrator privileges! :)


Report this post
Top
 Profile  
Reply with quote  
aaffe
 Post subject:
PostPosted: November 23rd, 2010, 4:50 pm 
Offline

Joined: May 17th, 2007, 12:07 pm
Posts: 1004
Location: Germany - Deutschland
Sorry, but this doesnt run for me:
Code:
if not A_IsAdmin
{
    Run *RunAs "%A_ScriptFullPath%"
    ExitApp
}

It says:
Action: RunAs
Verb: RunAs
There is no program bound to this file.

The ahk-file isnt compiled.....does it have to be compiled?


Report this post
Top
 Profile  
Reply with quote  
hotkeyd
 Post subject: Re: for ansi & unicode
PostPosted: November 23rd, 2010, 7:45 pm 
Code:
RunAsAdmin:
params := ""
if 0>0
{
    Loop, %0%  ; For each parameter:
    {
        param := %A_Index%  ; Fetch the contents of the variable whose name is contained in A_Index.
        params .= A_Space . param
    }
}
If A_IsCompiled
{
    if not A_IsAdmin
    {
       DllCall("shell32\ShellExecute", uint, 0, str, "RunAs", str, A_ScriptFullPath, str, params , str, A_WorkingDir, int, 1)
       ExitApp
    }
}
Else
{
    if not A_IsAdmin
    {
       DllCall("shell32\ShellExecute", uint, 0, str, "RunAs", str, A_AhkPath, str, """" . A_ScriptFullPath . """" . A_Space . params, str, A_WorkingDir, int, 1)
       ExitApp
    }
}

return

msgbox %A_IsAdmin%

Running the above on XP logged in with admin rights returns a msgbox with 1

Running as a compiled exe on XP with admin rights returns a msgbox with 1

Running on Win 7 as a compiled exe returns nothing.

Win 7 Right click run as administrator, return msgbox with 1.

I thought this would elevate the script/exe to have admin rights ?
Is that wrong ? or have I missed something ?


Report this post
Top
  
Reply with quote  
hotkeyd
 Post subject:
PostPosted: November 23rd, 2010, 8:14 pm 
Code:
Loop, %0%  ; For each parameter:
  {
    param := %A_Index%  ; Fetch the contents of the variable whose name is contained in A_Index.
    params .= A_Space . param
  }
ShellExecute := A_IsUnicode ? "shell32\ShellExecute":"shell32\ShellExecuteA"
   
if not A_IsAdmin
{
    If A_IsCompiled
       DllCall(ShellExecute, uint, 0, str, "RunAs", str, A_ScriptFullPath, str, params , str, A_WorkingDir, int, 1)
    Else
       DllCall(ShellExecute, uint, 0, str, "RunAs", str, A_AhkPath, str, """" . A_ScriptFullPath . """" . A_Space . params, str, A_WorkingDir, int, 1)
    ExitApp
}


this seems to work :)


Report this post
Top
  
Reply with quote  
Display posts from previous:  Sort by  
Post new topic Reply to topic  Page 1 of 3
  [ 37 posts ]  Go to page 1, 2, 3  Next

Board index » AutoHotkey » Scripts

All times are UTC [ DST ]

Who is online

Users browsing this forum: Apollo, Bing [Bot], Exabot [Bot], Google Feedfetcher, JamixZol, Yahoo [Bot] and 15 guests

You can post new topics in this forum
You can reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Powered by phpBB® Forum Software © phpBB Group