Needs a good source for 16x16 pixel alphabet icon packs

[LC99]

Does anyone know of a good source for alphabet icon packs? I want to use these for my Script Icons, but I need a bold font as my eyesight isn't so good in my old age. I've spent hours searching the web for these but have found nothing like what I'm looking for. Any help would be appreciated. Thanks.

[RussF]

Not sure what exactly you are looking for. I searched for "icon collection alphabet" in google and came up with far more than I care to look through.

If you can't find exactly what you want, you could always make your own. There are many icon editors available - most online, but I use Greenfish - it resides on your PC.

Russ

[Smile_]

Download pixelformer (light app) and make your own icons.

[JoeWinograd]

I've been using this:
https://iconarchive.com/show/alphabet-icons-by-ariil.html

It's freeware (no backlink required) and commercial usage is allowed. The ICO files all have 8 sizes, from 16x16 to 256x256. There are also PNG files, including a 16x16, so if you want an ICO file with just 16x16, you can make your own from the 16x16 PNG. Regards, Joe

Edit: I've also been using this one:
https://iconarchive.com/show/red-orb-alphabet-icons-by-iconarchive.html

It's also freeware and allows commercial use, but its license is CC Attribution 4.0. Like the above, the ICO files have 8 sizes, from 16x16 to 256x256, and there are also PNG files, from 16x16 to 256x256.

Btw, a search for alphabet at https://iconarchive.com will get you additional hits. Another good source for icons is https://www.iconfinder.com, and a search there for alphabet also gets hits.

[LC99]

I've looked at all those sites but didn't exactly find what I was looking for.

[flyingDman]

Maybe you can tell us - or show us - what you are looking for ...? font type, color, background ? loose icons or .dll pack or .png? Transparent?

[JoeWinograd]

didn't exactly find what I was looking for

OK, what exactly are you looking for? You asked for "a good source for alphabet icon packs", which I provided, but I'd be happy to try to provide other sources if I knew exactly what you need. Perhaps you could post one image of what you're looking for. You also said, "I need a bold font as my eyesight isn't so good in my old age..." Here's a 256x256 bold letter A downloaded from one of the sites I mentioned:

a_alphabet_bold_256x256.png (3.64 KiB) Viewed 4634 times

Is that along the lines of what you need? If not, what? Regards, Joe

[BoBo]

"I need a bold font as my eyesight isn't so good in my old age..."

You might think of (Chrome)casting your PC's desktop to a 16:9 flatscreen TV!?
And what about that other (already built in) "accessibility" stuff like "screen lens" and a browser's zoom(ing) option?

[LC99]

a_alphabet_bold_256x256.png

Is that along the lines of what you need? If not, what? Regards, Joe

Thanks, Joe. the sample you showed is exactly the type I'm looking for.
I have found an occasional icon of that type, but I haven't found a whole
set of them. I would actually like several packs of 16x16 icons in assorted
high-contrast colors. But I will settle for one pack of icons (Capital Letters and
Numbers) of that type. If necessary I can then change the icon Foreground
and Background of them to the High-Contrast colors of my liking.
Regards,
Larry Carley

[LC99]

Thanks for the suggestion Bobo, but my eyesight isn't that bad yet.

[JoeWinograd]

Hi Larry,
I don't know of a whole icon set with all 26 letters and all 10 numbers in that style font. Considering that you want several packs with a bold font and assorted high-contrast colors, I'd be tempted to create them myself. Since you say that you know how to "change the icon Foreground and Background of them to the High-Contrast colors of my liking", you must have some familiarity with a decent imaging tool, which should make it easy to create the set of 36 icons (all 16x16). My guess is that you can complete the initial set in an hour or so and then make as many high-contrast color variations as you want. For example, I made the attached 16x16 A and 1 icons with GIMP. I used the Arial Heavy font, which I think has the boldness/visibility that you're looking for, but that's the beauty of this approach...use whatever font is best for you. Each icon took only a minute or so to create with the GIMP Text tool followed by an Export to .ICO format. Regards, Joe

[JoeWinograd]

I will settle for one pack of icons (Capital Letters and Numbers) of that type.

Hi Larry,
Following up on my previous post, I had a spare half-hour tonight and added the other 34 icons. All 36 are in the attached ZIP file. Here's a screenshot of the folder that they're in on my W10 system (File Explorer in Details View):

icons A-Z and 0-9.png (44.18 KiB) Viewed 3777 times

