AutoHotkey Community

Gui, Add, ListView, xm r2 w500 Icon vLstOfIcons,Icon

Gui, Add, Radio, xm Section gRadIconsReport ,Report
Gui, Add, Radio, ys Checked gRadIconsIcons , Icons
Gui, Add, Radio, ys gRadIconsSmallIcons ,small Icons
Gui, Add, Radio, ys gRadIconsList , List

Gui, Show

;create new list of small images and replace and delete old one
IListIDIconsSmall := IL_Create(10, 10, False)
LV_SetImageList(IListIDIconsSmall)

;create new list of large images and replace and delete old one
IListIDIconsLarge := IL_Create(10, 10, True)
LV_SetImageList(IListIDIconsLarge)

;Search for 9999 icons in the selected file
Loop, 9999
  {
    ;get small icon
    ID := IL_Add(IListIDIconsSmall, A_WinDir . "\system32\shell32.dll" , A_Index)

    ;if small icon exist
    If ID > 0
      {
        ;get large icon
        IL_Add(IListIDIconsLarge, A_WinDir . "\system32\shell32.dll" , A_Index)

        ;add icon to list
        LV_Add("Icon" . A_Index, A_Index)
      }
    Else
        Break
  }

;Adjust width
LV_ModifyCol()
Return

;#############   Change of view mode for icon list   ##########################
RadIconsReport:
  GuiControl, +Report, LstOfIcons
  Gui, ListView, LstOfIcons
  LV_ModifyCol()
Return

RadIconsIcons:
  GuiControl, +Icon, LstOfIcons
Return

RadIconsSmallIcons:
  GuiControl, +IconSmall, LstOfIcons
Return

RadIconsList:
  GuiControl, +List, LstOfIcons
Return

;#############   Close window   ###############################################
GuiClose:
GuiEscape:
  ExitApp
Return
;#############   End of File   ################################################