26 replies to this topic

[Bruttosozialprodukt]

I couldn't find a short script that shows a progressbar while downloading. There was alreays a big lib or function necessary. So I came up with this great piece of code:
v1.1

DownloadFile(UrlToFile, SaveFileAs, Overwrite := True, UseProgressBar := True) {
    ;Check if the file already exists and if we must not overwrite it
      If (!Overwrite && FileExist(SaveFileAs))
          Return
    ;Check if the user wants a progressbar
      If (UseProgressBar) {
          ;Initialize the WinHttpRequest Object
            WebRequest := ComObjCreate("WinHttp.WinHttpRequest.5.1")
          ;Download the headers
            WebRequest.Open("HEAD", UrlToFile)
            WebRequest.Send()
          ;Store the header which holds the file size in a variable:
            FinalSize := WebRequest.GetResponseHeader("Content-Length")
          ;Create the progressbar and the timer
            Progress, H80, , Downloading..., %UrlToFile%
            SetTimer, __UpdateProgressBar, 100
      }
    ;Download the file
      UrlDownloadToFile, %UrlToFile%, %SaveFileAs%
    ;Remove the timer and the progressbar because the download has finished
      If (UseProgressBar) {
          Progress, Off
          SetTimer, __UpdateProgressBar, Off
      }
    Return
    
    ;The label that updates the progressbar
      __UpdateProgressBar:
          ;Get the current filesize and tick
            CurrentSize := FileOpen(SaveFileAs, "r").Length ;FileGetSize wouldn't return reliable results
            CurrentSizeTick := A_TickCount
          ;Calculate the downloadspeed
            Speed := Round((CurrentSize/1024-LastSize/1024)/((CurrentSizeTick-LastSizeTick)/1000)) . " Kb/s"
          ;Save the current filesize and tick for the next time
            LastSizeTick := CurrentSizeTick
            LastSize := FileOpen(SaveFileAs, "r").Length
          ;Calculate percent done
            PercentDone := Round(CurrentSize/FinalSize*100)
          ;Update the ProgressBar
            Progress, %PercentDone%, %PercentDone%`% Done, Downloading...  (%Speed%), Downloading %SaveFileAs% (%PercentDone%`%)
      Return
}

Examples of usage:

Spoiler

Example 1 - Download a firefox setup with a progressbar and overwrite it if it already exists on the disk:

DownloadFile("http://download-installer.cdn.mozilla.net/pub/firefox/releases/26.0/win32/en-US/Firefox%20Setup%2026.0.exe", "firefox_setup.exe")

Example 2 - Download Autohotkey with a progressbar and don't overwrite it if it already exists:

Url = http://ahkscript.org/download/ahk-install.exe
DownloadAs = AutoHotkey_L Installer.exe
Overwrite := False
UseProgressBar := True
DownloadFile(Url, DownloadAs, Overwrite, UseProgressBar)

Example 3 - Download a CCleaner setup and open a Save As dialog, asking the user where to save the file, overwriting it if already exists:

FileSelectFile, SaveAs, S, ccsetup410.exe
DownloadFile("http://download.piriform.com/ccsetup410.exe", SaveAs, True, True)

Screenshot:

Spoiler

Older versions:

Spoiler

v1.0

DownloadFile(UrlToFile, _SaveFileAs, Overwrite := True, UseProgressBar := True) {
    ;Check if the file already exists and if we must not overwrite it
      If (!Overwrite && FileExist(_SaveFileAs))
          Return
    ;Check if the user wants a progressbar
      If (UseProgressBar) {
          ;Make variables global that we need later when creating a timer
            Global SaveFileAs := _SaveFileAs, FinalSize
          ;Initialize the WinHttpRequest Object
            WebRequest := ComObjCreate("WinHttp.WinHttpRequest.5.1")
          ;Download the headers
            WebRequest.Open("HEAD", UrlToFile)
            WebRequest.Send()
          ;Store the header which holds the file size in a variable:
            FinalSize := WebRequest.GetResponseHeader("Content-Length")
            Progress, H80, , Downloading..., %UrlToFile% Download
            SetTimer, UpdateProgressBar, 100
      }
    ;Download the file
      UrlDownloadToFile, %UrlToFile%, %_SaveFileAs%
    ;Remove the timer and the progressbar  because the download has finished
      If (UseProgressBar) {
          Progress, Off
          SetTimer, UpdateProgressBar, Off
      }
}