I think the icons satisfy your criteria. Regards, Joe

[LC99]

Joe, thank you so much for the icons. I see the icon set you posted already has 3 downloads, so it undoubtedly will be a popular download here. I tried a number of different icon editors for creating icons and they all seemed to have a rather steep learning curve and I wasn't getting the results I wanted. GIMP is a photo editor I haven't tried yet. I will have to give it a try.

[JoeWinograd]

You're very welcome, Larry. A word of caution: GIMP is a superb program (and free!), but it has, to steal your words, "a rather steep learning curve". It is extremely robust, but with that comes a lot of complexity. I am by no means an expert in it, but I can usually get the results I'm looking for through trial-and-error, as was the case in creating the icon set for you. Regards, Joe

[flyingDman]

A different way to do this is to use MS Word and Imagemagick. Unfortunately, it is difficult to have a script take care of it all but I don't think it is impossible.
Here, I start by creating a Word document consisting of a single letter (say W) at the top and in the middle of the page (use Ctrl E to center). Pick a font type (I took Arial Narrow Bold) and a large font size (I took 85). Now, determine the coordinates of the letter (use winspy for instance) leaving a small border on every side such that these coordinates form a square (I took 128 x 128; is does not have to be an exact multiple of 16 as we will resize later; do not start smaller than you will need!). Make sure even the widest letters (W!) fit in that square .
The following script will loop over the alphabet (and whatever character you want), and, using those coordinates, clip squares using GDIP.

Code: Select all

#\::                                     ; launch when Word is active
oWord := ComObjActive("word.application")
X := 1205, Y := 324, W := 128, H := 128           ; coordinates to be adjusted to your res, dpi, font size, etc.
pToken := Gdip_Startup()
for a,b in strsplit("ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890")
	{
	oWord.Selection.WholeStory
	oWord.selection.text := b "            "
	sleep, 100
	oword.Selection.EndKey(6,0)
	sleep, 100
	flnm := "icon_" b ".png"
	pBitmap := Gdip_BitmapFromScreen(X "|" Y "|" W "|" H)
	Gdip_SaveBitmapToFile(pBitmap, flnm)
	Gdip_DisposeImage(pBitmap)
	}
Gdip_Shutdown(pToken)
return

This will create a .png file of each character in the form: icon_w.png.
Using Imagemagick you can set the transparency and the size of the final .ico files:

Code: Select all

size := "64x64"
loop, files, %A_ScriptDir%\icon_*.png
	{
	orgnlfl := A_LoopFileFullPath
	transfl := substr(A_LoopFileFullPath,1,-4) "_" size ".ico"
	runwait, C:\Program Files\ImageMagick-7.1.0-Q16\magick.exe "%orgnlfl%" -resize %size% -transparent white "%transfl%",,hide
	}

Files will have the following format: icon_W_16x16.ico. (Darn, this is not off-topic anymore....)

Icons_16x16.zip

(18.37 KiB) Downloaded 57 times

[JoeWinograd]

A different way to do this is to use MS Word and Imagemagick.

