A needless class to turn a progress bar into a slider (colorful gui sliders)

[Hellbent]

This is a very simple class for turning a Progress bar gui control into a slider.

With how it is set up, be sure to make your slider variable and paired edit variable global.



Here is a little demo script

Code: Select all

#SingleInstance, Force
global Demo_Slider_1 , DS1Edit , pSlider := []
global Demo_Slider_2 , DS2Edit
global Demo_Slider_3 , DS3Edit
global Demo_Slider_4 , DS4Edit

Gui,1:+AlwaysOnTop -DPIScale
Gui,1:Color,333333
Gui,1:Font,s10 w600


Gui,1:Add,Button,x40 y10 w35 h17 -Theme vSub5 gAdjustSlider1,- 5
Gui,1:Add,Button,x80 y10 w35 h17 -Theme vSub1 gAdjustSlider1,- 1
Gui,1:Add,Edit,x125 y10 w50 h17 -E0x200 Center Disabled vDS1Edit ,5
Gui,1:Add,Button,x185 y10 w35 h17 -Theme vAdd1 gAdjustSlider1,+ 1
Gui,1:Add,Button,x225 y10 w35 h17 -Theme vAdd5 gAdjustSlider1,+ 5
pSlider[1]:= New Progress_Slider("1","Demo_Slider_1",30,35,240,20,-20,25,5,"D18F0B","FFFF00",1,"DS1Edit",1)


pSlider[2]:= New Progress_Slider("1","Demo_Slider_2",30,70,10,200,0,250,58,"080D60","0A17D8",1,"DS2Edit",1,1)
Gui,1:Add,Edit,x10 y280 w50 h17 -E0x200 Center Disabled vDS2Edit ,58

pSlider[3]:= New Progress_Slider("1","Demo_Slider_3",80,70,30,200,0,550,122,"555555","aaaaaa",1,"DS3Edit",0,1)
Gui,1:Add,Edit,x70 y280 w50 h17 -E0x200 Center Disabled vDS3Edit ,122

pSlider[4]:= New Progress_Slider("1","Demo_Slider_4",150,70,20,200,0,1250,158,,,1,"DS4Edit",1,1,0)
Gui,1:Add,Edit,x140 y280 w40 h17 -E0x200 Center Disabled vDS4Edit,158

