Cambio de resolución Topic is solved

[gabriel_borward]

hola una consulta, hay alguna forma facil de cambiar la resolucion a un autohotkey por que ir modificando cada punto es bastante tedioso, espero sus respuestas gracias

[garry]

Test for Full-HD or 4-K Monitor

Code: Select all

;- Test for FullHD or 4-K Monitor 
;- PLAY Youtube video with videolan (vlc.exe) 
Filename1=VLCPlugin_Youtube-Play    ;- only videos allowed for embed
Gui,2:default
Gui,2:-border
GUI,2:Font,s14 cGray,Lucida Console
Gui,2: -DPIScale
Gui,2: Color, Black,Black 
id1=sraZaL6jylM;Lilian de Celis-El Relicario
stringsplit,c,id1,`;
F1=https://www.youtube.com/watch?v=%c1%
fp:="https://i.imgur.com/QiLP9qz.jpg"
pict=%a_scriptdir%\relicario_text.jpg
ifnotexist,%pict%
  urldownloadtofile,%fp%,%pict%
wa:=A_screenwidth
ha:=A_screenHeight
xx:=101
LW:=(wa*88)/xx,LH:=(ha*88)/xx,wm:=(wa*88.7)/xx,hm:=(ha*90)/xx,GW:=(wa*99.5)/xx,GH:=(ha*96)/xx  
x1:=(wa*1.5)/xx,y1:=(ha*2)/xx,x2:=(wa*1.2)/xx,y2:=(ha*.5)/xx
xxb=VideoLAN.VLCPlugin.2
xp:=(wa*90.3)/xx,yp:=(ha* 1.8)/xx,wp:=(wa* 8.4)/xx,hp:=(ha*88.9)/xx
   Gui,2:Add,ActiveX, x%x1% y%y1% w%lw%  h%lh% vVlcx,%xxb%
   Gui,2:Add,Picture, x%xp% y%yp% w%wp%  h%hp% ,%pict%
   Gui,2:add,GroupBox,x%x2% y%y2% w%WM% h%HM%
y:=(ha*92) /xx  
Gui,2:Add,Text,x%x2% y%y% , %c2%   ( use ESC to quit )
Gui,2:Show,x0 y0 w%gw% h%gh%,%filename1%
vlcx.playlist.add(F1,"","""""")
vlcx.playlist.next()
return
2Guiclose:
exitapp
esc::exitapp
;============ END script Youtube PLAY =====================================

colorpicker

Code: Select all

/*
GCCP (Color-Picker) ... its an easy Tool, Hotkey Strg+Alt+c
copy the Hex-Code of the Color under Mouse into Clipbard;
and Strg+Alt+K copy the Complementary Color into Clipboard.
Both Colors are displayed in the Program-Window and the Code too.
gero(May2009)
*/

#NoEnv
#SingleInstance force
SendMode Input
SetBatchLines, -1
SetTitleMatchMode, 3
OnExit, undweg
Menu, Tray, Tip, Strg+Alt+C=copy
GUI +LastFound  +AlwaysOnTop
Gui, Show, x100 y100 w150 h185 , GCCP
Gui, Color, c0c0c0
Gui, Font, s12
Gui, Add, Text, x0  y5    w150 center vMMM , %AAA%
Gui, Font, s10
GUI, Add, Text, x15 y30  w40 center vROT    , %ROT%
GUI, Add, Text, x55 y30  w40 center vGRUEN  , %GRUEN%
GUI, Add, Text, x95 y30  w40 center vBLAU   , %BLAU%
GUI, Add, Text, x15 y155 w40 center vKROT   , %ROT%
GUI, Add, Text, x55 y155 w40 center vKGRUEN , %GRUEN%
GUI, Add, Text, x95 y155 w40 center vKBLAU  , %BLAU%
Gui, Font, s12
Gui, Add, Text, x0 y130 w150 center vCOMP   , %AAA%
Gui, Font, s100 bold, Wingdings
Gui, Add, Text,  x10 y20 h100 w65 c%CCC% vTTT  +BackgroundTrans , n
Gui, Add, Text,  x65 y20 h100 w65 c%PPP% vCCol +BackgroundTrans , n
WinSet, Transparent, 255, GCCP
SetTimer, COLORPIC, 50
return

ACTIVE:
IfWinActive, GCCP
{
setTimer, COLORPIC, OFF
WinWaitNotActive, GCCP
setTimer, COLORPIC, ON
}
return



COLORPIC:
MouseGetPos, X0, Y0,
PixelGetColor, CCC, X0, Y0 , RGB
StringRight, AAA, CCC, 6
GuiControl, Text, MMM, #%AAA%
Gui, Font, c%CCC%
GuiControl, Font, TTT
StringLeft, GR1, CCC, 2
GR2:= SubStr(CCC, 5 , 2)
GRUEN:= GR1 GR2
GRUEN +=0
StringRight, BL1, CCC, 2
BLAU:= GR1 BL1
BLAU +=0
StringLeft, ROT, CCC, 4
ROT +=0
GUICONTROL, Text, ROT, %ROT%
GUICONTROL, Text, GRUEN, %GRUEN%
GUICONTROL, Text, BLAU, %BLAU%
ROT:=255-ROT
GRUEN:=255-GRUEN
BLAU:=255-BLAU
GUICONTROL, Text, KROT, %ROT%
GUICONTROL, Text, KGRUEN, %GRUEN%
GUICONTROL, Text, KBLAU, %BLAU%
SetFormat, Integer, hex
ROT +=0
GRUEN +=0
BLAU +=0
StringTrimLeft, ROT, ROT, 2
StringUpper, KROT, ROT
if StrLen(KROT)=1
{
KROT:=0 KROT
}
StringTrimLeft, GRUEN, GRUEN, 2
StringUpper, KGRUEN, GRUEN
IF StrLen(KGRUEN)=1
{
KGRUEN:=0 KGRUEN
}
StringTrimLeft, BLAU, BLAU, 2
StringUpper, KBLAU, BLAU
if StrLen(KBLAU)=1
{
KBLAU:=0 KBLAU
}
PPP:= GR1 KROT KGRUEN KBLAU
ForClipB:=KROT KGRUEN KBLAU
Gui, Font, c%PPP%
GuiControl, Font, CCOL
GUICONTROL, Text, COMP, #%KROT%%KGRUEN%%KBLAU%
return

!c::
Clipboard=#%AAA%
return

!K::
Clipboard=#%ForClipB%
return

undweg:
GuiClose:
ExitApp
return

Magnifier

Code: Select all

;- https://autohotkey.com/board/topic/10660-screenmagnifier/


#NoEnv
SetBatchLines -1

CoordMode Mouse, Screen
OnExit GuiClose
zoom = 2                ; initial magnification, 1..32
antialize = 0
Rx = 128                ; half vertical/horizontal side of magnifier window
Ry = 128
Zx := Rx/zoom           ; frame x/y size
Zy := Ry/zoom
                        ; GUI to show the magnified image
Gui +AlwaysOnTop +Resize +ToolWindow
Gui Show, % "w" 2*Rx " h" 2*Ry " x0 y0", Magnifier
WinGet MagnifierID, id,  Magnifier
WinSet Transparent, 255, Magnifier ; makes the window invisible to magnification
WinGet PrintSourceID, ID

hdd_frame := DllCall("GetDC", UInt, PrintSourceID)
hdc_frame := DllCall("GetDC", UInt, MagnifierID)

SetTimer Repaint, 50    ; flow through

Repaint:
   MouseGetPos x, y
   xz := In(x-Zx-6,0,A_ScreenWidth-2*Zx) ; keep the frame on screen
   yz := In(y-Zy-6,0,A_ScreenHeight-2*Zy)
  ; WinMove Frame,,%xz%, %yz%, % 2*Zx, % 2*Zy
   DllCall("gdi32.dll\StretchBlt", UInt,hdc_frame, Int,0, Int,0, Int,2*Rx, Int,2*Ry
   , UInt,hdd_frame, UInt,xz, UInt,yz, Int,2*Zx, Int,2*Zy, UInt,0xCC0020) ; SRCCOPY
Return


GuiSize:
   Rx := A_GuiWidth/2
   Ry := A_GuiHeight/2
   Zx := Rx/zoom
   Zy := Ry/zoom
   TrayTip,,% "Frame  =  " Round(2*Zx) " × " Round(2*Zy) "`nMagnified to = " A_GuiWidth "×" A_GuiHeight
