12 replies to this topic

[GeekDude]

Originally just one function, now a library of 4!

 

 

Functions included:

 

Array_Print(Array)

• Returns a textual representation of an array
• Won't print circular arrays (returns error)

 

Array_Gui(Array)

• Creates a GUI with a treeview representation of an array
• Remembers and goes back to the default GUI
• Resizeable (Can I get a spell check in here?)
• Won't print circular arrays (returns error)

 

Array_IsCircle(Array)

• Returns a boolean value according to whether or not the array contains itself

 

Array_DeepClone(Array)

• Returns a copy of the input array, with all sub arrays cloned as well
• Will create a circular reference where there was one in the input array

 

 

Example:

Spoiler

Array := {"A":{"Fruit":["Apple", "Apricot"], "Animals":["Aardvark", "Antelope"]}, "B":{"Fruit":["Banana", "Blueberry"], "Animals":["Bee", "Barnacle"]}, "C":"The alphabet :D"}

Gui, Add, Text,, % Array_Print(Array)
Array_Gui(Array)
Gui, Show
return

GuiClose:
Gui, Destroy
MsgBox,
(
I can detect circular arrays!

Array1 := []
Array1[1] := 1
Array2 := []
Array2[1] := Array2
MsgBox, `% "Array1: " Array_IsCircle(Array1) "``n"
. "Array2: " Array_IsCircle(Array2)
)

Array1 := []
Array1[1] := 1
Array2 := []
Array2[1] := Array2
MsgBox, % "Array1: " Array_IsCircle(Array1) "`n"
. "Array2: " Array_IsCircle(Array2)

MsgBox, Now that we have a circular array, let's try out our display functions with it!
MsgBox, % "Array_Gui: " Array_Gui(Array2) "`nArray_Print: " Array_Print(Array2)

MsgBox,
(
If I have an array, and I want to make another array with the same contents, I would do this:

Array := ["Contents"]
Array2 := Array.Clone()
Array2[1] := "Different contents"
Array_Gui(Array)
Array_Gui(Array2)
)

Array := ["Contents"]
Array2 := Array.Clone()
Array2[1] := "Different contents"
Array_Gui(Array)
Array_Gui(Array2)

MsgBox,
(
It appears to work just fine. However, if Array has Sub-Array(s):

Array := [["Contents"]]
Array2 := Array.Clone()
Array2[1,1] := "Different contents"
Array_Gui(Array)
Array_Gui(Array2)
)

Array := [["Contents"]]
Array2 := Array.Clone()
Array2[1,1] := "Different contents"
Array_Gui(Array)
Array_Gui(Array2)

MsgBox,
(
The sub-arrays are still linked. To fix this, we need to make a deep clone:

Array := [["Contents"]]
Array2 := Array_DeepClone(Array)
Array2[1,1] := "Different contents"
Array_Gui(Array)
Array_Gui(Array2)
)

Array := [["Contents"]]
Array2 := Array_DeepClone(Array)
Array2[1,1] := "Different contents"
Array_Gui(Array)
Array_Gui(Array2)

MsgBox,
(
All is well at last. One of my favorite features of my deep clone function,
is that circular refrences are cloned as well. An array that has a circle like this:
A -> B -> C -> B -> C -> ...
would be made into an array with a circle like this:
X -> Y -> Z -> Y -> Z -> ...

To demonstrate this, we can use this code:

A := [[[]]]
A[1,1,1] := A[1]
MsgBox, `% ""
. &A[1] " - B's Pointer``n"
. &A[1,1,1] " - Pointer to C's contents"

X := Array_DeepClone(A)
MsgBox, `% ""
. &X[1] " - Y's Pointer``n"
. &X[1,1,1] " - Pointer to Z's contents"
)

A := [[[]]]
A[1,1,1] := A[1]
MsgBox, % ""
. &A[1] " - B's Pointer`n"
. &A[1,1,1] " - Pointer to C's contents"

X := Array_DeepClone(A)
MsgBox, % ""
. &X[1] " - Y's Pointer`n"
. &X[1,1,1] " - Pointer to Z's contents"
return

 

Code:

Spoiler

;
; Function:
; Array_Print
; Description:
; Quick and dirty text visualization of an array
; Syntax:
; Arrary_Print(Array)
; Parameters:
; Param1 - Array
; An array, associative array, or object.
; Return Value:
; A text visualization of the input array
; Remarks:
; Supports sub-arrays
; Related:
; Array_Gui, Array_DeepClone, Array_IsCircle
; Example:
; MsgBox, % Array_Print({"A":["Aardvark", "Antelope"], "B":"Bananas"})
;
 
Array_Print(Array) {
if Array_IsCircle(Array)
        return "Error: Circular refrence"
    For Key, Value in Array
    {
        If Key is not Number
            Output .= """" . Key . """:"
        Else
            Output .= Key . ":"
        
        If (IsObject(Value))
            Output .= "[" . Array_Print(Value) . "]"
        Else If Value is not number
            Output .= """" . Value . """"
        Else
            Output .= Value
        
        Output .= ", "
    }
    StringTrimRight, OutPut, OutPut, 2
    Return OutPut
}
 
 
;
; Function:
; Array_Gui
; Description:
; Displays an array as a treeview in a GUI
; Syntax:
; Array_Gui(Array)
; Parameters:
; Param1 - Array
; An array, associative array, or object.
; Return Value:
; Null
; Remarks:
; Resizeable
; Related:
; Array_Print, Array_DeepClone, Array_IsCircle
; Example:
; Array_Gui({"GeekDude":["Smart", "Charming", "Interesting"], "tidbit":"Weird"})
;
 
Array_Gui(Array, Parent="") {
    static
    global GuiArrayTree, GuiArrayTreeX, GuiArrayTreeY
    if Array_IsCircle(Array)
    {
        MsgBox, 16, GuiArray, Error: Circular refrence
        return "Error: Circular refrence"
    }
    if !Parent
    {
        Gui, +HwndDefault
        Gui, GuiArray:New, +HwndGuiArray +LabelGuiArray +Resize
        Gui, Add, TreeView, vGuiArrayTree
        
        Parent := "P1"
        %Parent% := TV_Add("Array", 0, "+Expand")
        Array_Gui(Array, Parent)
        GuiControlGet, GuiArrayTree, Pos
        Gui, Show,, GuiArray
        Gui, %Default%:Default
        
        WinWaitActive, ahk_id%GuiArray%
        WinWaitClose, ahk_id%GuiArray%
        return
    }
    For Key, Value in Array
    {
        %Parent%C%A_Index% := TV_Add(Key, %Parent%)
        KeyParent := Parent "C" A_Index
        if (IsObject(Value))
            Array_Gui(Value, KeyParent)
        else
            %KeyParent%C1 := TV_Add(Value, %KeyParent%)
    }
    return
    
    GuiArrayClose:
    Gui, Destroy
    return
    
    GuiArraySize:
    if !(A_GuiWidth || A_GuiHeight) ; Minimized
        return
    GuiControl, Move, GuiArrayTree, % "w" A_GuiWidth - (GuiArrayTreeX * 2) " h" A_GuiHeight - (GuiArrayTreeY * 2)
    return
}
 
 
;
; Function:
; Array_DeepClone
; Description:
; Deep clone
; Syntax:
; Arrary_DeepClone(Array)
; Parameters:
; Param1 - Array
; An array, associative array, or object.
; Return Value:
; A copy of the array, that is not linked to the original
; Remarks:
; Supports sub-arrays, and circular refrences
; Related:
; Array_Gui, Array_Print, Array_IsCircle
; Example:
; Array1 := {"A":["Aardvark", "Antelope"], "B":"Bananas"}
; Array2 := Array_DeepClone(Array1)
;
 
Array_DeepClone(Array, Objs=0)
{
    if !Objs
        Objs := {}
    Obj := Array.Clone()
    Objs[&Array] := Obj ; Save this new array
    For Key, Val in Obj
        if (IsObject(Val)) ; If it is a subarray
            Obj[Key] := Objs[&Val] ; If we already know of a refrence to this array
            ? Objs[&Val] ; Then point it to the new array
            : Array_DeepClone(Val,Objs) ; Otherwise, clone this sub-array
    return Obj
}
 
 
;
; Function:
; Array_IsCircle
; Description:
; Checks for circular refrences that could crash my other functions
; Syntax:
; Arrary_IsCircle(Array)
; Parameters:
; Param1 - Array
; An array, associative array, or object.
; Return Value:
; Boolean value according to whether it has a circular refrence
; Remarks:
; Takes an average of 0.023 seconds
; Related:
; Array_Gui, Array_Print(), Array_DeepClone()
; Example:
; Array1 := {"A":["Aardvark", "Antelope"], "B":"Bananas"}
; Array2 := Array_Copy(Array1)
;
 
Array_IsCircle(Obj, Objs=0)
{
    if !Objs
        Objs := {}
    For Key, Val in Obj
        if (IsObject(Val)&&(Objs[&Val]||Array_IsCircle(Val,(Objs,Objs[&Val]:=1))))
            return 1
    return 0
}

[GeekDude]

Update:
- Fixed re-size
- Made top level expanded by default
- Uses three global variables (Could possibly be reduced to two, maybe one, by using an array)
- Some other stuff too

[GeekDude]

I was changing some code to make it so that you can edit the treeview, and about 3/4 (I think) of the way in to writing the treeview to array converter, I thought "I can't see how this would be useful, and it is very difficult to create". If anyone wants this feature, please say so. I will proceed to either continue working on it, or paste what I have (that is not working) here.

[GeekDude]

Major update, with many new features!

[raoyc]

Thanks for your code

[R3gX]

Yep, cool code!

 

I really like the 'Array_IsCircle()' code.

Could I use it in one of my scripts if I write you nickname (& post's url) ?

[GeekDude]

Yep, cool code!

 

I really like the 'Array_IsCircle()' code.

Could I use it in one of my scripts if I write you nickname (& post's url) ?

 

Sure!

[R3gX]

Thanks!

 

Yesterday I tried to do some modifications in your code to allow users to change the TreeView's values.

Next, I spent all day to code a function to save the treeview into an array. No so easy for me but I succeed (for at least one 'Leaf')!

The problem is that the treeview's array is... circle!

 

Do you have any ideas?!

[nordanalt]

Thanks for these!

I was fiddling around and trying to implement deep cloning myself, and I came up with this:

deepCopy(pArray){
    eArray := Object()
    for ix, pElement in pArray
    {
        if (!isObject(pElement)){
            eArray.Insert(ix, pElement)
        } else {
            eArray.Insert(ix, deepCopy(pElement))
        }
    }
    return eArray
}

Using this function I get the same results for the examples in your code as with your function, but I'm not sure if my function works in every case. Do you think I'm missing something? Cheers.

[GeekDude]

Thanks for these!

I was fiddling around and trying to implement deep cloning myself, and I came up with this:

-Snip-

 

Using this function I get the same results for the examples in your code as with your function, but I'm not sure if my function works in every case. Do you think I'm missing something? Cheers.

 

That's the approach I originally went with, but Uberi seems to think that approach is bad (Didn't get an answer out of him why). I notice that you are using a Not (!) in your if statement. I would suggest that you remove the not, and switch around the code blocks. You'll save cpu cycles that way. Also, many of your braces aren't necessary, but you probably already knew that.

[Uberi]

That's the approach I originally went with, but Uberi seems to think that approach is bad (Didn't get an answer out of him why). I notice that you are using a Not (!) in your if statement. I would suggest that you remove the not, and switch around the code blocks. You'll save cpu cycles that way. Also, many of your braces aren't necessary, but you probably already knew that.

I believe it was something about object keys, but to be honest, I don't remember anymore. Useful function, in any case.

Oh, and there was the issue of using Array.Insert with integer keys shifting values upwards, and how the object could possibly override the Insert method. But those are easily fixable, of course.

[nordanalt]

That's the approach I originally went with, but Uberi seems to think that approach is bad (Didn't get an answer out of him why). I notice that you are using a Not (!) in your if statement. I would suggest that you remove the not, and switch around the code blocks. You'll save cpu cycles that way. Also, many of your braces aren't necessary, but you probably already knew that.

Thanks for the suggestions, yeah, I like to put in the braces because more often than not I need to add some more code to the blocks and then I get annoyed if the braces aren't there already.
What I've found out so far for sure is that my version doesn't handle circular references, it gets stuck in an infinite loop. If I find out anything else, I will post it.

Oh, and there was the issue of using Array.Insert with integer keys shifting values upwards

Can you elaborate on this, please?

[Uberi]

Thanks for the suggestions, yeah, I like to put in the braces because more often than not I need to add some more code to the blocks and then I get annoyed if the braces aren't there already.
What I've found out so far for sure is that my version doesn't handle circular references, it gets stuck in an infinite loop. If I find out anything else, I will post it.

Can you elaborate on this, please?

Yep. If you look at the ObjInsert documentation, you'll notice that it can be used in two ways with the same syntax: with an integer key or with an object, real, or string key. x.Insert(Key, Value) behaves differently in these two cases. If Key is an integer, all existing keys higher than it will be shifted upwards by one. This behaviour cannot be disabled. Otherwise, the key is inserted normally. I generally prefer to use x[Key] := Value, but this does not work if the object implements the __Set method.