Gui,1:Show, w300 , pSlider Demo  `
return
GuiClose:
GuiContextMenu:
	ExitApp


AdjustSlider1:
	(A_GuiControl="Sub5")?(pSlider[1].Slider_Value-=5):(A_GuiControl="Sub1")?(pSlider[1].Slider_Value-=1):(A_GuiControl="Add1")?(pSlider[1].Slider_Value+=1):(A_GuiControl="Add5")?(pSlider[1].Slider_Value+=5)
	(pSlider[1].Slider_Value > pSlider[1].End_Range)?(pSlider[1].SET_pSlider(pSlider[1].End_Range)):(pSlider[1].Slider_Value < pSlider[1].Start_Range)?(pSlider[1].SET_pSlider(pSlider[1].Start_Range)):(pSlider[1].SET_pSlider(pSlider[1].Slider_Value))
	return

numpad1::
	pSlider[1].SET_pSlider(-8)
	return
	
	
class Progress_Slider	{
	__New(pSlider_GUI_NAME , pSlider_Control_ID , pSlider_X , pSlider_Y , pSlider_W , pSlider_H , pSlider_Range_Start , pSlider_Range_End , pSlider_Value:=0 , pSlider_Background_Color := "Black" , pSlider_Top_Color := "Red" , pSlider_Pair_With_Edit := 0 , pSlider_Paired_Edit_ID := "" , pSlider_Use_Tooltip := 0 ,  pSlider_Vertical := 0 , pSlider_Smooth := 1){
		This.GUI_NAME:=pSlider_GUI_NAME
		This.Control_ID:=pSlider_Control_ID
		This.X := pSlider_X
		This.Y := pSlider_Y
		This.W := pSlider_W
		This.H := pSlider_H
		This.Start_Range := pSlider_Range_Start
		This.End_Range := pSlider_Range_End
		This.Slider_Value := pSlider_Value
		This.Background_Color := pSlider_Background_Color
		This.Top_Color := pSlider_Top_Color
		This.Vertical := pSlider_Vertical
		This.Smooth := pSlider_Smooth
		This.Pair_With_Edit := pSlider_Pair_With_Edit
		This.Paired_Edit_ID := pSlider_Paired_Edit_ID
		This.Use_Tooltip := pSlider_Use_Tooltip
		This.Add_pSlider()
	}
	Add_pSlider(){
		Gui, % This.GUI_NAME ":Add" , Text , % "x" This.X " y" This.Y " w" This.W " h" This.H " hwndpSliderTriggerhwnd"
		pSlider_Trigger := This.Adjust_pSlider.BIND( THIS ) 
		GUICONTROL +G , %pSliderTriggerhwnd% , % pSlider_Trigger
		if(This.Smooth=1&&This.Vertical=0)
			Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " Background" This.Background_Color " c" This.Top_Color " Range" This.Start_Range "-" This.End_Range  " v" This.Control_ID ,% This.Slider_Value
		else if(This.Smooth=0&&This.Vertical=0)
			Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " -Smooth Range" This.Start_Range "-" This.End_Range  " v" This.Control_ID ,% This.Slider_Value
		else if(This.Smooth=1&&This.Vertical=1)
			Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " Background" This.Background_Color " c" This.Top_Color " Range" This.Start_Range "-" This.End_Range  " Vertical v" This.Control_ID ,% This.Slider_Value
		else if(This.Smooth=0&&This.Vertical=1)
			Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " -Smooth Range" This.Start_Range "-" This.End_Range  " Vertical v" This.Control_ID ,% This.Slider_Value
	}
	Adjust_pSlider(){
		CoordMode,Mouse,Client
		while(GetKeyState("LButton")){
			MouseGetPos,pSlider_Temp_X,pSlider_Temp_Y
			if(This.Vertical=0)
				This.Slider_Value := Round((pSlider_Temp_X - This.X ) / ( This.W / (This.End_Range - This.Start_Range) )) + This.Start_Range
			else
				This.Slider_Value := Round(((pSlider_Temp_Y - This.Y ) / ( This.H / (This.End_Range - This.Start_Range) )) + This.Start_Range )* -1 + This.End_Range
			if(This.Slider_Value > This.End_Range )
				This.Slider_Value:=This.End_Range
			else if(This.Slider_Value<This.Start_Range)
				This.Slider_Value:=This.Start_Range
			GuiControl,% This.GUI_NAME ":" ,% This.Control_ID , % This.Slider_Value 
			if(This.Pair_With_Edit=1)
				GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID , % This.Slider_Value 
			if(This.Use_Tooltip=1)
				ToolTip , % This.Slider_Value 
		}
		if(This.Use_Tooltip=1)
			ToolTip,
	}
	SET_pSlider(NEW_pSlider_Value){
		This.Slider_Value := NEW_pSlider_Value
		GuiControl,% This.GUI_NAME ":" ,% This.Control_ID , % This.Slider_Value
		if(This.Pair_With_Edit=1)
			GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID , % This.Slider_Value
	}
}

And here is the class alone

Code: Select all

	
class Progress_Slider	{
	__New(pSlider_GUI_NAME , pSlider_Control_ID , pSlider_X , pSlider_Y , pSlider_W , pSlider_H , pSlider_Range_Start , pSlider_Range_End , pSlider_Value:=0 , pSlider_Background_Color := "Black" , pSlider_Top_Color := "Red" , pSlider_Pair_With_Edit := 0 , pSlider_Paired_Edit_ID := "" , pSlider_Use_Tooltip := 0 ,  pSlider_Vertical := 0 , pSlider_Smooth := 1){
		This.GUI_NAME:=pSlider_GUI_NAME
		This.Control_ID:=pSlider_Control_ID
		This.X := pSlider_X
		This.Y := pSlider_Y
		This.W := pSlider_W
		This.H := pSlider_H
		This.Start_Range := pSlider_Range_Start
		This.End_Range := pSlider_Range_End
		This.Slider_Value := pSlider_Value
		This.Background_Color := pSlider_Background_Color
		This.Top_Color := pSlider_Top_Color
		This.Vertical := pSlider_Vertical
		This.Smooth := pSlider_Smooth
		This.Pair_With_Edit := pSlider_Pair_With_Edit
		This.Paired_Edit_ID := pSlider_Paired_Edit_ID
		This.Use_Tooltip := pSlider_Use_Tooltip
		This.Add_pSlider()
	}
	Add_pSlider(){
		Gui, % This.GUI_NAME ":Add" , Text , % "x" This.X " y" This.Y " w" This.W " h" This.H " hwndpSliderTriggerhwnd"
		pSlider_Trigger := This.Adjust_pSlider.BIND( THIS ) 
		GUICONTROL +G , %pSliderTriggerhwnd% , % pSlider_Trigger
		if(This.Smooth=1&&This.Vertical=0)
			Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " Background" This.Background_Color " c" This.Top_Color " Range" This.Start_Range "-" This.End_Range  " v" This.Control_ID ,% This.Slider_Value
		else if(This.Smooth=0&&This.Vertical=0)
			Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " -Smooth Range" This.Start_Range "-" This.End_Range  " v" This.Control_ID ,% This.Slider_Value
		else if(This.Smooth=1&&This.Vertical=1)
			Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " Background" This.Background_Color " c" This.Top_Color " Range" This.Start_Range "-" This.End_Range  " Vertical v" This.Control_ID ,% This.Slider_Value
		else if(This.Smooth=0&&This.Vertical=1)
			Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " -Smooth Range" This.Start_Range "-" This.End_Range  " Vertical v" This.Control_ID ,% This.Slider_Value
	}
	Adjust_pSlider(){
		CoordMode,Mouse,Client
		while(GetKeyState("LButton")){
			MouseGetPos,pSlider_Temp_X,pSlider_Temp_Y
			if(This.Vertical=0)
				This.Slider_Value := Round((pSlider_Temp_X - This.X ) / ( This.W / (This.End_Range - This.Start_Range) )) + This.Start_Range
			else
				This.Slider_Value := Round(((pSlider_Temp_Y - This.Y ) / ( This.H / (This.End_Range - This.Start_Range) )) + This.Start_Range )* -1 + This.End_Range
			if(This.Slider_Value > This.End_Range )
				This.Slider_Value:=This.End_Range
			else if(This.Slider_Value<This.Start_Range)
				This.Slider_Value:=This.Start_Range
			GuiControl,% This.GUI_NAME ":" ,% This.Control_ID , % This.Slider_Value 
			if(This.Pair_With_Edit=1)
				GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID , % This.Slider_Value 
			if(This.Use_Tooltip=1)
				ToolTip , % This.Slider_Value 
		}
		if(This.Use_Tooltip=1)
			ToolTip,
	}
	SET_pSlider(NEW_pSlider_Value){
		This.Slider_Value := NEW_pSlider_Value
		GuiControl,% This.GUI_NAME ":" ,% This.Control_ID , % This.Slider_Value
		if(This.Pair_With_Edit=1)
			GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID , % This.Slider_Value
	}
}

[Drugwash]

Third vertical progress-slider (left to right) works in reverse. Otherwise it's fine here on XP-SP4.
I did that some time ago for Win98SE despite people saying it'd be impossible. Good ol' days.

[Hellbent]

Third vertical progress-slider (left to right) works in reverse.

I was expecting that it would look different, but i'm not sure what you mean?

-Smooth (minus Smooth): Displays a length of segments rather than a smooth continuous bar.
Specifying -Smooth is also one of the requirements to show a themed progress bar on Windows XP or later.
The other requirement is that the bar not have any custom colors; that is, that the C and
Background options be omitted.

I assume that you are talking about getting it to look like segments, but other than that I'm not sure about the the reverse part.

[Drugwash]

I mean, sliding upwards it displays lower value, while sliding downwards it displays higher value.

ProgressSliderLowHighEdit.png (26.3 KiB) Viewed 4745 times

Not displaying as segmented is just another issue, but I don't like that style anyway.
There is however a script by jNizM originally posted here which I've slightly modified so it can display segmented progressbars (the last two at the bottom). Here's the modified code, it may be of help:

Code: Select all

; by jNizM  https://autohotkey.com/boards/viewtopic.php?f=7&t=4662

; GLOBAL SETTINGS ===============================================================================================================

#NoEnv
#SingleInstance Force

WM_USER               := 0x00000400
PBM_SETMARQUEE        := WM_USER + 10
PBM_SETSTATE          := WM_USER + 16
PBS_MARQUEE           := 0x00000008
PBS_SMOOTH            := 0x00000001
PBS_VERTICAL          := 0x00000004
PBST_NORMAL           := 0x00000001
PBST_ERROR            := 0x00000002
PBST_PAUSE            := 0x00000003
STAP_ALLOW_NONCLIENT  := 0x00000001
STAP_ALLOW_CONTROLS   := 0x00000002
STAP_ALLOW_WEBCONTENT := 0x00000004
WM_THEMECHANGED       := 0x0000031A

; SCRIPT ========================================================================================================================

Gui, Margin, 5, 5
Gui, Font, s14 Bold
Gui, Add, Text, xm ym 0x200, Progressbar Examples

; ------------------------------------------------------------------------------------------------------
Gui, Add, Progress, w300 h20, 50

; ------------------------------------------------------------------------------------------------------
Gui, Add, Progress, w300 h20 hwndMARQ1 +%PBS_MARQUEE%, 50
DllCall("User32.dll\SendMessage", Ptr, MARQ1, "Int", PBM_SETMARQUEE, Ptr, 1, Ptr, 50)

; ------------------------------------------------------------------------------------------------------
Gui, Add, Progress, w300 h20 BackgroundC9C9C9, 50

; ------------------------------------------------------------------------------------------------------
Gui, Add, Progress, w300 h20 BackgroundC9C9C9 hwndMARQ2 +%PBS_MARQUEE%, 50
DllCall("User32.dll\SendMessage", Ptr, MARQ2, "Int", PBM_SETMARQUEE, Ptr, 1, Ptr, 50)

; ------------------------------------------------------------------------------------------------------
DllCall("uxtheme.dll\SetThemeAppProperties", "UInt", 0)
Gui, Add, Progress, w300 h20 c66EE66 hwndUTHEME, 50
;DllCall("User32.dll\SendMessage", Ptr, UTHEME, "Int", WM_THEMECHANGED, Ptr, 0, Ptr, 0)
DllCall("uxtheme.dll\SetThemeAppProperties", "UInt", 7)

; ------------------------------------------------------------------------------------------------------
DllCall("uxtheme.dll\SetThemeAppProperties", "UInt", 0)
Gui, Add, Progress, w300 h20 c66EE66 hwndMARQ3 +%PBS_MARQUEE%, 50
DllCall("User32.dll\SendMessage", Ptr, MARQ3, "Int", PBM_SETMARQUEE, Ptr, 1, Ptr, 50)
DllCall("uxtheme.dll\SetThemeAppProperties", "UInt", 7)

; ------------------------------------------------------------------------------------------------------
Gui, Add, Progress, w300 h20 -%PBS_SMOOTH%, 50

; ------------------------------------------------------------------------------------------------------
Gui, Add, Progress, w300 h20 hwndMARQ4 -%PBS_SMOOTH% +%PBS_MARQUEE%, 50
DllCall("User32.dll\SendMessage", Ptr, MARQ4, "Int", PBM_SETMARQUEE, Ptr, 1, Ptr, 50)

; ------------------------------------------------------------------------------------------------------
Gui, Add, Progress, w300 h20 hwndPROG -%PBS_SMOOTH%, 50
DllCall("User32.dll\SendMessage", Ptr, PROG, "Int", PBM_SETSTATE, Ptr, PBST_NORMAL, Ptr, 0)

; ------------------------------------------------------------------------------------------------------
Gui, Add, Progress, w300 h20 hwndPROR -%PBS_SMOOTH%, 50
DllCall("User32.dll\SendMessage", Ptr, PROR, "Int", PBM_SETSTATE, Ptr, PBST_ERROR, Ptr, 0)

; ------------------------------------------------------------------------------------------------------
Gui, Add, Progress, w300 h20 hwndPROY -%PBS_SMOOTH%, 50
DllCall("User32.dll\SendMessage", Ptr, PROY, "Int", PBM_SETSTATE, Ptr, PBST_PAUSE, Ptr, 0)

; ------------------------------------------------------------------------------------------------------
; === ADDITION ===
Gui, Add, Progress, w300 h20 -Smooth -Theme BackgroundFFFFFF, 50
Gui, Add, Progress, w300 h20 -Smooth -Theme hwndMARQ5 +%PBS_MARQUEE% BackgroundFFFFFF, 50
DllCall("User32.dll\SendMessage", Ptr, MARQ5, "Int", PBM_SETMARQUEE, Ptr, 1, Ptr, 800)

Gui, Show, AutoSize
return

; EXIT ==========================================================================================================================
Close:
GuiClose:
GuiEscape:
    exitapp

Here's how it looks like:

20190120141454.png (15.98 KiB) Viewed 4745 times

[Hellbent]

That is very odd, I'm not seeing that here on my end.


https://imgur.com/a/YeXeH5m

[Drugwash]

Could have something to do with the Windows version and its common controls library, and/or AHK version; I'm currently using XP-SP3 (x86) with unofficial SP4 installed, and AHK 1.1.28.00 Unicode.
Well, no biggie. Thanks for your code, it may come in handy.

[Hellbent]

Could have something to do with the Windows version and its common controls library, and/or AHK version; I'm currently using XP-SP3 (x86) with unofficial SP4 installed, and AHK 1.1.28.00 Unicode.
Well, no biggie. Thanks for your code, it may come in handy.

No problem.
I take it that the other sliders work so it's only the -Smooth (pSlider_Smooth = 0) option that causes a issue for you.

[Drugwash]

Yes, all other sliders work correctly.

[thebbandit]

Bravo, another wonderful class! This thread deserves a bump!

[Hellbent]

You can find another take on a progress slider here.
https://www.autohotkey.com/boards/viewtopic.php?f=76&t=64671#p301727
and another one at the bottom of that page.

They aren't in a class, but have a few features that this one doesn't.

[thebbandit]

I took the code you built and as a learning exercise I built another class to create the color selection sliders to make a color picker. Its pretty awesome how it works once you figure out classes, I was always so timid to try using them because they seemed confusing.

Here is what I came up with, maybe someone will find this useful. I know that without your code I would have taken ages to figure out how to do a lot of the tricks you employ I really like the use of the blank text fields, that's a trick I have found to be extremely useful and seems to be the basis for most of these custom controls.

ColorPicker Class

Code: Select all

    ; ColorPicker - Create a color Picker into any GUI window or stand alone
    ; -----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
    class ColorPicker {
        __New(pGroup_GUI_NAME:="ColorPicker", pGroup_ID:="ColorPicker" , pGroup_X:=10 , pGroup_Y:=30 , pGroup_W:=90 , pGroup_H:=280, pGroup_SideBar:=110, pGroup_Start_Color:="000000"){
            This.GUI_NAME := pGroup_GUI_NAME
            This.ID := pGroup_ID
            This.X := pGroup_X
            This.Y := pGroup_Y
            This.W := pGroup_W
            This.H := pGroup_H
            This.SideBar := pGroup_SideBar
            This.Spacing := This.W // 2.5
            This.W_Bar := This.W // 4
            This.Start_Color := pGroup_Start_Color
            This.Start_Red := (0xff0000 & pGroup_Start_Color) >> 16
            This.Start_Green := (0x00ff00 & pGroup_Start_Color) >> 8
            This.Start_Blue := 0x0000ff & pGroup_Start_Color

            ; Gui,% This.GUI_NAME ":Destroy"
            Gui,% This.GUI_NAME ":+AlwaysOnTop -DPIScale +ToolWindow"
            Gui,% This.GUI_NAME ":Color",000000
            Gui,% This.GUI_NAME ":Font",s10 w600

            Edit_Trigger := This.UpdateColor.BIND( THIS ) 

            Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X - 9 " y" This.Y - 18 " w40 h17 -E0x200 Center Disabled v" This.ID "_Red_Edit_Hex" ,% Format("{1:02X}",This.Start_Red)
            This.Slider_Red := New Progress_Slider(This.GUI_NAME,This.ID "_Red",This.X ,This.Y,This.W_Bar,This.H,0,255,This.Start_Red,"550000","BB0000",2,This.ID "_Red_Edit",0,1)
            Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X - 10 " y" This.Y + This.H + 2 " w40 h17 -E0x200 Center Disabled v" This.ID "_Red_Edit hwndRedTriggerhwnd",% This.Start_Red
            GUICONTROL +G , %RedTriggerhwnd% , % Edit_Trigger

            Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X - 9 + This.Spacing " y" This.Y - 18 " w40 h17 -E0x200 Center Disabled v" This.ID "_Green_Edit_Hex" ,% Format("{1:02X}",This.Start_Green)
            This.Slider_Green := New Progress_Slider(This.GUI_NAME,This.ID "_Green",This.X + This.Spacing,This.Y,This.W_Bar,This.H,0,255,This.Start_Green,"005500","00BB00",2,This.ID "_Green_Edit",0,1)
            Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X - 10 + This.Spacing " y" This.Y + This.H + 2 " w40 h17 -E0x200 Center Disabled v" This.ID "_Green_Edit hwndGreenTriggerhwnd" ,% This.Start_Green
            GUICONTROL +G , %GreenTriggerhwnd% , % Edit_Trigger


            Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X - 9 + This.Spacing * 2 " y" This.Y - 18 " w40 h17 -E0x200 Center Disabled v" This.ID "_Blue_Edit_Hex" ,% Format("{1:02X}",This.Start_Blue)
            This.Slider_Blue := New Progress_Slider(This.GUI_NAME,This.ID "_Blue",This.X + This.Spacing*2,This.Y,This.W_Bar,This.H,0,255,This.Start_Blue,"000055","0000BB",2,This.ID "_Blue_Edit",0,1)
            Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X - 10 + This.Spacing * 2 " y" This.Y + This.H + 2 " w40 h17 -E0x200 Center Disabled v" This.ID "_Blue_Edit hwndBlueTriggerhwnd" ,% This.Start_Blue
            GUICONTROL +G , %BlueTriggerhwnd% , % Edit_Trigger


            Gui,% This.GUI_NAME ":Font",s15 w600
            Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X + This.Spacing * 3 " y" This.Y - 22 " w" This.SideBar "h17 -E0x200 Center Disabled v" This.ID "_Group_Color_Hex" ,% Format("0x{1:06X}",This.Start_Color)
        
            Copy_Trigger := This.CopyColor.BIND( THIS )

            Gui,% This.GUI_NAME ":Add",Text,% "x" This.X + This.Spacing * 3 " y" This.Y " w" This.SideBar " h" This.H // 2 + 40 " hwndCopyTriggerhwnd center",
            GUICONTROL +G , %CopyTriggerhwnd% , % Copy_Trigger
            
            Gui,% This.GUI_NAME ":Add",Progress,% "x" This.X + This.Spacing * 3 " y" This.Y " w" This.SideBar " h" This.H // 2 + 20 " Background000000 c" Format("{1:06X}",This.Start_Color) " v" This.ID "_Group_Color", 100

            Gui,% This.GUI_NAME ":Font",s25 w600 c77BB77
            Gui,% This.GUI_NAME ":Add",Text,% "x" This.X + This.Spacing * 3 " y" This.Y + This.H // 2 + 30 " w" This.SideBar " h" (This.H // 2 - 40) // 2 + 10 " hwndCopyTriggerhwnd center", Copy
            GUICONTROL +G , %CopyTriggerhwnd% , % Copy_Trigger
            Gui,% This.GUI_NAME ":Font",s25 w600 cBB7777
            Gui,% This.GUI_NAME ":Add",Text,% "x" This.X + This.Spacing * 3 " y" This.Y + This.H // 2 + 40 + 10 + (This.H // 2 - 40) // 2 " w" This.SideBar " h" (This.H // 2 - 40) // 2 + 10 " gCoordCommand center", Coord


            ; Gui,% This.GUI_NAME ":Show", AutoSize, Color Picker
        }
        UpdateColor(){
            GuiControl, % This.GUI_NAME ": +c" Format("{1:02X}",This.Slider_Red.Slider_Value) Format("{1:02X}",This.Slider_Green.Slider_Value) Format("{1:02X}",This.Slider_Blue.Slider_Value), % This.ID "_Group_Color",
            GuiControl, % This.GUI_NAME ":", % This.ID "_Group_Color_Hex", % "0x" Format("{1:02X}",This.Slider_Red.Slider_Value) Format("{1:02X}",This.Slider_Green.Slider_Value) Format("{1:02X}",This.Slider_Blue.Slider_Value)
        }
        SetColor(newColor){
                This.Start_Color := Format("0x{1:06X}",newColor)
                This.Start_Red := (0xff0000 & newColor) >> 16
                This.Start_Green := (0x00ff00 & newColor) >> 8
                This.Start_Blue := 0x0000ff & newColor
                This.Slider_Red.SET_pSlider(This.Start_Red)
                This.Slider_Green.SET_pSlider(This.Start_Green)
                This.Slider_Blue.SET_pSlider(This.Start_Blue)
        }
        CopyColor(){
            Clipboard := "0x" Format("{1:02X}",This.Slider_Red.Slider_Value) Format("{1:02X}",This.Slider_Green.Slider_Value) Format("{1:02X}",This.Slider_Blue.Slider_Value)
            ; MsgBox, 262144, Color Copied, The Hex color code has been copied to the Clipboard `n`n %Clipboard%
            Notify("Copied To Clipboard`n`n" Clipboard,"",3)
        }
    }
    ; Progress_Slider - Class written by Hellbent on AHK forum, adjusted by Bandit
    ; -----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
    class Progress_Slider	{
        __New(pSlider_GUI_NAME , pSlider_Control_ID , pSlider_X , pSlider_Y , pSlider_W , pSlider_H , pSlider_Range_Start , pSlider_Range_End , pSlider_Value:=0 , pSlider_Background_Color := "Black" , pSlider_Top_Color := "Red" , pSlider_Pair_With_Edit := 0 , pSlider_Paired_Edit_ID := "" , pSlider_Use_Tooltip := 0 ,  pSlider_Vertical := 0 , pSlider_Smooth := 1){
            This.GUI_NAME:=pSlider_GUI_NAME
            This.Control_ID:=pSlider_Control_ID
            This.X := pSlider_X
            This.Y := pSlider_Y
            This.W := pSlider_W
            This.H := pSlider_H
            This.Start_Range := pSlider_Range_Start
            This.End_Range := pSlider_Range_End
            This.Slider_Value := pSlider_Value
            This.Background_Color := pSlider_Background_Color
            This.Top_Color := pSlider_Top_Color
            This.Vertical := pSlider_Vertical
            This.Smooth := pSlider_Smooth
            This.Pair_With_Edit := pSlider_Pair_With_Edit
                ; Options
                ; 0 := Do not pair with edit
                ; 1 := Pair with only Decimal Edit
                ; 2 := Pair with both Decimal and Hex Edit
                ; 3 := Pair with only Hex Edit
            This.Paired_Edit_ID := pSlider_Paired_Edit_ID
            This.Paired_Edit_ID_Hex := (pSlider_Paired_Edit_ID != "" ? pSlider_Paired_Edit_ID . "_Hex" : "")
            This.Use_Tooltip := pSlider_Use_Tooltip
            This.Add_pSlider()
        }
        Add_pSlider(){
            Gui, % This.GUI_NAME ":Add" , Text , % "x" This.X " y" This.Y " w" This.W " h" This.H " hwndpSliderTriggerhwnd"
            pSlider_Trigger := This.Adjust_pSlider.BIND( THIS ) 
            GUICONTROL +G , %pSliderTriggerhwnd% , % pSlider_Trigger
            if(This.Smooth=1&&This.Vertical=0)
                Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " Background" This.Background_Color " c" This.Top_Color " Range" This.Start_Range "-" This.End_Range  " v" This.Control_ID ,% This.Slider_Value
            else if(This.Smooth=0&&This.Vertical=0)
                Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " -Smooth Range" This.Start_Range "-" This.End_Range  " v" This.Control_ID ,% This.Slider_Value
            else if(This.Smooth=1&&This.Vertical=1)
                Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " Background" This.Background_Color " c" This.Top_Color " Range" This.Start_Range "-" This.End_Range  " Vertical v" This.Control_ID ,% This.Slider_Value
            else if(This.Smooth=0&&This.Vertical=1)
                Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " -Smooth Range" This.Start_Range "-" This.End_Range  " Vertical v" This.Control_ID ,% This.Slider_Value
        }
        Adjust_pSlider(){
            CoordMode,Mouse,Client
            while(GetKeyState("LButton")){
                Static LastTT := 0
                MouseGetPos,pSlider_Temp_X,pSlider_Temp_Y
                if(This.Vertical=0)
                    This.Slider_Value := Round((pSlider_Temp_X - This.X ) / ( This.W / (This.End_Range - This.Start_Range) )) + This.Start_Range
                else
                    This.Slider_Value := Round(((pSlider_Temp_Y - This.Y ) / ( This.H / (This.End_Range - This.Start_Range) )) + This.Start_Range )* -1 + This.End_Range
                if(This.Slider_Value > This.End_Range )
                    This.Slider_Value:=This.End_Range
                else if(This.Slider_Value<This.Start_Range)
                    This.Slider_Value:=This.Start_Range
                GuiControl,% This.GUI_NAME ":" ,% This.Control_ID , % This.Slider_Value 
                if(This.Pair_With_Edit>=1)
                {
                    if(This.Pair_With_Edit<=2)
                    GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID , % This.Slider_Value 
                    if(This.Pair_With_Edit>=2)
                    GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID_Hex , % Format("{1:02X}",This.Slider_Value)
                }
                if(This.Add_Method!=0)
                {
                    
                    GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID_Hex , % Format("{1:02X}",This.Slider_Value)
                }
                if(This.Use_Tooltip=1 && A_TickCount - LastTT > 100 )
                {
                    LastTT := A_TickCount
                    ToolTip , % This.Slider_Value 
                }
            }
            if(This.Use_Tooltip=1)
                ToolTip,
        }
        SET_pSlider(NEW_pSlider_Value){
            This.Slider_Value := NEW_pSlider_Value
            GuiControl,% This.GUI_NAME ":" ,% This.Control_ID , % This.Slider_Value
            if(This.Pair_With_Edit>=1)
            {
                if(This.Pair_With_Edit<=2)
                GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID , % This.Slider_Value 
                if(This.Pair_With_Edit>=2)
                GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID_Hex , % Format("{1:02X}",This.Slider_Value)
            }
        }
    }

[Hellbent]

@thebbandit

Do you have a working example / sample of using your class?

[thebbandit]

Your right, I did some modifications for my own script since the testbench I built it in. Ahh I found the difference, in this testbench I was trying out inserting into another window as a parent. Its kinda strange. Thats why there is that empty "" in the third parameter. Here is the unaltered base to use as an example:

BaseCode

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
#SingleInstance, Force
global ColorPicker_Group_Color, ColorPicker_Group_Color_Hex
	, ColorPicker_Red, ColorPicker_Red_Edit, ColorPicker_Red_Edit_Hex
	, ColorPicker_Green , ColorPicker_Green_Edit, ColorPicker_Green_Edit_Hex
	, ColorPicker_Blue , ColorPicker_Blue_Edit, ColorPicker_Blue_Edit_Hex
Global Picker := New ColorPicker("ColorPicker","ColorPicker","",10,30,90,200,120,0xF0F0F0)

return
ColorGuiClose:
ColorGuiContextMenu:
	ExitApp

class ColorPicker {
	__New(pGroup_GUI_NAME:="ColorPicker", pGroup_ID:="ColorPicker" , pGroup_Parent:="" , pGroup_X:=10 , pGroup_Y:=30 , pGroup_W:=90 , pGroup_H:=280, pGroup_SideBar:=110, pGroup_Start_Color:="000000"){
		This.GUI_NAME := pGroup_GUI_NAME
		This.ID := pGroup_ID
		This.X := pGroup_X
		This.Y := pGroup_Y
		This.W := pGroup_W
		This.H := pGroup_H
		This.SideBar := pGroup_SideBar
		This.Spacing := This.W // 2.5
		This.W_Bar := This.W // 4
		This.Start_Color := pGroup_Start_Color
		This.Start_Red := (0xff0000 & pGroup_Start_Color) >> 16
		This.Start_Green := (0x00ff00 & pGroup_Start_Color) >> 8
		This.Start_Blue := 0x0000ff & pGroup_Start_Color
		This.Parent := pGroup_Parent

		Gui,% This.GUI_NAME ":Destroy"
		Gui,% This.GUI_NAME ":+AlwaysOnTop -DPIScale +ToolWindow" (This.Parent!="" ? " +parent" This.Parent : "")
		Gui,% This.GUI_NAME ":Color",000000
		Gui,% This.GUI_NAME ":Font",s10 w600

		Edit_Trigger := This.UpdateColor.BIND( THIS ) 

		Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X - 9 " y" This.Y - 18 " w40 h17 -E0x200 Center Disabled v" This.ID "_Red_Edit_Hex" ,% Format("{1:02X}",This.Start_Red)
		This.Slider_Red := New Progress_Slider(This.GUI_NAME,This.ID "_Red",This.X ,This.Y,This.W_Bar,This.H,0,255,This.Start_Red,"550000","BB0000",2,This.ID "_Red_Edit",0,1)
		Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X - 10 " y" This.Y + This.H + 2 " w40 h17 -E0x200 Center Disabled v" This.ID "_Red_Edit hwndRedTriggerhwnd",% This.Start_Red
		GUICONTROL +G , %RedTriggerhwnd% , % Edit_Trigger

		Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X - 9 + This.Spacing " y" This.Y - 18 " w40 h17 -E0x200 Center Disabled v" This.ID "_Green_Edit_Hex" ,% Format("{1:02X}",This.Start_Green)
		This.Slider_Green := New Progress_Slider(This.GUI_NAME,This.ID "_Green",This.X + This.Spacing,This.Y,This.W_Bar,This.H,0,255,This.Start_Green,"005500","00BB00",2,This.ID "_Green_Edit",0,1)
		Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X - 10 + This.Spacing " y" This.Y + This.H + 2 " w40 h17 -E0x200 Center Disabled v" This.ID "_Green_Edit hwndGreenTriggerhwnd" ,% This.Start_Green
		GUICONTROL +G , %GreenTriggerhwnd% , % Edit_Trigger


		Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X - 9 + This.Spacing * 2 " y" This.Y - 18 " w40 h17 -E0x200 Center Disabled v" This.ID "_Blue_Edit_Hex" ,% Format("{1:02X}",This.Start_Blue)
		This.Slider_Blue := New Progress_Slider(This.GUI_NAME,This.ID "_Blue",This.X + This.Spacing*2,This.Y,This.W_Bar,This.H,0,255,This.Start_Blue,"000055","0000BB",2,This.ID "_Blue_Edit",0,1)
		Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X - 10 + This.Spacing * 2 " y" This.Y + This.H + 2 " w40 h17 -E0x200 Center Disabled v" This.ID "_Blue_Edit hwndBlueTriggerhwnd" ,% This.Start_Blue
		GUICONTROL +G , %BlueTriggerhwnd% , % Edit_Trigger


		Gui,% This.GUI_NAME ":Font",s15 w600
		Gui,% This.GUI_NAME ":Add",Edit,% "x" This.X + This.Spacing * 3 " y" This.Y - 22 " w" This.SideBar "h17 -E0x200 Center Disabled v" This.ID "_Group_Color_Hex" ,% Format("0x{1:06X}",This.Start_Color)
	
		Gui,% This.GUI_NAME ":Font",s20 w600 c777777
		Gui,% This.GUI_NAME ":Add",Text,% "x" This.X + This.Spacing * 3 " y" This.Y " w" This.SideBar " h" This.H " hwndCopyTriggerhwnd center", `n`n`n`nCopy`nColor
		Gui,% This.GUI_NAME ":Add",Progress,% "x" This.X + This.Spacing * 3 " y" This.Y " w" This.SideBar " h" This.H // 2 + 20 " Background000000 c" Format("{1:06X}",This.Start_Color) " v" This.ID "_Group_Color", 100


		Copy_Trigger := This.CopyColor.BIND( THIS ) 
		GUICONTROL +G , %CopyTriggerhwnd% , % Copy_Trigger

		Gui,% This.GUI_NAME ":Show", AutoSize , Color Picker

	}
	UpdateColor(){
		GuiControl, % This.GUI_NAME ": +c" Format("{1:02X}",This.Slider_Red.Slider_Value) Format("{1:02X}",This.Slider_Green.Slider_Value) Format("{1:02X}",This.Slider_Blue.Slider_Value), % This.ID "_Group_Color",
		GuiControl, % This.GUI_NAME ":", % This.ID "_Group_Color_Hex", % "0x" Format("{1:02X}",This.Slider_Red.Slider_Value) Format("{1:02X}",This.Slider_Green.Slider_Value) Format("{1:02X}",This.Slider_Blue.Slider_Value)
	}
	CopyColor(){
		Clipboard := "0x" Format("{1:02X}",This.Slider_Red.Slider_Value) Format("{1:02X}",This.Slider_Green.Slider_Value) Format("{1:02X}",This.Slider_Blue.Slider_Value)
		; MsgBox, 262144, Color Copied, The Hex color code has been copied to the Clipboard `n`n %Clipboard%
		Tooltip, Copied To Clipboard
		Sleep, 500
		Tooltip,
	}
}

