123 and ctrl and alt keys getting stuck

[jojothemojo]

I'm having issues with this spam clicker getting stuck and not letting go of either the ctrl key, or alt key, and sometimes just completely stuck pressing a number and it'll only stop when I press the number again. Is there a way to make this smoothier?


I have this set up but for the MMO I'm playing, I also do ctrl+1, ctrl +2, ctrl +3, and alt+1, alt+2, alt+3. Can anyone lend some knowledge, I'm new to this. To clarify, I also want it to be able to spam the 123 keys with the alt and ctrl activated but I don't want it to get stuck.

Code: Select all

*1::
Loop
{
GetKeyState, state, 1, p
if state = U
break
; Otherwise:
Send, {1}
Sleep, 30
}

*2::
Loop
{
GetKeyState, state, 2, p
if state = U
break
; Otherwise:
Send, {2}
Sleep, 30
}

*3::
Loop
{
GetKeyState, state, 3, p
if state = U
break
; Otherwise:
Send, {3}
Sleep, 30
}

[Mod edit: [code][/code] tags added]

[Rohwedder]

Hallo,
try:

Code: Select all

$*1::
Loop
{
	GetKeyState, state, 1, p
	if state = U
		break
	; Otherwise:
	Send, {Blind}{1}
	Sleep, 30
}
Return
$*2::
Loop
{
	GetKeyState, state, 2, p
	if state = U
		break
	; Otherwise:
	Send, {Blind}{2}
	Sleep, 30
}
Return
$*3::
Loop
{
	GetKeyState, state, 3, p
	if state = U
		break
	; Otherwise:
	Send, {Blind}{3}
	Sleep, 30
}
Return

or shorter:

Code: Select all

$*1::
$*2::
$*3::
Key := SubStr(A_ThisHotkey, 0)
While, GetKeyState(Key, "P")
{
	Send, {Blind}{%Key%}
	Sleep, 30
}
Return