Способы сравнения бинарных значений GUID в Autohotkey Topic is solved

[vmech]

Ок. Спрошу здесь.

Кроме напрашивающегося самим собой способа, например:

Code: Select all

#Requires Autohotkey v2.0
szGUID := 16, Schemes := [], ActiveScheme := Buffer(szGUID)
Loop
{
  r := DllCall('powrprof.dll\PowerEnumerate', 'Ptr', 0, 'Ptr', 0, 'Ptr', 0, 'UInt', 16, 'UInt', A_Index - 1, 'Ptr', GUID := Buffer(szGUID), 'PtrP', &szGUID)
  If r != 0
    Break
  Schemes.Push(GUID)
}

DllCall('powrprof.dll\PowerGetActiveScheme', 'Ptr', 0, 'PtrP', &ptrActive := 0)
NumPut('Int64', NumGet(ptrActive, 'Int64'), 'Int64', NumGet(ptrActive, 8, 'Int64'), ActiveScheme)
DllCall('LocalFree', 'Ptr', ptrActive)

Loop Schemes.Length
{
  If CompareGUID(ActiveScheme, Schemes[A_Index])
    MsgBox('Bingo!')
}

CompareGUID(p1, p2) => (NumGet(p1, 'Int64') = NumGet(p2, 'Int64') && NumGet(p1, 8, 'Int64') = NumGet(p2, 8, 'Int64'))

какие ещё способы сравнивать бинарные GUID'ы возможно реализовать силами Autohotkey ?

[teadrinker]

Попробуйте так:

Code: Select all

CompareGUID(p1, p2) => DllCall('Ole32\IsEqualGUID', 'Ptr', p1, 'Ptr', p2)

[vmech]

Попробуйте так:

Code: Select all

CompareGUID(p1, p2) => DllCall('Ole32\IsEqualGUID', 'Ptr', p1, 'Ptr', p2)

Вобщем забавная штука... Если в циклах бенча вызывать оба варианта через объекты функций, то вариант с NumGet получается немного быстрее, чем вариант с DllCall.

Вызовы через прослойку

Code: Select all

#Requires Autohotkey v2.0
CRLF := '`n', szGUID := 16, Schemes := [], Count := 10 ** 6
Loop
{
  If ( 0 != DllCall('powrprof.dll\PowerEnumerate', 'Ptr', 0, 'Ptr', 0, 'Ptr', 0, 'UInt', 16, 'UInt', A_Index - 1, 'Ptr', GUID := Buffer(szGUID), 'PtrP', &szGUID) )
    Break
  Schemes.Push(GUID)
}
DllCall('powrprof.dll\PowerGetActiveScheme', 'Ptr', 0, 'PtrP', &ptrActive := 0)

a := A_TickCount
Loop Count
  Loop Schemes.Length
    CompareGUID(ptrActive, Schemes[A_Index])
b := A_TickCount
c .= 'CompareGUID: ' (b - a) CRLF
a := A_TickCount
Loop Count
  Loop Schemes.Length
    IsEqualGUID(ptrActive, Schemes[A_Index])
b := A_TickCount
c .= 'IsEqualGUID: ' (b - a) CRLF
MsgBox(c,,64)

DllCall('LocalFree', 'Ptr', ptrActive)
CompareGUID(p1, p2) => (NumGet(p1, 'Int64') = NumGet(p2, 'Int64') && NumGet(p1, 8, 'Int64') = NumGet(p2, 8, 'Int64'))
IsEqualGUID(p1, p2) => (DllCall('ole32.dll\IsEqualGUID', 'Ptr', p1, 'Ptr', p2))

Если же в циклах бенча использовать прямые вызовы, без прослоек, тогда наблюдается примерный паритет.

Прямые вызовы

Code: Select all

#Requires Autohotkey v2.0
CRLF := '`n', szGUID := 16, Schemes := [], Count := 10 ** 6
Loop
{
  If ( 0 != DllCall('powrprof.dll\PowerEnumerate', 'Ptr', 0, 'Ptr', 0, 'Ptr', 0, 'UInt', 16, 'UInt', A_Index - 1, 'Ptr', GUID := Buffer(szGUID), 'PtrP', &szGUID) )
    Break
  Schemes.Push(GUID)
}
DllCall('powrprof.dll\PowerGetActiveScheme', 'Ptr', 0, 'PtrP', &ptrActive := 0)

a := A_TickCount
Loop Count
  Loop Schemes.Length
    NumGet(ptrActive, 'Int64') = NumGet(Schemes[A_Index], 'Int64') && NumGet(ptrActive, 8, 'Int64') = NumGet(Schemes[A_Index], 8, 'Int64')
b := A_TickCount
c .= 'CompareGUID: ' (b - a) CRLF
a := A_TickCount
Loop Count
  Loop Schemes.Length
    DllCall('ole32.dll\IsEqualGUID', 'Ptr', ptrActive, 'Ptr', Schemes[A_Index])
b := A_TickCount
c .= 'IsEqualGUID: ' (b - a) CRLF
MsgBox(c,,64)

DllCall('LocalFree', 'Ptr', ptrActive)

А в целом, именно для сравнения единичных значений, оба варианта одинаково хороши.

[teadrinker]

Вы можете ускорить работу с dll в цикле, если укажете #DllLoad 'Ole32.dll' в начале скрипта.

[vmech]

Вы можете ускорить работу с dll в цикле, если укажете #DllLoad 'Ole32.dll' в начале скрипта.

Я пробовал и #DllLoad, и вызовы LoadLibrary с GetProcAddress, но, по каким то причинам, эти шаги не ускорили работу с внешними функциями ни на миллисекунду.
Мне неизвестны причины такого поведения, но я осмелился предположить, что, вероятно, v2 эффективно линкует вызовы функций из DllCall ещё на стадии первичной обработки исходного кода скриптов.
А м.б. причина в более эффективной сборке бинарников библиотек в новейших ОС Windows. Или ещё каких то оптимизациях ОС.
А м.б. в совокупности обоих факторов

ЗЫ. Проверка времени исполнения проводилась на гораздо более тяжелом варианте вызовов функций CLSIDFromString --> StringFromCLSID. В том числе с замерами с помощью QueryPerformanceCounter. На миллионы вызовов погрешность времени исполнения укладывалась в доли миллисекунд (десятки/сотни микросекунд).
ЗЫЫ. Тенденция значительного увеличения накладных расходов при вызовах функций библиотек через прослойку в виде собственных функций Autohotkey так же сохранилась. И не отличалась для вариантов с динамической линковкой, и принудительно загруженных машинных адресов функций.

[teadrinker]

Да, действительно, я не проверил. Оказывается, библиотека Ole32.dll уже загружена в AHK процесс. Проверить можно так:

Code: Select all

MsgBox DllCall('GetModuleHandle', 'Str', 'Ole32.dll')

в отличие от, например, Gdiplus.dll:

Code: Select all

MsgBox DllCall('GetModuleHandle', 'Str', 'Gdiplus.dll')

[vmech]

Да уж... Под 10-кой 64-бита загружается «вагон и маленькая тележка» библиотек

Spoiler

ADVAPI32.dll
COMCTL32.dll
dwmapi.dll
GDI32.dll
KERNEL32.dll
mscoree.dll
ntdll.dll
ole32.dll
OLEAUT32.dll
PSAPI.DLL
riched20.dll
SHELL32.dll
SHLWAPI.dll
USER32.dll
user32.dll
UxTheme.dll
VERSION.dll
WININET.dll
WINMM.dll
WSOCK32.dll