class Progress_Slider	{
	__New(pSlider_GUI_NAME , pSlider_Control_ID , pSlider_X , pSlider_Y , pSlider_W , pSlider_H , pSlider_Range_Start , pSlider_Range_End , pSlider_Value:=0 , pSlider_Background_Color := "Black" , pSlider_Top_Color := "Red" , pSlider_Pair_With_Edit := 0 , pSlider_Paired_Edit_ID := "" , pSlider_Use_Tooltip := 0 ,  pSlider_Vertical := 0 , pSlider_Smooth := 1){
		This.GUI_NAME:=pSlider_GUI_NAME
		This.Control_ID:=pSlider_Control_ID
		This.X := pSlider_X
		This.Y := pSlider_Y
		This.W := pSlider_W
		This.H := pSlider_H
		This.Start_Range := pSlider_Range_Start
		This.End_Range := pSlider_Range_End
		This.Slider_Value := pSlider_Value
		This.Background_Color := pSlider_Background_Color
		This.Top_Color := pSlider_Top_Color
		This.Vertical := pSlider_Vertical
		This.Smooth := pSlider_Smooth
		This.Pair_With_Edit := pSlider_Pair_With_Edit
			; Options
			; 0 := Do not pair with edit
			; 1 := Pair with only Decimal Edit
			; 2 := Pair with both Decimal and Hex Edit
			; 3 := Pair with only Hex Edit
		This.Paired_Edit_ID := pSlider_Paired_Edit_ID
		This.Paired_Edit_ID_Hex := (pSlider_Paired_Edit_ID != "" ? pSlider_Paired_Edit_ID . "_Hex" : "")
		This.Use_Tooltip := pSlider_Use_Tooltip
		This.Add_pSlider()
	}
	Add_pSlider(){
		Gui, % This.GUI_NAME ":Add" , Text , % "x" This.X " y" This.Y " w" This.W " h" This.H " hwndpSliderTriggerhwnd"
		pSlider_Trigger := This.Adjust_pSlider.BIND( THIS ) 
		GUICONTROL +G , %pSliderTriggerhwnd% , % pSlider_Trigger
		if(This.Smooth=1&&This.Vertical=0)
			Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " Background" This.Background_Color " c" This.Top_Color " Range" This.Start_Range "-" This.End_Range  " v" This.Control_ID ,% This.Slider_Value
		else if(This.Smooth=0&&This.Vertical=0)
			Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " -Smooth Range" This.Start_Range "-" This.End_Range  " v" This.Control_ID ,% This.Slider_Value
		else if(This.Smooth=1&&This.Vertical=1)
			Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " Background" This.Background_Color " c" This.Top_Color " Range" This.Start_Range "-" This.End_Range  " Vertical v" This.Control_ID ,% This.Slider_Value
		else if(This.Smooth=0&&This.Vertical=1)
			Gui, % This.GUI_NAME ":Add" , Progress , % "x" This.X " y" This.Y " w" This.W " h" This.H " -Smooth Range" This.Start_Range "-" This.End_Range  " Vertical v" This.Control_ID ,% This.Slider_Value
	}
	Adjust_pSlider(){
		CoordMode,Mouse,Client
		while(GetKeyState("LButton")){
			Static LastTT := 0
			MouseGetPos,pSlider_Temp_X,pSlider_Temp_Y
			if(This.Vertical=0)
				This.Slider_Value := Round((pSlider_Temp_X - This.X ) / ( This.W / (This.End_Range - This.Start_Range) )) + This.Start_Range
			else
				This.Slider_Value := Round(((pSlider_Temp_Y - This.Y ) / ( This.H / (This.End_Range - This.Start_Range) )) + This.Start_Range )* -1 + This.End_Range
			if(This.Slider_Value > This.End_Range )
				This.Slider_Value:=This.End_Range
			else if(This.Slider_Value<This.Start_Range)
				This.Slider_Value:=This.Start_Range
			GuiControl,% This.GUI_NAME ":" ,% This.Control_ID , % This.Slider_Value 
			if(This.Pair_With_Edit>=1)
			{
				if(This.Pair_With_Edit<=2)
				GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID , % This.Slider_Value 
				if(This.Pair_With_Edit>=2)
				GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID_Hex , % Format("{1:02X}",This.Slider_Value)
			}
			if(This.Add_Method!=0)
			{
				
				GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID_Hex , % Format("{1:02X}",This.Slider_Value)
			}
			if(This.Use_Tooltip=1 && A_TickCount - LastTT > 100 )
			{
				LastTT := A_TickCount
				ToolTip , % This.Slider_Value 
			}
		}
		if(This.Use_Tooltip=1)
			ToolTip,
	}
	SET_pSlider(NEW_pSlider_Value){
		This.Slider_Value := NEW_pSlider_Value
		GuiControl,% This.GUI_NAME ":" ,% This.Control_ID , % This.Slider_Value
		if(This.Pair_With_Edit>=1)
		{
			if(This.Pair_With_Edit<=2)
			GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID , % This.Slider_Value 
			if(This.Pair_With_Edit>=2)
			GuiControl,% This.GUI_NAME ":" ,% This.Paired_Edit_ID_Hex , % Format("{1:02X}",This.Slider_Value)
		}
	}
}

