WheelUp y WheelDown con clic derecho (right click) Topic is solved

[Aprendiendo]

Hola, no me funciona la rueda del raton y me preguntaba si era posible crear un ahk que funcione con el movimiento del raton. Lo que quiero es que si tengo RButton pulsado y muevo el raton hacia arriba me haga WheelUp y si lo muevo hacia abajo me haga WheelDown. Gracias.

[Flipeador]

Hola, esta es una forma muy simple de hacerlo. Se podría mejorar mucho más.

Code: Select all

RButton::
KeyWait RButton, T0.2
if ( ErrorLevel )
{
    MouseGetPos X1, Y1
    while GetKeyState("RButton", "P")
    {
        MouseGetPos X2, Y2
        if ( Y1 > Y2 )
        {
            SendInput {WheelUp}
        }
        else if ( Y1 < Y2 )
        {
            SendInput {WheelDown}
        }
        Y1 := Y2
        Sleep 100
    }
}
else
    SendInput {RButton}
return

AHKv2

Code: Select all

; AHK v2.0-a100-52515e2
#Warn  ; Ayuda a detectar errores.

Hotkey("RButton", "Hotkey_RButton")  ; Registramos el botón derecho.
return

; -------------------------------------------------

Hotkey_RButton()
{
    local  ; Evita interferir con las variables super-globales (como nombres de clases).

    ; Si el clic derecho se mantiene presionado por más de 200 milisegundos,
    ; asumimos que el usuario quiere mover la rueda del mouse moviendo el mouse hacia
    ; arriba o hacia abajo mientras se mantiene presionado el clic derecho.
    r := KeyWait("RButton", "T0.2")

    if r  ; Si el botón derecho se soltó antes de los 200 milisegundos.
        return SendInput("{RButton}")  ; Enviamos el clic derecho y devolvemos.
     
    ; En caso contrario...

    ; Recuperamos la coordenada Y actual del cursor, que es la que nos interesa.
    MouseGetPos(, Y1)

    while GetKeyState("RButton", "P")  ; Mientras se mantenga presionado el click derecho.
    {
        MouseGetPos(, Y2)  ; Recuperamos nuevamente la coordenada Y del cursor.

        if Y1 > Y2  ; Si el mouse se movió hacia arriba.
        {
            ;if (Y1-Y2) > 17
                SendInput("{WheelUp}")
        }
        else if Y1 < Y2  ; Si el mouse se movío hacia abajo.
        {
            ;if (Y2-Y1) > 17
                SendInput("{WheelDown}")
        }

        Y1 := Y2  ; Actualizamos la coordenada Y1, para compararla en la próxima iteración.
        Sleep(100)  ; Retraso para evitar WheelUp/WheelDown demasiado rapidos.
    }
}