.AHK
Joined: 26 Apr 2006
Posts: 662
Location: USA
|
 Posted: Mon Nov 27, 2006 11:27 pm Post subject: IE 7 & Script Error |
 |
|
After installing Internet Explorer 7 I found that an error from AutoHotKey gets displayed while running my script, after opening any menu on IE 7.
The error is given by my TimeClip script. This is the error information.
Title: "TimeGUI: AutoHotkey.exe - Entry Point Not Found"
Description: "The procedure entry point GetProcessImageFileNameW could not be located in the dynamic link library PSAPI.DLL."
TimeClip script:
| Code: | ; Timeclip.ahk - Made by ".AHK"
; Ctrl+Alt+LMouse - Hide/Reposition GUI
; Ctrl+Alt+RMouse - Toggle Off/On AlwaysOnTop
; Ctrl+Alt+C - Hide/Show Clipboard Tooltip
; Ctrl+Alt+E - Exit script
; Ctrl+Alt+S - Shutdown Computer
; Ctrl+Alt+R - Restart Computer
#NoEnv
#NoTrayIcon
NoShow = 1
CoordMode Mouse, Screen
CoordMode ToolTip, Screen
DetectHiddenWindows On
Gui Font, S11
Gui Color, Red
Gui -SysMenu +LastFound -Theme +ToolWindow +AlwaysOnTop
FormatTime, TimeString, R
Gui Add, Button, x0 y0 H30 W265 vthetime, %TimeString%
T = 2000
T += A_TickCount/1000,Seconds
FormatTime FormdT, %T%, HH'h 'mm'm 'ss's'
Gui Add, Button, x0 H30 W265 vidletime, Elapsed time after bootup: %FormdT%
Gui Add, Button, x0 H30 W265 vclipboardB gclipboardGS, Show the contents of the clipboard.
Gui Add, Button, x0 H30 W125 vShutdownC gShutdownComp, Shutdown
Gui Add, Button, x140 y+-30 H30 W125 vRestartC gRestartComp, Restart
WinSet TransColor, Red 250
Gui -Caption
Gui Show, Center, TimeGUI
Loop {
Sleep 30
T = 2000
T += A_TickCount/1000,Seconds
FormatTime FormdT, %T%, HH'h 'mm'm 'ss's'
GuiControl,, idletime, Elapsed time after bootup: %FormdT%
If A_Sec <= 01
{
FormatTime, TimeString, R
GuiControl,, thetime, %TimeString%
}
}
Return
ShutdownComp:
MsgBox 4100, Prompt, Shutdown computer?
IfMsgBox Yes
Shutdown 9
Return
^!S::Gosub ShutdownComp
^!R::Gosub RestartComp
RestartComp:
MsgBox 4100, Prompt, Restart computer?
IfMsgBox Yes
Shutdown 2
Return
^!LButton::
amt++
If amt = 1
{ WinHide TimeGUI
Return
}
Else
{ amt = 0
MouseGetPos MouseX, MouseY
WinMove TimeGUI,, %MouseX%, %MouseY%
WinShow TimeGUI
}
Return
^!RButton::
Amt2++
If amt2 = 1
WinSet AlwaysOnTop, Off, TimeGUI
Else
{ amt2 = 0
WinSet AlwaysOnTop, On, TimeGUI
}
Return
~^c::
If NoShow = 1
Return
Gosub clipboardGS
Return
^!c::
clipboardGS:
Amt3++
If Amt3 = 1
{
NoShow = 0
GuiControl,, clipboardB, Hide the contents of the clipboard.
Gosub ClipboardChange
}
Else
{ Amt3 = 0
GuiControl,, clipboardB, Show the contents of the clipboard.
ToolTip
NoShow = 1
}
Return
OnClipboardChange:
Gosub ClipboardChange
Return
ClipboardChange:
ClipboardContents =
If NoShow = 1
Return
ToolTip
FormatTime, TimeString, R
ClipboardContents = %Clipboard%
If ClipboardContents =
ClipboardContents = The clipboard is currently empty or contains an image.
ToolTip %TimeString%`n`n%ClipboardContents%, 25, 25
Amt = 0
return
^!e::ExitApp |
|
|
FAQ
Search
Memberlist
Register
Profile
Log in to check your private messages
Log in
