2 replies to this topic

[aCkRiTe]

You can try this. This will get any active window that is not named 'Program Manager'... Program Manager is the window title for the desktop, as far as I know, at least on XP.

Loop
	{
		Sleep, 1000
		WinGetActiveTitle, Var
		If Var <> Program Manager
			Break
	}
MsgBox, %Var%

HTH...

[JSLover]

I use WinWaitNotActive to wait for "any next window"...

;//remember current window...
hwndtmp:="ahk_id " WinExist("a")

;//insert code here to cause a window to become active...for example...
Run, notepad

;//next line for debug only...show tooltip while waiting...
Tooltip, waiting...

;//wait for remembered window to NOT be active...means "something" else is active...
;//increase/decrease timeout as needed for this situation...8 means 8 seconds...
WinWaitNotActive, %hwndtmp%, , 8
if (errorlevel) {
	;//next line for debug only...clear tooltip...
	Tooltip

	;//it's good to handle timeouts in your code, so it doesn't get stuck...& you don't know why...
	;//msgbox, 16, , WinWait Timeout waiting for <type helpful description here> window
	msgbox, 16, , WinWait Timeout waiting for Notepad window
}
;//next line for debug only...clear tooltip...
Tooltip

;//get an hwnd of JUST this window...& use it to reference this window...
hwnd:="ahk_id " WinExist("a")

;//your code continues here...
msgbox, 64, , Debug: hwnd(%hwnd%)`n`ndone!

...this may be a bad example, since if you ARE using Run to "cause the window to appear"...you should try to use the pid param of run...but sometimes the pid fails, so this is a good workaround...just in-case you are using Run, here's an example of how to use the pid...

;//run a program, save the pid...
Run, notepad, , , pid

;//next line for debug only...show tooltip while waiting...
Tooltip, waiting...

;//wait for a window matching the Run pid, to EXIST...
;//change this to use active, if you want to only continue if it's active...
;//increase/decrease timeout as needed for this situation...8 means 8 seconds...
WinWait, ahk_pid %pid%, , 8
if (errorlevel) {
	;//next line for debug only...clear tooltip...
	Tooltip

	;//it's good to handle timeouts in your code, so it doesn't get stuck...& you don't know why...
	;//msgbox, 16, , WinWait Timeout waiting for <type helpful description here> window
	msgbox, 16, , WinWait Timeout waiting for Notepad window
}
;//next line for debug only...clear tooltip...
Tooltip

;//then for even better (more specific) code, trade the pid for an hwnd of JUST this window...
hwndnotepad:="ahk_id " WinExist()

;//your code continues here...
msgbox, 64, , Debug: pid(%pid%) hwndnotepad(%hwndnotepad%)`n`ndone!