AutoHotkey Community

@echo off
setlocal ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
goto Intro
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: PURPOSE:   Sets UTILS enviroment variables in Machine Registry.
::      Variables can imeddiately be used except in current
::      command window.
::
:: NOTE:   This is must in order for many programs in Utils folder
::      to work correctly.
::
:: Created by M. Milic on WinXP SR1
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:main
   
  set UTILS=%CD%
  set X=%UTILS%\_Console\Rkit\SetX.exe
  if NOT EXIST %X% (
     echo FATAL ERROR: %X% does not exist
     pause
     exit
  )

  :: PATH VARIABLES :::::::::::::::::::::::::::::::::::::::::::::::::::
  :: Will be added to path if not already in it

   set MM_1=%UTILS%\_Console
   set MM_2=%UTILS%\_Console\Rkit
   set MM_3=%UTILS%\_Console\SysInternals
   set MM_4=%UTILS%\_Console\SysInternals\PSTools
   set MM_5=%UTILS%\_Scripts\
   set MM_6=%UTILS%\_Tools

   echo Directories added to PATH:
   set P_ADD=
   for /F "delims==" %%i in ('set MM_') do call :AddDir "!%%i!" P_ADD

   if "%P_ADD%"=="" echo     None
   echo.
  :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::


  echo UTILS
  echo     %UTILS%&echo.
  %X% UTILS "%UTILS%" -m

  echo COMMANDER_PATH
  echo     %UTILS%\Total Commander&echo.
  %X% COMMANDER_PATH "%UTILS%\Total Commander" -m

  echo PATH
  echo     %PATH%%P_ADD%&echo.
  %X% PATH "%PATH%%P_ADD%" -m

goto Outro


:Intro
  echo.
  echo Instalation of UTILS enviroment variables.
  echo Press ^<CTRL^>+C to exit or any other key to continue.
  echo.&echo.
  echo WILL BE SET TO:    %CD%&echo.
  pause >nul
  cls
goto main



:Outro
  echo.&echo.&echo.&echo.
  echo  INSTALLATION COMPLETE
  echo  Press any key to exit&echo.
  pause >nul
  echo  Created by M. Milic on WinXP PRO SP1
  ping -n 3 127.0.0.1 >nul
goto :EOF



::======================================================================
:AddDir DIR
::
:: PURPOSE:   Check if DIR is already in the PATH. If it's not,
::      remove trailing spaces and add it to %2 (P_ADD) variable
::
::======================================================================
@echo off&setlocal ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
 set FP=%~1

 if "%PATH%"=="!PATH:%FP%=!" endlocal&set %2=!%2!;%FP%&echo    %FP%

goto :EOF

RunBeforeStop=%U3_HOST_EXEC_PATH%\truecrypt.exe ... /d /q