Cambio depende de la pagina

[Aprendiendo]

Hola, me gustaría saber si es posible hacer que depende de en que sitio está el script funcione de una manera o otra. Por ejemplo si estoy en YouTube el F2 haga ^{w} pero si estoy en otro sitio no. Si no es posible hacerlo depende de la web, al menos depende del programa (solo si no se puede de la otra forma)

[devnullsp]

Si que es posible,

Mirate https://autohotkey.com/docs/commands/Hotkey.htm

En concreto la opción:

Code: Select all

Hotkey, IfWinActive/Exist , WinTitle, WinText

Que es básicamente lo que tu quieres....

Un Saludo

[Aprendiendo]

Lo he intentado pero con google no me funciona, perdona mi ignorancia

[A_AhkUser]

Para perfeccionar la respuesta que ha dado aqui (dado que tu pregunta es prácticamente igual en ambos casos) y simplificarla, teniendo en cuenta la sugerencia de devnullsp:

Code: Select all

SetTitleMatchMode, RegEx

Hotkey, IfWinActive, (.*- )?YouTube(?= - Mozilla Firefox$) ahk_class MozillaWindowClass ahk_exe firefox.exe
Hotkey, F4, subrutina
return

subrutina:
MsgBox, TEST
return

o

Code: Select all

SetTitleMatchMode, RegEx
#IfWinActive (.*- )?YouTube(?= - Mozilla Firefox$) ahk_class MozillaWindowClass ahk_exe firefox.exe
	F4::MsgBox, TEST
#IfWinActive

[devnullsp]

Por curiosidad A_AhkUser usar RegEx consume mucho o tu no notas nada?

[A_AhkUser]

Por curiosidad A_AhkUser usar RegEx consume mucho o tu no notas nada?

@devnullsp
Hola, no, no noto nada, por lo menos, en el mundo real.
Es cierto que, en un entorno de producción, se recomienda que el comportamiento de SetTitleMatchMode sea configurado 'sobre la marcha', a nivel local:

Code: Select all

#If WinActiveRegEx("(.*- )?YouTube(?= - Mozilla Firefox$) ahk_class MozillaWindowClass ahk_exe firefox.exe")
	F4::MsgBox % A_ThisHotkey
#If

WinActiveRegEx(_wintitle) {
	local _titleMatchMode := A_TitleMatchMode
	SetTitleMatchMode, RegEx
	_hwnd := WinActive(_wintitle)
	SetTitleMatchMode % _titleMatchMode
return _hwnd
}

Por muy innecesariamente complejo que parezca el script del vinculo anterior, presenta la ventaja de llamar la función RegExMatch únicamente si se han cumplido los requisitos. Es preciso considerar al menos otra una opcion por lo que es adecuado para entornos de producción: sacar partido del 'cortocircuito' lógico de los operadores booleanos OR/AND o/y del único operador ternario de ahk ?: - a modo de ejemplo:

Code: Select all

SetTitleMatchMode, RegEx
Hotkey, If, WinActive("ahk_class MozillaWindowClass ahk_exe firefox.exe") && WinActive("(.*- )?YouTube(?= - Mozilla Firefox$)")
	Hotkey, F4, test
return

test:
	MsgBox % A_ThisLabel
return

#If WinActive("ahk_exe firefox.exe") && WinActive("(.*- )?YouTube(?= - Mozilla Firefox$)") ; !known limitation: if Expression contains an and/or operator, it is not recognized as an existing expression. As a workaround, use the equivalent &&/|| 
#If

Lo he intentado pero con google no me funciona, perdona mi ignorancia

@Aprendiendo Lo siento pero no tengo chrome para comprobar, mas es possible que el ultimo script funcione con el navegador chrome con tal que sustituyas 'firefox' y 'Mozilla Firefox' por 'chrome' y 'Google Chrome', respectivamente.


Saludos