Hi Dman,
Absolutely brilliant stuff! Worked perfectly on W10/21H2 with the latest AHK V1, latest O365, and ImageMagick-7.0.11-Q8 (the version I already had installed...don't want to update at this time). Superb! Thanks for posting. Regards, Joe

[flyingDman]

Thanks Joe. As I said, I am pretty sure there is a way to do this with only GDIP. @Hellbent maybe?

[JoeWinograd]

As I said, I am pretty sure there is a way to do this with only GDIP.

I missed that comment when you said it, but I'm sure you're right. Here's a way to do it without Word (leveraging all of your other code):

Code: Select all

ImageMagickEXE:="your full path for ImageMagick here"
OutputFolder:=A_ScriptDir . "\ICOs-PNGs\"
FontSize:=50
FontWeight:=600
FontColor:="Black"
FontName:="Arial"
IconSize:=64
GuiColor:="White"

pToken:=Gdip_Startup()
Gui,Color,%GuiColor%
Gui,Font,s%FontSize% w%FontWeight% c%FontColor%,%FontName%
Gui,Add,Text,Center w%IconSize% h%IconSize% vCharacter,%Char%
Gui,Show,,CreateIcons
WinGetPos,GuiX,GuiY,GuiW,GuiH,CreateIcons
ControlGetPos,X,Y,W,H,%Character%,CreateIcons
CharX:=GuiX+X
CharY:=GuiY+Y
for a,b in strsplit("ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890")
{
  GuiControl,,Character,%b%
  flnm:=OutputFolder . "icon_" b ".png"
  pBitmap := Gdip_BitmapFromScreen(CharX "|" CharY "|" W "|" H)
  Gdip_SaveBitmapToFile(pBitmap,flnm)
  Gdip_DisposeImage(pBitmap)
  Sleep,100
}
Gui,Destroy
loop, files, %OutputFolder%icon_*.png
{
  orgnlfl := A_LoopFileFullPath
  transfl := substr(A_LoopFileFullPath,1,-4) "_" IconSize ".ico"
  runwait, %ImageMagickEXE% "%orgnlfl%" -resize %IconSize% -transparent %GuiColor% "%transfl%",,hide
}
MsgBox Done!
ExitApp

But it still relies on putting the characters on screen (via an AHK GUI instead of Word). There's almost surely a way to do it without relying on Gdip_BitmapFromScreen, perhaps with Gdip_CreateBitmap, Gdip_BitmapSetResolution, and Gdip_TextToGraphics, among other Gdip functions, but Gdip is not in my wheelhouse. Regards, Joe

[flyingDman]

Nice!

[JoeWinograd]

Thanks!

Some notes for @LC99:

Hi Larry,

You said earlier that you would like several packs of icons in assorted high-contrast colors, and the script in this post will let you create that (bulk of the credit to flyingDman), but a few things to keep in mind with it:

Most folks like the background on icons to be transparent. That's why flyingDman put the -transparent option on the ImageMagick call. But that defeats the high-contrast objective because the background won't show. For example, suppose you want Lime text on a Black background as your high-contrast pack. However, with a transparent background, it will look like this:

LetterW-lime-transparent.png (907 Bytes) Viewed 2455 times

If you want the Black background, do not include the -transparent option on the ImageMagick call. To make that easier, I added a Transparent variable to the script in my previous post...set it to 1 if you want the transparent background or to 0 if you're making high-contrast icons and need the background color. For example, the Lime text on Black background will look like this without transparency:

LetterW-lime-not-transparent.png (1.04 KiB) Viewed 2455 times

flyingDman and I have been going back and forth with 64x64 icons. If you really want 16x16, change IconSize to 16 and experiment with different values for FontSize (on my system with Arial font, 11 works well as font size). That said, 64x64 should be fine, as programs that use icons know how to downsize them (such as File Explorer and the system tray icons).

Updated script is below. Regards, Joe

Code: Select all

; *** begin variables to change
ImageMagickEXE:="your full path for ImageMagick here"
OutputFolder:=A_ScriptDir . "\ICOs-PNGs\"
FontSize:=50
FontWeight:=600
FontColor:="Lime"
FontName:="Arial"
IconSize:=64
GuiColor:="Black"
Transparent:=0 ; 0=>background not transparent  1=>background transparent
; *** end variables to change

pToken:=Gdip_Startup()
If (Transparent)
  TransParam:="-transparent " . GuiColor
Else
  TransParam:=""
Gui,Color,%GuiColor%
Gui,Font,s%FontSize% w%FontWeight% c%FontColor%,%FontName%
Gui,Add,Text,Center w%IconSize% h%IconSize% vCharacter,%Char%
Gui,Show,,CreateIcons
WinGetPos,GuiX,GuiY,GuiW,GuiH,CreateIcons
ControlGetPos,X,Y,W,H,%Character%,CreateIcons
CharX:=GuiX+X
CharY:=GuiY+Y
for a,b in strsplit("ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890")
{
  GuiControl,,Character,%b%
  flnm:=OutputFolder . "icon_" b ".png"
  pBitmap := Gdip_BitmapFromScreen(CharX "|" CharY "|" W "|" H)
  Gdip_SaveBitmapToFile(pBitmap,flnm)
  Gdip_DisposeImage(pBitmap)
  Sleep,100
}
Gui,Destroy
loop, files, %OutputFolder%icon_*.png
{
  orgnlfl := A_LoopFileFullPath
  transfl := substr(A_LoopFileFullPath,1,-4) "_" IconSize ".ico"
  runwait, %ImageMagickEXE% "%orgnlfl%" -resize %IconSize% %TransParam% "%transfl%",,hide
}
MsgBox Done!
ExitApp