消息使用简介

[amnesiac]

注：本文原计划为三个部分，目前后两个部分仍在整理中。

导言：许多新人、甚至一些使用不短时间脚本的用户对消息都比较陌生，看到使用消息的代码时总感觉玄而又玄，他们怎么知道可以用消息？消息中的那些参数是哪里来的？什么时候或什么场合可以考虑用消息？在自己的图形界面中如何自定义消息？本文尝试回答这些问题，让大家对消息有个大概的认识。
消息机制是 Windows 系统中的一种通讯方式，简单的说就像人与人之间使用的短信。它是 Windows 发出的一个通知，告诉应用程序某个事情发生了。例如，单击鼠标、改变窗口尺寸、按下键盘上的一个键都会使 Windows 发送一个消息给应用程序。

帮助中相关内容：
SendMessage/PostMessage
OnMessage()
Windows 消息列表

处理系统消息
消息本身是作为一个记录传递给应用程序的，这个记录中包含了消息的类型及其他相关信息。在 AutoHotkey 中我们可以使用 OnMessage() 捕捉系统消息，这样可以实现对右击、双击、获取焦点等行为的判断，从而进行进一步的响应。这里将探讨如何监视系统消息并根据需要进行处理。

从示例开始
我们先来看看下面这个例子，这里实现了当编辑控件取得焦点（可以通过点击鼠标或键盘导航）时清除提示，若失去焦点前没有输入新内容则恢复提示。

Code: Select all

SetFormat, integer, hex
WM_COMMAND := 0x111    ; http://msdn.microsoft.com/en-us/library/ms647591.aspx
TestStr := "请输入测试字符串！"
Gui, +Border +LastFound +AlwaysOnTop +ToolWindow
hWin := WinExist()
Gui, Add, Edit
Gui, Font, italic s15
Gui, Add, Edit, vEditVar HwndhEdit, %TestStr%
Gui, Font, norm
Gui, Add, Button, Default, 确定
Gui, Show, AutoSize, 测试 GUI
OnMessage(WM_COMMAND,"MsgHandler")
Return

GuiClose:
ExitApp

MsgHandler(wParam, lParam, msg, hwnd)
{
  global hEdit, TestStr, EditVar
  EN_SETFOCUS := 0x100    ; http://msdn.microsoft.com/en-us/library/bb761685
  EN_KILLFOCUS := 0x200
  ;~ xn := NumGet(wParam, 0, "short")
  ;~ yn := NumGet(wParam, 2, "short")
  Transform, loword, BitAnd, wParam, 0xffff
  Transform, hiword, BitShiftRight, wParam, 16
  if (hEdit <> lParam)    ; 发送此通告的不是目标编辑控件
    return
  ControlGetText, EditContent, , ahk_id %hEdit%    ; 获取控件现在的内容
  if (EditContent <> "" and EditContent <> TestStr)    ; 控件的内容不为空，说明已经输入了新内容或者为第一次获取焦点前的原始内容。
    return
  if (hiword = EN_SETFOCUS)    ; 编辑控件获得焦点
  {
    Gui, Font, norm
    GuiControl, Font, EditVar 
    GuiControl, , EditVar
  }
  if (hiword = EN_KILLFOCUS)    ; 编辑控件失去焦点
  {
    Gui, Font, italic
    GuiControl, Font, EditVar 
    GuiControl, , EditVar, %TestStr%
  }
  return, 0
}

剖析脚本各部分
下面我们对这段代码进行简单的分析：

Code: Select all

WM_COMMAND := 0x111

这里是赋值我们需要监视的系统消息，与许多高级语言可以通过加载头文件从而包含常量值 WM_COMMAND 不同，在 AutoHotkey 中并没有，所以要使用消息前需要先赋值（或者直接在后面使用相应的数值）。

Code: Select all

OnMessage(WM_COMMAND,"MsgHandler")

监视 WM_COMMAND 消息，接收到后使用 MsgHandler() 函数处理。如果我们这里没有监视系统消息，那么应用程序接收到消息后会进行默认的处理。除了 WM_COMMAND，还有许多其他的消息，例如 WM_NOTIFY，更多的请参阅帮助中“Windows 消息列表”页面。

Code: Select all

MsgHandler(wParam, lParam, msg, hwnd){}

这个是消息处理函数，四个参数的值都是数字，这里简要说明它们的含义：

• wParam：消息的首个参数，表示的含义与具体的系统消息有关。
• lParam：消息的第二个参数，表示的含义与具体的系统消息有关。
• msg：接收到的消息号，如果我们使用一个函数监视多种系统消息例如 WM_COMMAND 和 WM_NOTIFY，在函数中可以根据这个判断接收到的是哪种消息。
• hwnd：接收到消息的窗口句柄，当我们写的脚本中含有多个窗口时可以根据此参数判断接收到消息的是哪个窗口。

Code: Select all

EN_SETFOCUS := 0x100
EN_KILLFOCUS := 0x200

赋值控件定义的通告码，这些通告码包含在消息的参数中，我们需要分解参数判断控件发生了什么。

Code: Select all

Transform, loword, BitAnd, wParam, 0xffff
Transform, hiword, BitShiftRight, wParam, 16

