Triple cambio de tecla Topic is solved

[randysejas]

Cambié el funcionamiento de la tecla CapsLock a Delete (dentro de windows), pero ya en photoshop lo cambio a Backspace (hasta ahí todo funciona muy bien)... pero dentro de Photoshop hago otro cambio de teclas, CapsLock a Tab (pero ahí CapsLock se sigue comportando como Backspace)... hay algo que esté haciendo mal?... muchas gracias por adelantado.

Code: Select all

CapsLock::Delete

#IfWinActive, ahk_exe Photoshop.exe                     ; PHOTOSHOP 
;------------------------------------------------------------------------------
CapsLock::Backspace

CambiarCursores := 0
~Space & s::
    SoundBeep, 300, 150
    CambiarCursores :=!CambiarCursores
    if (CambiarCursores=0)
        ToolTip
    else
        ToolTip, ON, 910, 32
Return
#IF (CambiarCursores=1)
{
    CapsLock::Tab
    s::Down
    w::Up
    a::Left
    d::Right
}
#IF

[ositoMalvado]

Prueba con esto

Code: Select all

Global Toggle:=false
Global PsName:="photoshop.exe"
Hotkey, $CapsLock, Caps
Hotkey, $a, aToLeft
Hotkey, $d, dToRight
Hotkey, $s, sToDown
Hotkey, $w, wToUp
return
Caps:
 	If (Toggle and WinActive("ahk_exe " PsName)){
		send {tab}
	}else{
		If (WinActive("ahk_exe " PsName))
			send {backspace}
		else
			send {delete}
 	}
return
aToLeft:
	if (Toggle and (WinActive("ahk_exe " PsName)))
		send {Left}
	else
		send a
return
dToRight:
	if (Toggle and (WinActive("ahk_exe " PsName)))
		send {Right}
	else
		send d
return
sToDown:
	if (Toggle and (WinActive("ahk_exe " PsName)))
		send {Down}
	else
		send s
return
wToUp:
	if (Toggle and (WinActive("ahk_exe " PsName)))
		send {Up}
	else
		send w
return
~Space & s::
	if(Toggle){
		SoundBeep, 400, 200
		Toggle:=false
		ToolTip, Script apagado
	}else{ 
		SoundBeep, 480, 200
		Toggle:=true
		ToolTip, Script encendido
	}
	SetTimer, killIt, 500
return
killIt:
	ToolTip
	SetTimer, killIt, off	
return

[randysejas]

@ositoMalvado Gracias... probé con tu código pero no me funcionan los cursores correctamente cuando mantengo presionado Shift + Cursores..... pero en el foro en inglés ya me respondieron y el código funcionó muy bien... lo publico aquí y @ositoMalvado muchas gracias nuevamente‼

Code: Select all

CapsLock::Delete
#IF (CambiarCursores=1) And WinActive("ahk_exe Photoshop.exe")
CapsLock::Tab
s::Down
w::Up
a::Left
d::Right
#IfWinActive, ahk_exe Photoshop.exe                     ; PHOTOSHOP
;------------------------------------------------------------------------------
CapsLock::Backspace
CambiarCursores := 0 ;unexecuted code
~Space & s::
SoundBeep, 300, 150
CambiarCursores :=!CambiarCursores
if (CambiarCursores=0)
	ToolTip
else
	ToolTip, ON, 910, 32
Return
#IF