AutoHotkey Community

; Example of use

Gui Add, Edit, x10 y70 w250 h100, Just`nto test`nUp and Down`noutside a Fud.

; Current number of such controls
#fudControlNb := 0

?fudRangeLow := 0
?fudRangeHigh := 10
?fudIncrement := 0.1
?fudStartValue := 5
?fudXPos := 10
?fudYPos := 10
?fudWidth := 70
?fudVarName = firstUD
Gosub AddFlexibleUpDownControl

?fudRangeLow := -50
?fudRangeHigh := 50
?fudIncrement := 2
?fudStartValue := 0
?fudXPos := 10
?fudYPos := 40
?fudWidth := 50
?fudVarName = anotherUpDown
Gosub AddFlexibleUpDownControl


Gui Add, Button, x100 y180 w50 h25 gShowValues, OK
Gui +LastFound
guiID := WinExist()
Gui Show, w320, FlexibleGuiUpDown
Return

ShowValues:
   Loop %#fudControlNb%
   {
      v := #fudControlList?vn?%A_Index%
      GuiControlGet %v%
      v := %v%
      r = %r%UD%A_Index% = %v%`n
   }
   MsgBox %r%
Return

/*
Flexible Gui Up Down control
*/

; I prefix the volatile variables I use here with fud? and the persistant ones with #fud
; to avoid clashes with the variables of the host application.
; Also I prefix the parameters of the subroutine with ?fud.
; Alas, this makes the code quite obscure...

AddFlexibleUpDownControl:
   ; Store the parameters of the control
   #fudControlNb += 1
   #fudControlArray%#fudControlNb%?rangLow := ?fudRangeLow
   #fudControlArray%#fudControlNb%?rangHigh := ?fudRangeHigh
   #fudControlArray%#fudControlNb%?increment := ?fudIncrement
   ; Create the pseudo-buddy edit control, named as requested
   Gui Add, Edit, x%?fudXPos% y%?fudYPos% w%?fudWidth% h20 v%?fudVarName%, %?fudStartValue%
   px := ?fudXPos + ?fudWidth
   ; Create the up-down control on the right of the buddy
   Gui Add, UpDown, x%px% y%?fudYPos% w12 h24 Range-1-1 -16 gUDClick v[%?fudVarName%], 0
   ; Store lookup information
   #fudControlList?id?%?fudVarName% := #fudControlNb
   #fudControlList?vn?%#fudControlNb% := ?fudVarName
Return

UDClick:
   ; Which up-down control was clicked?
   fudVar?udVar := A_GuiControl
   fudVar?udValue := %fudVar?udVar% ; -1 or 1
   ; Remove [ and ] to get the control name
   StringTrimLeft fudVar?udVar, fudVar?udVar, 1
   StringTrimRight fudVar?udVar, fudVar?udVar, 1
   ; Get the control ID
   fudVar?controlNb := #fudControlList?id?%fudVar?udVar%
UDChange:
   ; Get value in the Edit control
   GuiControlGet %fudVar?udVar%
   ; Add (or substract) the increment
   fudVar?udValue := %fudVar?udVar% + fudVar?udValue * #fudControlArray%fudVar?controlNb%?increment
   ; Keep it within the bounds (no wrapping yet)
   If (fudVar?udValue < #fudControlArray%fudVar?controlNb%?rangLow)
      fudVar?udValue := #fudControlArray%fudVar?controlNb%?rangLow
   Else If (fudVar?udValue > #fudControlArray%fudVar?controlNb%?rangHigh)
      fudVar?udValue := #fudControlArray%fudVar?controlNb%?rangHigh
   ; Update the value in the Edit control
   GuiControl, , %fudVar?udVar%, %fudVar?udValue%
   ; And reset the UpDown control to the neutral position
   GuiControl, , [%fudVar?udVar%], 0
Return

~*Up::
~*Down::
   ; Get the variable name of the control with the focus
   GuiControlGet fudVar?udVar, FocusV
   fudVar?controlNb := 0
   ; Search if it is one of our flexible up down controls...
   Loop %#fudControlNb%
   {
      If (fudVar?udVar = #fudControlList?vn?%A_Index%)
      {
         ; Found!
         fudVar?controlNb := A_Index
         Break
      }
   }
   If (fudVar?controlNb > 0)
   {
      ; OK, that's one of our controls
      If (A_ThisHotkey = "~*Up")
         fudVar?udValue := 1
      Else
         fudVar?udValue := -1
      Goto UDChange
   }
Return

GuiClose:
GuiEscape:
ExitApp

#SingleInstance force

;"(ClassNN of the editcontrol which should have floats in it, found via windowspy)|(minvalue)|(maxvalue)|(steps)(`n)(NextEditsClassNN...)"
udEditList:="Edit1|10|50|0.25`nEdit2|-10|10|0.5"

;add the controls as usuall
Gui Add, Edit, w100 h20 vudedit,
Gui Add, UpDown,  w30 h24  vud , 23

Gui Add, Edit,  w100 h20 vudedit2,
Gui Add, UpDown,  w30 h24  vud2 , 5

Gui, Show

;look for the WM_NOTIFY message
OnMessage(0x4E, "WM_NOTIFY")
return

WM_NOTIFY(wParam, lParam)
{
    if (ExtractIntegerP(lParam,8,1) = -722)       ; if this is true a updowncontrol has send an UDN_DELTAPOS message
    {
        udHwnd:=ExtractIntegerP(lparam,0,0)
        iPos:=ExtractIntegerP(lparam,12,1)   
        iDelta:=ExtractIntegerP(lparam,16,1)

        SendMessage, 0x46A,,,, ahk_id %udHwnd%    ;gets the buddy of the updowncontrol that send the UDN_DELTAPOS message
        if (errorlevel)
        {
            udEditHwnd:=errorlevel
            udData:=GetudData(udEditHwnd,iDelta)  ;parse the udEditList and return the new value
            if udData = FAIL
                Return False                      ;the item was not found in the udEditList
            ControlSetText,, % udData , ahk_id %udEditHwnd%  ;set the new value in the editcontrol

            return True  ; indicates that the proposed change from the updowncontrol should be discarded
        }
        else
            return False ; don't discard the proposed change by the updowncontrol
    }

}

GetudData(_udEditHwnd,_delta)
{
    local udEditListItem, udEdithwnd, udEdit

    Loop, Parse, udEditList, `n, `n
    {
        StringSplit, udEditListItem, A_LoopField,|
        ControlGet, udEdithwnd, Hwnd,, %udEditListItem1%, A

        if (udEdithwnd = _udEdithwnd)
        {
            ControlGetText, udEdit,, ahk_id %udEditHwnd%
            udEdit+=udEditListItem4*_Delta

            if (udEdit < udEditListItem2)
                return udEditListItem2
            else if (udEdit > udEditListItem3)
                return udEditListItem3
            else
                return udEdit
        }
        else
            continue
    }
    Return "FAIL"
}

GuiClose:
ExitApp

ExtractIntegerP(ByRef pSource, pOffset = 0, pIsSigned = false, pSize = 4)
{
   Loop %pSize%
      result += *(pSource + pOffset + A_Index-1) << 8*(A_Index-1)
   if (!pIsSigned OR pSize > 4 OR result < 0x80000000)
      return result
   return -(0xFFFFFFFF - result + 1)
}