member just me please

[raylan]

I'm your fan

your all functions perfect
I'm so good

autohoykey FileSelectFolder uncomfortable

FileSelectFolder The new vista dialog style Please make

[just me]

Hi,

I've absolutely no problem with FileSelectFolder. The Vista+ dialog would require an implemantation of the Common Item Dialog. That's COM, and COM isn't my preferred playground. But maybe some other member will do it or has done it already.

[raylan]

thanks for reading

[just me]

Well, it turned out to be not that difficult as I expected. Here's a minimum implementation, seemingly working:

Code: Select all

SelectFolder() {
   ; Common Item Dialog -> msdn.microsoft.com/en-us/library/bb776913%28v=vs.85%29.aspx
   ; IFileDialog        -> msdn.microsoft.com/en-us/library/bb775966%28v=vs.85%29.aspx
   ; IShellItem         -> msdn.microsoft.com/en-us/library/bb761140%28v=vs.85%29.aspx
   Static OsVersion := DllCall("GetVersion", "UChar")
   Static Show := A_PtrSize * 3
   Static SetOptions := A_PtrSize * 9
   Static GetResult := A_PtrSize * 20
   SelectedFolder := ""
   If (OsVersion < 6) { ; IFileDialog requires Win Vista+
      FileSelectFolder, SelectedFolder
      Return SelectedFolder
   }
   If !(FileDialog := ComObjCreate("{DC1C5A9C-E88A-4dde-A5A1-60F82A20AEF7}", "{42f85136-db7e-439c-85f1-e4075d135fc8}"))
      Return ""
   VTBL := NumGet(FileDialog + 0, "UPtr")
   DllCall(NumGet(VTBL + SetOptions, "UPtr"), "Ptr", FileDialog, "UInt", 0x00000028, "UInt") ; FOS_NOCHANGEDIR | FOS_PICKFOLDERS
   If !DllCall(NumGet(VTBL + Show, "UPtr"), "Ptr", FileDialog, "Ptr", 0, "UInt") {
      If !DllCall(NumGet(VTBL + GetResult, "UPtr"), "Ptr", FileDialog, "PtrP", ShellItem, "UInt") {
         GetDisplayName := NumGet(NumGet(ShellItem + 0, "UPtr"), A_PtrSize * 5, "UPtr")
         If !DllCall(GetDisplayName, "Ptr", ShellItem, "UInt", 0x80028000, "PtrP", StrPtr) ; SIGDN_DESKTOPABSOLUTEPARSING
            SelectedFolder := StrGet(StrPtr, "UTF-16"), DllCall("Ole32.dll\CoTaskMemFree", "Ptr", StrPtr)
         ObjRelease(ShellItem)
      }
   }
   ObjRelease(FileDialog)
   Return SelectedFolder
}

[raylan]

hi just me

I can never thank you enough
Couldn't be better
You're the best!
thank you so much

Please be happy always!

[raylan]

my windows 10 Pro x64
It works perfectly
by any chance Prompt title ?
Okay Thanks just me

[kon]

This seems to set the title.

Code: Select all

SelectFolder("My Title")