Here is what the testbench looks like


And this is what I ended up with within the GUI it was for:

[sasee_sw]

Hay, thank you for your materials. ❤ I want to know how to get an updated value get and save it as a global variable. thank you.

[Hellbent]

Hay, thank you for your materials. ❤ I want to know how to get an updated value get and save it as a global variable. thank you.

Hi sasee_sw. Welcome to the ahk forum.

You can get the current value of the slider by looking at the Slider_Value key of your slider object ( the name you give your slider ).

Here is a simple example of getting and setting the value of the slider. See the F1 and F2 hotkeys to see how to get and set your values.

.

pSlider.gif (378.23 KiB) Viewed 895 times

.

Code: Select all

#Include pSliders.ahk ;<---- Assumes that the class is in another file. (you can paste the class in this script as well)

#SingleInstance, Force

global Demo_Slider_1 ;The name to use for the progress control 
global DS1Edit ;The edit control that displays the slider value
global MySlider ;The name of your slider object.

Gui,1:+AlwaysOnTop -DPIScale

Gui,1:Add,Edit,x125 y15 w50 h17 -E0x200 Center Disabled vDS1Edit , 5
MySlider := New Progress_Slider( "1" , "Demo_Slider_1" , 30 , 35 , 240 , 20 , 0 , 255 , 5 , "D18F0B" , "FFFF00" , 1 , "DS1Edit" , 1 )

Gui,1:Margin, , 30
Gui,1:Show, w300 , pSlider Demo 

return
GuiClose:
GuiContextMenu:
*ESC::ExitApp

F1:: ;Get the slider value
	Gui, 1:+OwnDialogs
	MsgBox, % "Slider 1 Value: " MySlider.Slider_Value 
	Return

F2:: ;Set the slider value
	MySlider.SET_pSlider( 122 )
	Gui, 1:+OwnDialogs
	MsgBox, The value of the slider has been set to 122
	return