UpdateProgressBar:
    ;Get the current filesize and tick
      CurrentSize := FileOpen(SaveFileAs, "r").Length ;FileGetSize wouldn't return reliable results
      CurrentSizeTick := A_TickCount
    ;Calculate the downloadspeed
      Speed := Round((CurrentSize/1024-LastSize/1024)/((CurrentSizeTick-LastSizeTick)/1000)) . " Kb/s"
    ;Save the current filesize and tick for the next time
      LastSizeTick := CurrentSizeTick
      LastSize := FileOpen(SaveFileAs, "r").Length
    ;Calculate percent done
      PercentDone := Round(CurrentSize/FinalSize*100)
    ;Update the ProgressBar
      Progress, %PercentDone%, %PercentDone%`% Done, Downloading...  (%Speed%), Downloading %SaveFileAs% (%PercentDone%`%)
Return

Changelog:

Spoiler

v1.1
-The label is inside of the function now.
-Removed globals.
-Commented a line that I forgot to comment in the initial release.
-Renamed variable _SaveFileAs to SaveFileAs.
-Renamed label UpdateProgressBar to __UpdateProgressBar.

I hope anyone of you finds this usefull. Tell me if you have ideas for improvement.

edit:
Check out this post:
http://www.autohotke...ar/#entry630902
an even shorter example!

[Guest10]

Nice script. Is there a way I can "Save As" in the above examples without Overwriting if files already exist on the disk?

[RHCP]

That's a really neat function!

 

if you place the label inside the function, then you don't have to use any global variables

I use a longer label name, as the label name is still global and so can obviously be called from anywhere else in the script i.e. clash with a users own label.

 

DownloadFile(UrlToFile, _SaveFileAs, Overwrite := True, UseProgressBar := True) {
    ;Check if the file already exists and if we must not overwrite it
      If (!Overwrite && FileExist(_SaveFileAs))
      {
        FileSelectFile, _SaveFileAs,S, %_SaveFileAs%
        if !_SaveFileAs ; user didnt select anything
          return
      }

    ;Check if the user wants a progressbar
      If (UseProgressBar) {
          ;Make variables global that we need later when creating a timer
            SaveFileAs := _SaveFileAs
          ;Initialize the WinHttpRequest Object
            WebRequest := ComObjCreate("WinHttp.WinHttpRequest.5.1")
          ;Download the headers
            WebRequest.Open("HEAD", UrlToFile)
            WebRequest.Send()
          ;Store the header which holds the file size in a variable:
            FinalSize := WebRequest.GetResponseHeader("Content-Length")
            Progress, H80, , Downloading..., %UrlToFile% Download
            SetTimer, DownloadFileFunction_UpdateProgressBar, 100
      }
    ;Download the file
      UrlDownloadToFile, %UrlToFile%, %_SaveFileAs%
    ;Remove the timer and the progressbar  because the download has finished
      If (UseProgressBar) {
          Progress, Off
          SetTimer, DownloadFileFunction_UpdateProgressBar, Off
      }
      return

      DownloadFileFunction_UpdateProgressBar:
    ;Get the current filesize and tick
      CurrentSize := FileOpen(_SaveFileAs, "r").Length ;FileGetSize wouldn't return reliable results
      CurrentSizeTick := A_TickCount
    ;Calculate the downloadspeed
      Speed := Round((CurrentSize/1024-LastSize/1024)/((CurrentSizeTick-LastSizeTick)/1000)) . " Kb/s"
    ;Save the current filesize and tick for the next time
      LastSizeTick := CurrentSizeTick
      LastSize := FileOpen(_SaveFileAs, "r").Length
    ;Calculate percent done
      PercentDone := Round(CurrentSize/FinalSize*100)
    ;Update the ProgressBar
      Progress, %PercentDone%, %PercentDone%`% Done, Downloading...    (%Speed%), Downloading %_SaveFileAs% (%PercentDone%`%)
      return
}

 