Return

#a::
  antialize := !antialize
  DllCall( "gdi32.dll\SetStretchBltMode", "uint", hdc_frame, "int", 4*antialize )  ; Antializing ?
Return 

#x::
GuiClose:
   DllCall("gdi32.dll\DeleteDC", UInt,hdc_frame )
   DllCall("gdi32.dll\DeleteDC", UInt,hdd_frame )
ExitApp

#p::
MButton::
   if paused = 
   {
        Gui, 2:Hide 
        Gui, Hide 
        SetTimer, Repaint, Off
        paused = 1
   }
   else
   {
        Gui, 2:Show 
        Gui, Show 
        SetTimer, Repaint, 50
        paused =
   }
Return

^+Up::
^+Down::
^+WheelUp::                      ; Ctrl+Shift+WheelUp to zoom in
^+WheelDown::                    ; Ctrl+Shift+WheelUp to zoom out
   If (zoom < 31 and ( A_ThisHotKey = "^+WheelUp" or A_ThisHotKey = "^+Up" ))
      zoom *= 1.189207115         ; sqrt(sqrt(2))
   If (zoom >  1 and ( A_ThisHotKey = "^+WheelDown" or A_ThisHotKey = "^+Down" ))
      zoom /= 1.189207115
   Zx := Rx/zoom
   Zy := Ry/zoom
   TrayTip,,% "Zoom = " Round(100*zoom) "%"
Return

In(x,a,b) {                      ; closest number to x in [a,b]
   IfLess x,%a%, Return a
   IfLess b,%x%, Return b
   Return x
}