在这个例子中，我们监视的是目标编辑控件取得和失去焦点时的系统消息，根据 MSDN 中 WM_COMMAND 消息页面可以看到，wParam 中的低字表示控件标识符，高字表示控件定义的通告码，lParam 表示发送此消息的控件句柄。这里摘取 MSDN 中 EN_SETFOCUS notification code 页面的关于 wParam 描述部分：

wParam
The LOWORD contains the identifier of the edit control. The HIWORD specifies the notification code.

所以，这个例子中如果完整的判断时（例如在含有多窗口的脚本中使用一个函数监视多种系统消息时），首先根据 hwnd 判断是否是我们需要监视的目标窗口，使用 msg 知道接收到的消息号，使用 lParam 判断发送消息的控件，然后检查 wParam 中的高字，如果高字的内容为 EN_SETFOCUS，说明目标编辑控件取得了焦点。
这里有两个地方要小心：

• 从 wParam 中分离高字和低字时使用 NumGet() 得到的结果是错误的；
• 应该使用 lParam 判断发送消息的控件而不用 wParam 中的低字，因为控件标识符不是唯一的（在函数中还可以使用 AutoHotkey 的一些内置变量进行辅助判断，例如 A_Gui 等）。

如何编写消息脚本

本部分待整理

在前一部分中我对监视目标编辑控件在取得焦点和失去焦点时进行响应的实际例子进行了简要的分析, 其中我没有提到一些很重要的问题: WM_COMMAND 是怎么来的? EN_SETFOCUS 和 EN_KILLFOCUS 又要从哪里获取? 本文试图就这些问题说说我自己的一些经验. 现在假设我们面对前面脚本解决的问题 (先忘记前面的脚本), 即我们要在某个编辑控件取得焦点时进行响应, 如何开始写这个脚本呢?

首先先明晰一些概念. 消息是用于通讯的, 例如系统和脚本之间, 脚本和它的窗口 (这里的窗口是广义的, 包括屏幕上许多可视对象, 例如 GUI 窗口, 编辑控件, 对话框等) 之间. 这里的消息分为一般消息 (message) 和含通告 (notification) 的消息, 在脚本中一般消息主要由应用程序发送给它的窗口, 而含通告的消息则相反. 这点稍作了解并在实践中体会, 不需要纠结. 控件消息分为通用控件消息和专用控件消息. 现在在看看问题: 如何对脚本中某个 GUI 窗口中的特定编辑控件取得焦点时进行响应呢?

从问题中我们可以提取到两个关键点: "编辑控件" 和 "取得焦点". 在浏览器中打开 MSDN 中的 General Control Reference 页面, 下拉到通告部分, 可以看到所有通用控件消息 (为什么是通告而不是一般消息? 因为这里需要监视的是编辑控件取得焦点时发送给脚本的消息).

WinSpetorU 自定义消息

从上面的说明, 您也许发现了在有些时候系统消息的用处很大, 然而为什么称为系统消息呢? 因为它们只适用于由 Windows 系统 (确切的说是其中的一些 dll 文件) 提供的控件上, 这样的控件一般称为标准控件. 如果发送这些消息给非标准控件会发生什么情况呢? 无法预料, 反过来说, 当我们发送这样的消息给控件却不起作用时, 有可能目标控件是非标准控件, 另一种较罕见的可能是低版本的控件不支持一些新消息 (这种情况对消息极少见, 不过在样式中较可能遇到, 这也是我们常在一些含 GUI 的脚本中看到提示说在一些低版本系统中某些特效不起作用的原因了).

Code: Select all

;~ 暂停脚本 自己响应

SetFormat, integer, hex
WM_NOTIFY := 0x4E    ; http://msdn.microsoft.com/en-us/library/bb775583
TestStr := "请输入测试字符串!"
Gui, +Border +LastFound +AlwaysOnTop +ToolWindow
hWin := WinExist()
Gui, Add, Edit
;~ Gui, Font, italic s15
Gui, Add, Edit, HwndhEdit, %TestStr%
;~ Gui, Font, norm
Gui, Add, Button, Default, 确定
Gui, Show, AutoSize, 测试 GUI
WinGet, ControlListHwnd, ControlListHwnd
WinGet, ControlList, ControlList
OnMessage(WM_NOTIFY,"MsgHandler")
Return

GuiClose:
ExitApp

MsgHandler(wParam, lParam, msg, hwnd)
{
  global hEdit, hWin, hwndFrom
  NM_SETFOCUS := -7	; http://msdn.microsoft.com/en-us/library/bb775567
  
  if (hwnd <> hWin)
	return
  
  hwndFrom := NumGet(lParam, 0, "UInt")
  code := NumGet(lParam, 8, "UInt")
  ;~ if (hEdit = hwndFrom)
  Pause
}

F1::Pause

F2::WinGetClass, SWin, ahk_id %hwndFrom%

在脚本 GUI 中自定义消息

本部分待整理

这里还有一个例子： 请问怎样实现点击Edit框那些字就消失的效果?

小结

Spoiler

如何使用消息控制第三方程序？使用消息截取工具或查阅第三方工具文档了解它们是否支持消息及支持哪些消息。

扩展阅读：

• 消息指南
• 脚本主窗口的妙用
• amnesiac 的 Everything 热键
• 如何借助Autohotkey使total commander在单双窗口间切换？
• 检测托盘气泡的点击