Nice script. Is there a way I can "Save As" in the above examples without Overwriting if files already exist on the disk?

 

Try the above function with overwrite disabled.

DownloadFile("http://download-installer.cdn.mozilla.net/pub/firefox/releases/26.0/win32/en-US/Firefox%20Setup%2026.0.exe", A_ScriptDir "\firefox_setup.exe", 0)

 

[Bruttosozialprodukt]

@Guest10 My second example does exactly what you want. The third parameter simply needs to be False or 0.

@RHCP

Thanks, I wasn't aware that you could put a label into a function.

To make sure that a variable/function/label name is unique I usually just put 2 __ in the beginning.
FileSelectFile is something you should call before the function in my opinion.

I will update the first post.

[garry]

very nice Bruttosozialprodukt , found  another short  example  from user DataLife

;-------- http://www.autohotkey.com/board/topic/17915-urldownloadtofile-progress/page-4 ---
sUrl:="http://download-installer.cdn.mozilla.net/pub/firefox/releases/26.0/win32/en-US/Firefox%20Setup%2026.0.exe"
SplitPath, surl, name, dir, ext, name_no_ext, drive
sFile=%a_desktop%\%name%     ;- where to download
ifexist,%sFile%
   filedelete,%sFile%

;-----------------------------------------------
a:=a_tickcount
Progress, % "M W" . A_ScreenWidth//2, 0, 0 of 0
VarSetCapacity(vt, 4*11), nParam = 31132253353
Loop, Parse, nParam
	NumPut(RegisterCallback("DownloadProgress", "Fast", A_LoopField, A_Index-1), vt, 4*(A_Index-1))
DllCall("urlmon\URLDownloadToFileA", "Uint", 0, "str", sUrl, "str", sFile, "Uint", 0, "UintP", &vt)
delta:=((a_tickcount-a)/1000)
msgbox, 262208,Downloaded ,Downloaded in %delta% seconds

DownloadProgress(pthis, nProgress = 0, nProgressMax = 0, nStatusCode = 0, pStatusText = 0)
{
	If A_EventInfo = 6
	Progress, % p := 100 * nProgress//nProgressMax, %p%, % nProgress . " of " . nProgressMax
	Return 0
}
return
;----------------------------------

[Bruttosozialprodukt]

Thanks this looks very interessting!
Some comments on what numput does here and what the dllcall parameters do would have been nice though.
Any idea where I can find documentation on urlmon\URLDownloadToFileA?

[Godric]

Thank you so much for this script.

[Guest10]

could you evangelize this also on http://ahkscript.org/boards/ ?

[Bruttosozialprodukt]

Here you go: http://ahkscript.org...&t=1674&p=10020

[Bruttosozialprodukt]

Here is an alternative to UrlDownloadToFile:

UrlToFile := "http://ahkscript.org/download/1.1/AutoHotkey111402_Install.exe"
SaveFileAs := A_ScriptDir . "\AHK_Install.exe"
OverWrite := True

WinHttpObj := ComObjCreate("WinHttp.WinHttpRequest.5.1")
WinHttpObj.Open("GET", UrlToFile)
WinHttpObj.Send()

ADODBObj := ComObjCreate("ADODB.Stream")
ADODBObj.Type := 1
ADODBObj.Open()
ADODBObj.Write(WinHttpObj.ResponseBody)
ADODBObj.SaveToFile(SaveFileAs, Overwrite ? 2:1)
ADODBObj.Close()

For bigger files, using this this might be a bad idea, because the file will initially be downloaded into the RAM and only be moved to the disc, when the download finished.

[capbat]

Glad to see that this thread is still alive.

Thank your for this script, I was looking for exactly this.

 

Bat

[capbat]

Hi Brutto.

 

I have been using your app for a week or so without any problem but today I am having an error at line.

 FinalSize := WebRequest.GetResponseHeader("Content-Length")

The file on the server exist it has a size of 865,792 bytes.

The Error I am Getting is "The  requested Header was not found"

 

