GeoIP()

[BoBo]

Inspiriert durch diese Anfrage im Englischen Forum stellte sich mir die Frage ob, ähnlich der Geo-Location-Bestimmung für mobile devices eine Option für imobile PC's verfügbar ist. Dem ist so. IP Geo Location. Muss zwar ohne GPS und cell tower Ortung auskommen, doch für die annähernde Bestimmung der Zeitzone (sowie weiterer IP basierter Ausgaben) genügt es (unter Vorbehalt).

Drohende Verbesserungsvorschläge (fast) jeder Art (z.B. zur json/xml-Verbuxelung) werden gerne (zur Kenntnis) genommen. Have phun!

Code: Select all

GeoIP()																	; load object using the 'https://ipapi.co/' API

MsgBox % GeoIP.region													; your current IP's assigned region ..
MsgBox % GeoIP.org														; .. organisation
MsgBox % GeoIP.version													; .. version
MsgBox % GeoIP.ip														; .. value. Check https://ipapi.co/api/#introduction for details!

For k, v in GeoIP 														; extract all assignments from the previously loaded GeoIP object 
	lst .= k ": " v "`n"
MsgBox % clipboard := lst												; display all assignments of your current IP

GeoIP("?")																; display GeoIP' help
Return

GeoIP(type:="") {
	if (type = "?") || (type = "help")
		help()
	else {
		Global GeoIP	:= {}
		whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
		whr.SetTimeouts(0, 5000, 5000, 100000)								; adjust timeouts accordingly. Default: (0, 30000, 30000, 600000)
		whr.Open("GET","https://ipapi.co/csv/", False)						; optional output formats are: json, jsonp, xml, csv, yaml.
		whr.Send()
		Sleep 100
		k := StrSplit(StrSplit(Trim(whr.ResponseText,"`n`r"),"`n").1,",")	; processing retrieved csv's 1st line
		v := StrSplit(StrSplit(Trim(whr.ResponseText,"`n`r"),"`n").2,",")	; processing retrieved csv's 2nd line
		Loop % k.Length() 
			GeoIP[Trim(k[A_Index],"`n`r")] := v[A_Index]
		Return
		}
	}

help(){
MsgBox, 
(%
Example:

   Once 'GeoIP()' has been loaded you can get the 
   'timezone' of a PC's geographical location
   using 'GeoIP.timezone' or 'GeoIP["timezone"]'

   Ie 'MsgBox % GeoIP.timezone' possible output: 'Europe/Berlin'.
   The following keys/options might be interesting as well.

	asn
	city
	continent_code
	country
	country_area
	country_calling_code
	country_capital
	country_code
	country_code_iso3
	country_name
	country_population
	country_tld
	currency
	currency_name
	in_eu
	ip
	languages
	latitude
	longitude
	org
	postal
	region
	region_code
	timezone
	utc_offset
	version
	)
ExitApp
}

Dasselbe nochmal als Funktion: Auf zur

Peep -

... mit Übergabe einer beliebigen IP zur Ermittlung von deren Geo Location Details (z.B. zur Spammer-Identifikation).

Code: Select all

MsgBox % GeoIP("region")								; get region assigned to your public IP using the 'https://ipapi.co/' API
MsgBox % GeoIP("country","8.8.8.8")						; get country for a specific IP .. (mal sehn wo Google wohnt!)
MsgBox % GeoIP()

GeoIP(req:="",ip:="") {
	if (req ="")
		Return guide()
	if req not in asn,city,continent_code,country,country_area,country_calling_code,country_capital,country_code,country_code_iso3,country_name,country_population,country_tld,currency,currency_name,in_eu,ip,languages,latitude,longitude,org,postal,region,region_code,timezone,utc_offset,version
		Return "Invalid parameter!"
	whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
	whr.SetTimeouts(0, 2500, 2500, 50000)				; adjust timeouts accordingly. Default: (0, 30000, 30000, 600000)
	req := (ip != "") ? ip . "/" req : req 
	whr.Open("GET","https://ipapi.co/" . req, False)
	whr.Send()
	Sleep 100
	Return whr.ResponseText
	}

guide() {
msg =
(
Example
	key: (will return) value
	-------------------------------------------
	asn: AS6840
	city: ToonTown
	continent_code: EU
	country: DE
	country_area: 357021.0
	country_calling_code: +49
	country_capital: Berlin
	country_code: DE
	country_code_iso3: DEU
	country_name: Germany
	country_population: 82927922.0
	country_tld: .de
	currency: EUR
	currency_name: Euro
	in_eu: True
	ip: 2a02:908:4c14:8900:2853:9fac:3c57:8822
	languages: de
	latitude: 50.121400
	longitude: 8.513400
	org: Liberty Global B.V.
	postal: 60000
	region: Hesse
	region_code: HE
	timezone: Europe/Berlin
	utc_offset: +0100
	version: IPv6
	-------------------------------------------
	)
Return msg
}

Tags: external IPgeofencinglocationGeoIPtimezoneCountry Code

Wie identifiziert man/frau lat/long innerhalb eines Radius (zB um (d)einen Wohnort) zum GeoFencing? Werde hieraus nicht wirklich schlau: http://janmatuschek.de/LatitudeLongitudeBoundingCoordinates

[BoBo]

Wie identifiziert man/frau lat/long innerhalb eines Radius (zB um (d)einen Wohnort) zum GeoFencing? Werde hieraus nicht wirklich schlau: http://janmatuschek.de/LatitudeLongitudeBoundingCoordinates

Verschiedene API-Services bieten eine Abfragemöglichkeite mit dem Parameter 'radius' oder 'bounds' an.
Mit Tools wie diesem lässt sich ein "Koordinaten-Fenster" ermitteln, was z.B. zur Restriktierung dienen kann!
HTH