View topic - DllCall: HttpQueryInfo - Get HTTP headers • AutoHotkey Community

View unanswered posts | View active topics

Board index » AutoHotkey » Scripts

All times are UTC [ DST ]

DllCall: HttpQueryInfo - Get HTTP headers

Page 2 of 2

[ 21 posts ]

Go to page Previous 1, 2

Print view | E-mail friend

Previous topic | Next topic

Author

Message

Guest

Post subject:

Posted: May 13th, 2008, 5:33 am

can anyone help me to retrieve unicode header properly?
it gets http header but can't display unicode text in header

Top

desperate

Post subject:

Posted: September 13th, 2008, 4:37 pm

Mistrel wrote:

It should be noted that this script returns the header information for the final destination and not necessarily the header of the specified url.

Is it possible to modify this script to properly capture the header from an url with a Location:(url) redirect?

Can anyone show me how to do this? I have tried modifing the original post's InternetOpenUrlA call's dwFlags to include dwFlag values of

for a final value of 0x80208000, but it still always redirects to the final destination.

Top

desperate

Post subject:

Posted: September 13th, 2008, 4:56 pm

desperate wrote:

Mistrel wrote:

Talk about feeling like a dummy, I tried it again (many times) and now it is working as desired (it does not redirect, and does capture "Location:(url) redirect"

For the record here is the modified iou_hInternet code:

Quote:

iou_hInternet := DllCall("wininet\InternetOpenUrlA"
, "uint", io_hInternet
, "str", url
, "str", "" ;lpszHeaders
, "uint", 0 ;dwHeadersLength
, "uint", 0x80208000 ;dwFlags: INTERNET_FLAG_RELOAD = 0x80000000 // retrieve the original item
; + INTERNET_FLAG_NO_AUTO_REDIRECT 0x200000
; + INTERNET_FLAG_IGNORE_REDIRECT_TO_HTTP 0x8000
, "uint", 0) ;dwContext
If (ErrorLevel != 0 or iou_hInternet = 0) {
DllCall("FreeLibrary", "uint", hModule)
return, -1
}

Top

desperate

Post subject: my final vesion

Posted: September 13th, 2008, 5:18 pm

Here is the full modified version of the original post. Note that the function call has been modified.

To prevent reidrection call as: HttpQueryInfo(URL, QueryInfoFlag, TRUE, Proxy, ProxyBypass)

Code:

/* ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; HttpQueryInfo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 
original source by olfen: DllCall: HttpQueryInfo - Get HTTP headers
            http://www.autohotkey.com/forum/post-64567.html#64567
QueryInfoFlag: 

HTTP_QUERY_RAW_HEADERS = 21 
Receives all the headers returned by the server. 
Each header is terminated by "\0". An additional "\0" terminates the list of headers. 

HTTP_QUERY_CONTENT_LENGTH = 5 
Retrieves the size of the resource, in bytes. 

HTTP_QUERY_CONTENT_TYPE = 1 
Receives the content type of the resource (such as text/html). 

Find more at: http://msdn.microsoft.com/en-us/library/aa384238(VS.85,printer).aspx
         and: http://msdn.microsoft.com/en-us/library/aa385351(VS.85,printer).aspx
original obsolete reference: http://msdn.microsoft.com/library/en-us/wininet/wininet/query_info_flags.asp 

Proxy Settings: 

INTERNET_OPEN_TYPE_PRECONFIG                    0   // use registry configuration 
INTERNET_OPEN_TYPE_DIRECT                       1   // direct to net 
INTERNET_OPEN_TYPE_PROXY                        3   // via named proxy 
INTERNET_OPEN_TYPE_PRECONFIG_WITH_NO_AUTOPROXY  4   // prevent using java/script/INS 

*/ ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 

HttpQueryInfo(URL, QueryInfoFlag=21, NoRedirect="", Proxy="", ProxyBypass="") { 
hModule := DllCall("LoadLibrary", "str", "wininet.dll") 

If (Proxy != "") 
AccessType=3 
Else 
AccessType=1 

io_hInternet := DllCall("wininet\InternetOpenA" 
, "str", "" ;lpszAgent 
, "uint", AccessType 
, "str", Proxy 
, "str", ProxyBypass 
, "uint", 0) ;dwFlags 
If (ErrorLevel != 0 or io_hInternet = 0) { 
DllCall("FreeLibrary", "uint", hModule) 
return, -1 
} 

iou_hInternet := DllCall("wininet\InternetOpenUrlA" 
, "uint", io_hInternet 
, "str", url 
, "str", "" ;lpszHeaders 
, "uint", 0 ;dwHeadersLength 
, "uint", NoRedirect ? 0x80208000 : 0x80000000 ;dwFlags: INTERNET_FLAG_RELOAD = 0x80000000 // retrieve the original item 
                          ; INTERNET_FLAG_NO_AUTO_REDIRECT 0x200000 
                          ; INTERNET_FLAG_IGNORE_REDIRECT_TO_HTTP 0x8000
, "uint", 0) ;dwContext 
If (ErrorLevel != 0 or iou_hInternet = 0) { 
DllCall("FreeLibrary", "uint", hModule) 
return, -1 
} 
            

VarSetCapacity(buffer, 1024, 0) 
VarSetCapacity(buffer_len, 4, 0) 

Loop, 5 
{ 
  hqi := DllCall("wininet\HttpQueryInfoA" 
  , "uint", iou_hInternet 
  , "uint", QueryInfoFlag ;dwInfoLevel 
  , "uint", &buffer 
  , "uint", &buffer_len 
  , "uint", 0) ;lpdwIndex 
  If (hqi = 1) { 
    hqi=success 
    break 
  } 
} 

IfNotEqual, hqi, success, SetEnv, res, timeout 

If (hqi = "success") { 
p := &buffer 
Loop 
{ 
  l := DllCall("lstrlen", "UInt", p) 
  VarSetCapacity(tmp_var, l+1, 0) 
  DllCall("lstrcpy", "Str", tmp_var, "UInt", p) 
  p += l + 1  
  res := res  . "`n" . tmp_var 
  If (*p = 0) 
  Break 
} 
StringTrimLeft, res, res, 1 
} 

DllCall("wininet\InternetCloseHandle",  "uint", iou_hInternet) 
DllCall("wininet\InternetCloseHandle",  "uint", io_hInternet) 
DllCall("FreeLibrary", "uint", hModule) 

return, res 
}

Top

andz

Post subject:

Posted: March 15th, 2011, 7:06 pm

Joined: October 5th, 2007, 10:41 pm
Posts: 11

This should work for AutoHotkey_L (tested with QueryInfoFlag=5 only!):
(changes marked in red)

Code:

HttpQueryInfo(URL, QueryInfoFlag=21, Proxy="", ProxyBypass="") {
hModule := DllCall("LoadLibrary", "str", "wininet.dll")

If (Proxy != "")
AccessType=3
Else
AccessType=1

io_hInternet := DllCall("wininet\InternetOpenA"
, "str", "" ;lpszAgent
, "uint", AccessType
, "str", Proxy
, "str", ProxyBypass
, "uint", 0) ;dwFlags
If (ErrorLevel != 0 or io_hInternet = 0) {
DllCall("FreeLibrary", "uint", hModule)
return, -1
}

iou_hInternet := DllCall("wininet\InternetOpenUrlA"
, "uint", io_hInternet
, "Astr", url
, "str", "" ;lpszHeaders
, "uint", 0 ;dwHeadersLength
, "uint", 0x80000000 ;dwFlags: INTERNET_FLAG_RELOAD = 0x80000000 // retrieve the original item
, "uint", 0) ;dwContext
If (ErrorLevel != 0 or iou_hInternet = 0) {
DllCall("FreeLibrary", "uint", hModule)
return, -1
}

VarSetCapacity(buffer, 1024, 0)
VarSetCapacity(buffer_len, 4, 0)

Loop, 5
{
 hqi := DllCall("wininet\HttpQueryInfoW"
  , "uint", iou_hInternet
  , "uint", QueryInfoFlag ;dwInfoLevel
  , "uint", &buffer
  , "uint", &buffer_len
  , "uint", 0) ;lpdwIndex
  If (hqi = 1) {
    hqi=success
    break
  }
}

IfNotEqual, hqi, success, SetEnv, res, timeout

If (hqi = "success") {
p := &buffer
Loop
{
  l := DllCall("lstrlen", "UInt", p)
  VarSetCapacity(tmp_var, l+1, 0)
  DllCall("lstrcpy", "Str", tmp_var, "UInt", p)
  p += l + 1 
  res := res . tmp_var
  If (*p = 0)
  Break
}
;StringTrimLeft, res, res, 1
}

DllCall("wininet\InternetCloseHandle",  "uint", iou_hInternet)
DllCall("wininet\InternetCloseHandle",  "uint", io_hInternet)
DllCall("FreeLibrary", "uint", hModule)

return, res
}

Top

0x150||ISO

Post subject: Re: DllCall: HttpQueryInfo - Get HTTP headers

Posted: April 29th, 2012, 9:48 am

Joined: January 1st, 2011, 2:05 pm
Posts: 482

Heres an updated version that works in both builds
as per user query: viewtopic.php?f=1&t=85660

Code:

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; HttpQueryInfo Function ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;Source: post by olfen "DllCall: HttpQueryInfo - Get HTTP headers"
;                       http://www.autohotkey.com/forum/post-64567.html#64567
;
; For flag info, see: http://msdn.microsoft.com/en-us/library/aa385351(VS.85).aspx

HttpQueryInfo(URL, QueryInfoFlag=21, Proxy="", ProxyBypass="") {
hModule := DllCall("LoadLibrary", "str", dll := "wininet.dll")

; Adapt for build by 0x150||ISO
ver := ( A_IsUnicode && !RegExMatch( A_AhkVersion, "\d+\.\d+\.4" ) ? "W" : "A" )
InternetOpen := dll "\InternetOpen" ver
HttpQueryInfo := dll "\HttpQueryInfo" ver
InternetOpenUrl := dll "\InternetOpenUrl" ver

If (Proxy != "")
AccessType=3
Else
AccessType=1

io_hInternet := DllCall( InternetOpen
, "str", "" 
, "uint", AccessType
, "str", Proxy
, "str", ProxyBypass
, "uint", 0) ;dwFlags
If (ErrorLevel != 0 or io_hInternet = 0) {
DllCall("FreeLibrary", "uint", hModule)
return, -1
}

iou_hInternet := DllCall( InternetOpenUrl
, "uint", io_hInternet
, "str", url
, "str", ""
, "uint", 0
, "uint", 0x80000000
, "uint", 0)
If (ErrorLevel != 0 or iou_hInternet = 0) {
DllCall("FreeLibrary", "uint", hModule)
return, -1
}

VarSetCapacity(buffer, 1024, 0)
VarSetCapacity(buffer_len, 4, 0)

Loop, 5
{
  hqi := DllCall( HttpQueryInfo
  , "uint", iou_hInternet
  , "uint", QueryInfoFlag
  , "uint", &buffer
  , "uint", &buffer_len
  , "uint", 0)
  If (hqi = 1) {
    hqi=success
    break
  }
}

IfNotEqual, hqi, success, SetEnv, res, timeout

If (hqi = "success") {
p := &buffer
Loop
{
  l := DllCall("lstrlen", "UInt", p)
  VarSetCapacity(tmp_var, l+1, 0)
  DllCall("lstrcpy", "Str", tmp_var, "UInt", p)
  p += l + 1 
  res := res . tmp_var
  If (*p = 0)
  Break
}
}

DllCall("wininet\InternetCloseHandle",  "uint", iou_hInternet)
DllCall("wininet\InternetCloseHandle",  "uint", io_hInternet)
DllCall("FreeLibrary", "uint", hModule)

return, res
}

I added an adapter to switch function calls depending on W/A && AHK version.
I did not test this in ANSI _L.
edit: Works in all versions now.

_________________

AHK_L = HUGE BENIFITS!!! FREE :geek:

and :ugeek:

Top

Page 2 of 2

[ 21 posts ]

Go to page Previous 1, 2

Board index » AutoHotkey » Scripts

All times are UTC [ DST ]

Who is online

Users browsing this forum: specter333 and 24 guests

You can post new topics in this forum
You can reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum