AutoHotkey Community

var = "cheese"

WS_Initialize()
WS_Exec("Dim Array(3)")
code =
(
Array(0) = "Clean Underwear"
Array(1) = "Vacuum Cleaner"
Array(2) = "New Computer"
Array(3) = %var%
)
WS_Exec(code)
WS_Eval(x, "Array(2)")
WS_Uninitialize()

msgbox % x
return

var = "cheese"

COM_Init()
Array := COM_CreateObject("Scripting.Dictionary")
COM_Invoke(Array, "Item", 0, "Clean Underwear")
COM_Invoke(Array, "Item", "one!", "Vacuum Cleaner") ; Not limited to numeric indices.
COM_Invoke(Array, "Item", 2, "New Computer")
COM_Invoke(Array, "Item", 3, var)
x := COM_Invoke(Array, "Item", 2)
COM_Term()

msgbox % x
return

var = "cheese"

A_Put(Array, _:="Clean Underwear") ; _:= because parameter is ByRef.
A_Put(Array, _:="Vacuum Cleaner")
A_Put(Array, _:="New Computer")
A_Put(Array, var, 4) ; Index is optional if appending. Note one-based (4 vs 3).
x := A_Get(Array, 2)

msgbox % x
return

var = "cheese"

VarSetCapacity(Array, 4*4)
NumPut(DllCall("shlwapi\StrDupA", "str", "Clean Underwear"), Array,  0)
NumPut(DllCall("shlwapi\StrDupA", "str", "Vacuum Cleaner"),  Array,  4)
NumPut(DllCall("shlwapi\StrDupA", "str", "New Computer"),    Array,  8)
NumPut(DllCall("shlwapi\StrDupA", "str", var),               Array, 12)
x := DllCall("MulDiv", "int", NumGet(Array, 12), "int", 1, "int", 1, "str")
Loop, 4
    DllCall("LocalFree", "uint", NumGet(Array, A_Index*4-4))

msgbox % "Mmm, " x "."
return

COM_Init()
Array := COM_CreateObject("Scripting.Dictionary")
COM_Invoke(Array, "Item", "w", 2)
COM_Invoke(Array, "Item", "h", 2)
COM_Invoke(Array, "Item", "1,1", "aa")
COM_Invoke(Array, "Item", "2,1", "ab")
COM_Invoke(Array, "Item", "1,2", "ba")
COM_Invoke(Array, "Item", "2,2", "bb")
Loop % COM_Invoke(array, "Item", "h")
{
    n := A_Index
    Loop % COM_Invoke(array, "Item", "w")
        MsgBox % COM_Invoke(Array, "Item", A_Index "," n)
}
COM_Term()
return

Array_w = 2
Array_h = 2
Array_1_1 = aa
Array_2_1 = ab
Array_1_2 = ba
Array_2_2 = bb
Loop % Array_h
{
    n := A_Index
    Loop % Array_w
        MsgBox % Array_%A_Index%_%n%
}

x := COM_Invoke(Array, "Items")
x := COM_Invoke(Array, "Keys")

penum := COM_Invoke(Array, "_NewEnum")
While COM_Enumerate(penum, key) = 0
    text .= key "=" COM_Invoke(Array, "Item", key) "`n"
COM_Release(penum)
MsgBox % text

Array := COM_CreateObject("Scripting.Dictionary")

Exe(ptr, code)
{   COM_Invoke(ptr, "ExecuteStatement", code)
}

Eval(ptr, code, param = 0)
{   if param = N   ; only for sort() function - to sort numbers correctly
   {   stringreplace code, code, (), , A
      code =
      (   
      function sortNumber(a, b)
      {
      return a - b;
      }
      %code%(sortNumber)
      )
      COM_Invoke(ptr, "ExecuteStatement", code)
      return
   }   
   else
      return COM_Invoke(ptr, "Eval", code)
}

COM_Init()
A := COM_CreateObject("MSScriptControl.ScriptControl")
COM_Invoke(A, "Language", "JScript")

Exe(A, "var arr1 = new Array()")
Exe(A, "var arr2 = new Array()")
code =
(
arr1[0] = "This";
arr1[1] = "is";
arr1[2] = "an"
arr1[3] = "Array"
arr2[0] = "10";
arr2[1] = "5";
arr2[2] = "40";
arr2[3] = "25";
arr2[4] = "1000";
arr2[5] = "1";
)
Exe(A, code)

msgbox % Eval(A, "arr1.push('Additional')")
msgbox % Eval(A, "arr1.join('.')")
msgbox % Eval(A, "arr2.join('.')")
Eval(A, "arr2.sort()", "N")
msgbox % Eval(A, "arr2.join('.')")

COM_Release(A)
COM_Term()
return

COM_Init()
arr := COM_ScriptControl("var arr = new Array('This', 'is', 'a', 'test', '!');`r`n arr;", "JScript", 1)
Loop,   % COM_Invoke(arr, "length")
MsgBox, % COM_Invoke(arr, A_Index-1)
COM_Release(arr)
COM_Term()