AutoHotkey Community

RegExMatch(TrayIcons("app.exe"), "uID: (\d+).+?hWnd: (\d+)", id)
RemoveTrayIcon(id2, id1)

;#NoTrayIcon      ;  to test standalone, uncomment these four lines
;#SingleInstance, force
;TrayIcon_CleanUp()
;Return

TrayIcon_CleanUp()
{   ; Remove abandoned icons in notification tray, such as left behine by "Process Close"
   ; Windows 7 64 bit & AutoHotkey_L UNICODE 64Bit ONLY version!!!!!!!
   ; v0-5 - extensive change for Win7/64
   ; Originally based on TrayIcon by Sean @ http://www.autohotkey.com/forum/topic17314.html
   ;
   DetectHiddenWindows, On
   TBW:=GetTrayBar()
   WinGet, pidTaskbar, PID, ahk_class Shell_TrayWnd
   hProc := DllCall("OpenProcess"
                  , "Uint", 0x38
                  , "int", 0
                  , "Uint", pidTaskbar)
   pRB := DllCall("VirtualAllocEx"
                  , "Uint", hProc
                  , "Uint", 0
                  , "Uint", 32
                  , "Uint", 0x1000
                  , "Uint", 0x4)
   VarSetCapacity(btn, 32, 0)
   VarSetCapacity(nfo, 32, 0)
   SendMessage, 0x418, 0, 0, ToolbarWindow32%TBW%
                     , ahk_class Shell_TrayWnd   ; TB_BUTTONCOUNT
   Counter := ErrorLevel
   Loop, %Counter%
   {
      Counter-- ; Must count DOWN as the zero-based indexes change if you remove a lower one
;
      SendMessage, 0x417, Counter, pRB, ToolbarWindow32%TBW%
                              , ahk_class Shell_TrayWnd ; TB_GETBUTTON
      VarSetCapacity(bread,8,32)
      VarSetCapacity(bread2,8,32)
      DllCall("ReadProcessMemory", "int64", hProc
                           ,"int64", pRB
                           ,"int64", &btn
                           ,"int64", 32
                           ,"int64", &bread)
      dwData := Numget(btn,0x10,"int64") ; see struct way below
      DllCall("ReadProcessMemory"   , "int64", hProc
                           , "int64", dwData
                           , "int64", &nfo
                           , "int64", 32
                           , "int64", &bread2)
      hWnd   := NumGet(nfo, 0, "int64")
      if !WinExist("ahk_id " . hWnd) {
         SendMessage, 1046, Counter , 0, ToolbarWindow32%TBW%      ; zero-based index of button
                                 , ahk_class Shell_TrayWnd ; TB_DELETEBUTTON
      }
   } ; /Loop
   DllCall("VirtualFreeEx"
            , "Uint", hProc
            , "Uint", pRB
            , "Uint", 0
            , "Uint", 0x8000)
   DllCall("CloseHandle", "Uint", hProc)
   Return   sTrayIcon_CleanUp
}

GetTrayBar()   ; Get the notification area traybar number. For Windows 7 ONLY!!!!!!!
{              ; Sorry, forgot who I got this approach from. Note it works, I confirmed hWnd
   ControlGet, hParent, hWnd,, TrayNotifyWnd1  , ahk_class Shell_TrayWnd
   ControlGet, hChild , hWnd,, ToolbarWindow321, ahk_id %hParent%
   Loop
   {
      ControlGet, hWnd, hWnd,, ToolbarWindow32%A_Index%, ahk_class Shell_TrayWnd
      If  Not   hWnd
         Break
      Else If   hWnd = %hChild%
      {
         idxTB := A_Index
         Break
      }
   }
   Return   idxTB
}

; Structs for W7/64
/*typedef struct {
  int       iBitmap;      x00
  int       idCommand;       x04
  BYTE      fsState;      x08
  BYTE      fsStyle;      x09
#ifdef _WIN64
  BYTE      bReserved[6];   x0A
#else
#if defined(_WIN32)
  BYTE      bReserved[2];   x0A
#endif
#endif                   WIN32/WIN64
  DWORD_PTR dwData;         x0C/x10      d12/d16
  INT_PTR   iString;      x10/x18      d16/d24
                     x14/x20      d20/d32
} TBBUTTON, *PTBBUTTON, *LPTBBUTTON;
*/
/*
BOOL WINAPI ReadProcessMemory(
  __in   HANDLE hProcess, 64
  __in   LPCVOID lpBaseAddress, 64
  __out  LPVOID lpBuffer,64
  __in   SIZE_T nSize, 64
  __out  SIZE_T *lpNumberOfBytesRead 64
);
*/

   /*typedef struct _NOTIFYICONDATA {
  DWORD cbSize;            x00
  HWND  hWnd;              x04
  UINT  uID;               x0c/d12
  UINT  uFlags;            x10/d16
  UINT  uCallbackMessage;  x14/d20
  HICON hIcon;             x18/d24
  TCHAR szTip[64];         x20 (UNICODE)
  DWORD dwState;           xa0
  DWORD dwStateMask;       xa4
  TCHAR szInfo[256];       xa8 (UNICODE)
  union {
    UINT uTimeout;         x01a8
    UINT uVersion;         x01a8
  };
  TCHAR szInfoTitle[64];   x01ac (UNICODE)
  DWORD dwInfoFlags;       x022c
  GUID  guidItem; (128bits) x0230
  HICON hBalloonIcon;      x023c
            ;end           x0244
} NOTIFYICONDATA, *PNOTIFYICONDATA;
*/