SelectFolder(Title:="") {
   ; Common Item Dialog -> msdn.microsoft.com/en-us/library/bb776913%28v=vs.85%29.aspx
   ; IFileDialog        -> msdn.microsoft.com/en-us/library/bb775966%28v=vs.85%29.aspx
   ; IShellItem         -> msdn.microsoft.com/en-us/library/bb761140%28v=vs.85%29.aspx
   Static OsVersion := DllCall("GetVersion", "UChar")
   Static Show := A_PtrSize * 3
   Static SetOptions := A_PtrSize * 9
   Static SetTitle := A_PtrSize * 17
   Static GetResult := A_PtrSize * 20
   SelectedFolder := ""
   If (OsVersion < 6) { ; IFileDialog requires Win Vista+
      FileSelectFolder, SelectedFolder
      Return SelectedFolder
   }
   If !(FileDialog := ComObjCreate("{DC1C5A9C-E88A-4dde-A5A1-60F82A20AEF7}", "{42f85136-db7e-439c-85f1-e4075d135fc8}"))
      Return ""
   VTBL := NumGet(FileDialog + 0, "UPtr")
   DllCall(NumGet(VTBL + SetOptions, "UPtr"), "Ptr", FileDialog, "UInt", 0x00000028, "UInt") ; FOS_NOCHANGEDIR | FOS_PICKFOLDERS
   If (Title != "")
      DllCall(NumGet(VTBL + SetTitle, "UPtr"), "Ptr", FileDialog, "Str", Title, "UInt")
   If !DllCall(NumGet(VTBL + Show, "UPtr"), "Ptr", FileDialog, "Ptr", 0, "UInt") {
      If !DllCall(NumGet(VTBL + GetResult, "UPtr"), "Ptr", FileDialog, "PtrP", ShellItem, "UInt") {
         GetDisplayName := NumGet(NumGet(ShellItem + 0, "UPtr"), A_PtrSize * 5, "UPtr")
         If !DllCall(GetDisplayName, "Ptr", ShellItem, "UInt", 0x80028000, "PtrP", StrPtr) ; SIGDN_DESKTOPABSOLUTEPARSING
            SelectedFolder := StrGet(StrPtr, "UTF-16"), DllCall("Ole32.dll\CoTaskMemFree", "Ptr", StrPtr)
         ObjRelease(ShellItem)
      }
   }
   ObjRelease(FileDialog)
   Return SelectedFolder
}

Here's the vtable offsets for the other methods.

Code: Select all

IFileDialog vtable offsets
0   QueryInterface
1   AddRef 
2   Release 
3   Show 
4   SetFileTypes 
5   SetFileTypeIndex 
6   GetFileTypeIndex 
7   Advise 
8   Unadvise 
9   SetOptions 
10  GetOptions 
11  SetDefaultFolder 
12  SetFolder 
13  GetFolder 
14  GetCurrentSelection 
15  SetFileName 
16  GetFileName 
17  SetTitle 
18  SetOkButtonLabel 
19  SetFileNameLabel 
20  GetResult 
21  AddPlace 
22  SetDefaultExtension 
23  Close 
24  SetClientGuid 
25  ClearClientData 
26  SetFilter

[raylan]

Hi Kon
I owe you thanks

[just me]

LPCWSTR pszTitle

Code: Select all

      DllCall(NumGet(VTBL + SetTitle, "UPtr"), "Ptr", FileDialog, "WStr", Title, "UInt")

[kon]

Thanks for the correction just me. The sad thing is I know that all COM strings should be Unicode. There's a lot to keep track of, and I need more practice with DllCall data types.

raylan, Because of the incorrect string type, my code above would not work on ANSI versions of AHK.

[Delta Pythagorean]

Ok, old topic, I know.
But I'd like to get this dialog to be a "child" to an AHK made Gui, know of any way? I've tried the DllCall SetParent, I've Tried Gui, +OwnDialogs nothing worked...
I haven't found a solution in the Microsoft docs either. I'm completely stumped :s

[jeuneperkersauvage]

Ok, old topic, I know.
But I'd like to get this dialog to be a "child" to an AHK made Gui, know of any way? I've tried the DllCall SetParent, I've Tried Gui, +OwnDialogs nothing worked...
I haven't found a solution in the Microsoft docs either. I'm completely stumped :s

When creating your GUI, make sure to tell AutoHotkey to save its HWND to a variable.

You can then change SelectFolder() { to SelectFolder(hwndOwner := 0) { and DllCall(NumGet(VTBL + Show, "UPtr"), "Ptr", FileDialog, "Ptr", 0, "UInt") into DllCall(NumGet(VTBL + Show, "UPtr"), "Ptr", FileDialog, "Ptr", hwndOwner, "UInt").

Pass said HWND when calling SelectFolder and it should be OK. Documentation on the Show method can be found here: https://msdn.microsoft.com/en-us/librar ... s.85).aspx

[jeuneperkersauvage]

Or just use https://autohotkey.com/boards/viewtopic.php?f=6&t=18939

[Delta Pythagorean]

Or just use https://autohotkey.com/boards/viewtopic.php?f=6&t=18939

https://autohotkey.com/boards/posting.p ... postingbox

Thank you both very much! It's greatly appreciated!