Mouse button pull down

[AshMann]

Hello! I am looking for a script that moves the mouse crosshair down at a steady rate when I hold down the left mouse button over half a second! Any help with this script would be great! I'm new to scripting and I'm trying it out on some processes!

Thanks!

[boiler]

Try this:

Code: Select all

Speed := 2

LButton::
	Click, Down
	KeyWait, LButton, T0.5
	if ErrorLevel {
		while GetKeyState("LButton", "P")
			MouseMove, 0, Speed, 0, R
	}
	Click, Up
return

[AshMann]

THANK YOU!!!

do you also know of a script where if I hold down the spacebar for more than half a second the spacebar get spammed until i let go of the spacebar

[AshMann]

@boiler

^^^^^^^^^^^^^^^^

[AshMann]

@boiler

also... is it possible to make it where it only goes down with both mouse clicks

[boiler]

Patience is a virtue...

[boiler]

do you also know of a script where if I hold down the spacebar for more than half a second the spacebar get spammed until i let go of the spacebar

Try this:

Code: Select all

$Space::
	Send, {Space}
	KeyWait, Space, T0.5
	if ErrorLevel
		while GetKeyState("Space", "P") {
			Send, {Space}
			Sleep, 50
		}
return

is it possible to make it where it only goes down with both mouse clicks

I don't know what you mean by this. Do you mean you want it to move the mouse pointer down only after a double-click and the button is held down after the second click?

[AshMann]

@boiler

I mean if I hold the RButton down AND the LButton down on the mouse at the same time... only then will the mouse move down until the buttons are released

[boiler]

Code: Select all

Speed := 2

LButton::
	Click, Down
	KeyWait, LButton, T0.5
	if ErrorLevel {
		while GetKeyState("LButton", "P") && GetKeyState("RButton", "P")
			MouseMove, 0, Speed, 0, R
	}
	KeyWait, LButton
	Click, Up
return

If you want it to move the mouse pointer without holding down the mouse button, you can remove the Click statements, but then the regular mouse button use won't work.