This is more complicated example.
The goal is to read so called root item from the Explorers TreeView on the left (folders). This item is "Desktop" on all systems but you can not get the text of it using regular API functions. Example is a little complicated then
shimanov's work for reading columns of ListView control in Explorer because it requires 2 remote buffers - one to receive the text, and one as an input to SendMessage function witch represents data of the item to be obtained (TVITEM structure in MSDN). If neither of those 2 buffers is local, the Windows will return nothing.
Run explorer, make sure you have folders open on the left and execute the script. You should get message containing word "Desktop" (or whatever localisation you have)
Code:
;Run Explorer
;WinWait ahk_class ExploreWClass
GetHandles() ;set XHandle & TreeHandle
GetRoot() ;display the text of root item
return
;------------------------------------------------------------------------------------------------
; Get the text of the root item (Desktop)
GetRoot()
{
global
local bufID, txt
;open remote buffer
bufID := RemoteBuf_Open(hwEx, 128)
if bufID < 0
MsgBox Can not open remote buffer (code %bufID%)
bufAdr := RemoteBuf_GetAdr(bufID)
;get root handle TVM_GETNEXTITEM = 0x110A TVGN_ROOT = 0
SendMessage 0x110A, 0, 0, ,ahk_id %hwTV%
root = %ErrorLevel%
;set TVITEM struct
VarSetCapacity(sTV, 40, 1) ;10x4 = 40
InsertInteger(0x011, sTV, 0) ;set mask to TVIF_TEXT | TVIF_HANDLE = 0x001 | 0x0010
InsertInteger(root, sTV, 4) ;set itemid to root
InsertInteger(bufAdr, sTV, 16) ;set txt pointer
InsertInteger(127, sTV, 20) ;set txt size
;copy the TVITEM structure to explorer address space
r_tvi := RemoteBuf_Open(hwEx, 40)
r_adr := RemoteBuf_GetAdr(r_tvi)
RemoteBuf_Write(r_tvi, sTV, 40)
;send tv_getitem message
SendMessage 0x110C, 0, r_adr ,, ahk_id %hwTV%
;read the text from the remote buffer
VarSetCapacity(txt, 128, 1)
RemoteBuf_Read(bufID, txt, 128 )
;close the buffers
RemoteBuf_Close( bufID )
RemoteBuf_Close( r_tvi )
MsgBox %txt%
}
;------------------------------------------------------------------------------------------------
; Get Explorer and its TreeView handle
GetHandles()
{
global
;get tree view handle
hwEx := WinExist("ahk_class ExploreWClass")
hwTV := FindWindowExId(hwEx, "BaseBar", 0)
hwTV := FindWindowExID(hwTV, "ReBarWindow32", 0)
hwTV := FindWindowExID(hwTV, "SysTreeView32", 100)
}
;------------------------------------------------------------------------------------------------
; Iterate through controls with the same class, find the one with ctrlID and return its handle
; Used for finding a specific control
;
FindWindowExID(dlg, className, ctrlId)
{
local ctrl, id
ctrl = 0
Loop
{
ctrl := DllCall("FindWindowEx", "uint", dlg, "uint", ctrl, "str", className, "uint", 0 )
if (ctrlId = "0")
{
return ctrl
}
if (ctrl != "0")
{
id := DllCall( "GetDlgCtrlID", "uint", ctrl )
if (id = ctrlId)
return ctrl
}
else
return 0
}
}
InsertInteger(pInteger, ByRef pDest, pOffset = 0, pSize = 4)
; The caller must ensure that pDest has sufficient capacity. To preserve any existing contents in pDest,
; only pSize number of bytes starting at pOffset are altered in it.
{
Loop %pSize% ; Copy each byte in the integer into the structure as raw binary data.
DllCall("RtlFillMemory", "UInt", &pDest + pOffset + A_Index-1, "UInt", 1, "UChar", pInteger >> 8*(A_Index-1) & 0xFF)
}
#include RemoteBuf.ahk
One question remains here about the blue line: why I must initialize array of bytes to non-zero value. Script doesn't work if you set 0 instead of any positive value.
Login
Register
FAQ
Search
vPhiLho 