Any suggestion.

 

Bat

[capbat]

I have fixed my problem above.

But I am wondering now if this could be adapted to a File copy or move FileDirCopy?.

 

Thanks.

[jhabers]

Here is an alternative to UrlDownloadToFile:

UrlToFile := "http://ahkscript.org/download/1.1/AutoHotkey111402_Install.exe"
SaveFileAs := A_ScriptDir . "\AHK_Install.exe"
OverWrite := True

WinHttpObj := ComObjCreate("WinHttp.WinHttpRequest.5.1")
WinHttpObj.Open("GET", UrlToFile)
WinHttpObj.Send()

ADODBObj := ComObjCreate("ADODB.Stream")
ADODBObj.Type := 1
ADODBObj.Open()
ADODBObj.Write(WinHttpObj.ResponseBody)
ADODBObj.SaveToFile(SaveFileAs, Overwrite ? 2:1)
ADODBObj.Close()

For bigger files, using this this might be a bad idea, because the file will initially be downloaded into the RAM and only be moved to the disc, when the download finished.

 

 

 

 

 

I am trying to get this download method working with a status bar but cant seem to get it to work. The reson i like this download method is because I am running this from a USB thumbdrive and the other way goes very slow. Here is what I have. can anyone help?

	Url            =  http://download.adlice.com/RogueKiller/RogueKiller.exe
	DownloadAs     = RogueKiller.exe
	Overwrite      := True
	UseProgressBar := True
	DownloadFile(Url, DownloadAs, Overwrite, UseProgressBar)
	

;=================== Start Functions =====================================================================

DownloadFile(UrlToFile, SaveFileAs, Overwrite := True, UseProgressBar := True) {
    ;Check if the file already exists and if we must not overwrite it
      If (!Overwrite && FileExist(SaveFileAs))
          Return
    ;Check if the user wants a progressbar
      If (UseProgressBar) {
          ;Initialize the WinHttpRequest Object
            WebRequest := ComObjCreate("WinHttp.WinHttpRequest.5.1")
          ;Download the headers
            WebRequest.Open("HEAD", UrlToFile)
            WebRequest.Send()
          ;Store the header which holds the file size in a variable:
            FinalSize := WebRequest.GetResponseHeader("Content-Length")
          ;Create the progressbar and the timer
            Progress, H80, , Downloading..., %UrlToFile%
            SetTimer, __UpdateProgressBar, 1000
      }
    ;Download the file 
	WinHttpObj := ComObjCreate("WinHttp.WinHttpRequest.5.1")
	WinHttpObj.Open("GET", UrlToFile)
	WinHttpObj.Send()

	ADODBObj := ComObjCreate("ADODB.Stream")
	ADODBObj.Type := 1
	ADODBObj.Open()
	ADODBObj.Write(WinHttpObj.ResponseBody)
	ADODBObj.SaveToFile(SaveFileAs, Overwrite ? 2:1)
	ADODBObj.Close()
	  
	  
    ;Remove the timer and the progressbar because the download has finished
      If (UseProgressBar) {
          Progress, Off
          SetTimer, __UpdateProgressBar, Off
      }
    Return
    
    ;The label that updates the progressbar
      __UpdateProgressBar:
          ;Get the current filesize and tick
            CurrentSize := FileOpen(SaveFileAs, "r").Length ;FileGetSize wouldn't return reliable results
            CurrentSizeTick := A_TickCount
          ;Calculate the downloadspeed
            Speed := Round((CurrentSize/1024-LastSize/1024)/((CurrentSizeTick-LastSizeTick)/1000)) . " Kb/s"
          ;Save the current filesize and tick for the next time
            LastSizeTick := CurrentSizeTick
            LastSize := FileOpen(SaveFileAs, "r").Length
          ;Calculate percent done
            PercentDone := Round(CurrentSize/FinalSize*100)
          ;Update the ProgressBar
            Progress, %PercentDone%, %PercentDone%`% Done, Downloading...  (%Speed%), Downloading %SaveFileAs% (%PercentDone%`%)
      Return
}

[jhabers]

Anybody have any idea? Thanks!