HotKey Launcher - By YoucefHam

[YoucefHam]

HotKey Launcher - By YoucefHam

Hello,

It's Just to save a HotKey To run something, enjoy.

feel free to optimize it.



Code Updated [12/06/2019 17:08:15]

HotKey Launcher - By YoucefHam.AHK

Code: Select all

if Not A_IsAdmin AND A_OSVersion <> WIN_XP
{
	Run *RunAs "%A_ScriptFullPath%"
	ExitApp
}
#NoEnv
#MaxHotkeysPerInterval 99000000
#HotkeyInterval 99000000
#KeyHistory 0
#SingleInstance Force
SetWorkingDir %A_ScriptDir%
ListLines Off
Process, Priority, , A
SetBatchLines, -1
SetKeyDelay, -1, -1
SetMouseDelay, -1
SetDefaultMouseSpeed, 0
SetWinDelay, -1
SetControlDelay, -1
SendMode Input

IfNotExist, Saved File.INI
	MiniW("","")
else
{
	IniRead, var, % "Saved File.INI"
	IfNotInString, Var, KeyList
		MiniW("","")
}

Menu, Tray, NoStandard
Menu, Tray, Add, Show/Hide, Show_Hide
Menu, Tray, Default, Show/Hide
Menu, Tray, Click, 1
Menu, Tray, Add
Menu, Tray, Add, Reload, Reload
Menu, Tray, Add
Menu, Tray, Add, Exit, Exit_Func


Gui, Font, s8 bold
Gui, Add, Text, x10 y10 cBlue, % "Key :"
Gui, Add, Hotkey, x+5 y5 w425 vKey
Gui, Add, Button, x10 y+10 w460 gSetFileDir, Brows
Gui, Add, Text, x10 y+10 cBlue, % "File : "
Gui, Add, Edit, x+2 y+-18 w425 r1 vFile 
Gui, Add, Button, x10 w460 gSave, SAVE
Gui, Add, Button, x10 y+5 w460 gDeleteRow, DELETE
Gui, Font, s10 bold underline
Gui, Add, Text, % "x10 y+10 cBlue", Saved Files :
Gui, Font, s8 norm
Gui, Font, norm bold
Gui, Add, ListView, x10 y+5 r20 w460 -LV0x10 -Multi vSavedFileList gSelectKey AltSubmit, File|HotKey
LV_ModifyCol(1, "330 Text")  ; For sorting purposes, indicate that column 2 is an integer.
LV_ModifyCol(2, "125 Text")  ; For sorting purposes, indicate that column 2 is an integer.
MiniGet()
Title := "HotKey Launcher - By YoucefHam"
Gui, show,, % Title
Gui, +LastFound -Theme -MinimizeBox
return


SelectKey:
Gui, Submit, NoHide
if (LV_GetCount("Selected") = 0)
	LastItemSelected := ""
else if (A_GuiEvent = "Normal") and !(A_EventInfo = 0) and (LV_GetCount("Selected") = 1)
	LastItemSelected := A_EventInfo
;~ else if (A_GuiEvent = "DoubleClick") and !(A_EventInfo = 0) and (LV_GetCount("Selected") = 1)
	;~ goto, DeleteRow
return

SetFileDir:
FileSelectFile, SelectedFile, 3, , Open a file, All Files (*.*)
if SelectedFile
	GuiControl,, File, % SelectedFile
return

SAVE:
Gui, Submit, NoHide
if (Key = "") or (File = "")
	return
if !(MiniR(,Key) = "Error") or !(MiniR(,(RegExMatch(Key,"[\^\!\+]") ? RegExReplace(Key,"([\^\!\+]+)(.*?)$","$1~$2") : "*~" Key)) = "Error") or !(MiniR(,"*~" Key) = "Error") or !(MiniR(,"*$" Key) = "Error")
{
	MsgBox, 4144, , HotKey Exist, 1.5
	return
}
MsgBox, 4148, Block Key Input, You want to Block Key Input (*$)
IfMsgBox, Yes
	Key := (RegExMatch(Key,"[\^\!\+]") ? Key : "*$" Key)
else
	Key := (RegExMatch(Key,"[\^\!\+]") ? RegExReplace(Key,"([\^\!\+]+)(.*?)$","$1~$2") : "*~" Key)
LV_Add("","""" File """",Key)
MiniW("""" File """",Key)
Hotkey, % key, on, UseErrorLevel
Hotkey, % key, _Hotkey
return

_Hotkey:
Run, % MiniR(,A_ThisHotkey)
return

DeleteRow:
Gui, Submit, NoHide
if (!LastItemSelected) and (LV_GetCount("Selected") = 0)
	return
MsgBox, 4148, Delete Key, Are you sure to Delete!!!
IfMsgBox, Yes
{
	LV_GetText(Key,LastItemSelected,2)
	Hotkey, % key, Off
	LV_Delete(LastItemSelected)
	MiniD(Key)
}
return

GuiClose:
ExitApp
return

Show_Hide:
IfWinNotExist,  % Title
	WinShow,  % Title
else
	WinHide,  % Title
return

Reload:
Reload
return

Exit_Func:
ExitApp

MiniGet() {
	global
	IfExist, Saved File.INI
		Loop, Parse, % MiniR("Saved File"), `n
		{
			IfInString, A_LoopField, [
				continue
			else IfInString, A_LoopField, =
			Loop, Parse, % A_LoopField, =
			{
				if A_Index = 1
					Key := A_LoopField
				if A_Index = 2
					File := A_LoopField
				Hotkey, % key, _Hotkey
			}
			LV_Add("", File, Key)
		}
	return
}
MiniW(value,Key) {
	global
	IniWrite, %value%, % "Saved File.INI", % "KeyList", %Key%
	return
}
MiniR(var = "var",Key="") {
	global
	IniRead, var, % "Saved File.INI", % "KeyList", %Key%, % ""
	return % ((var == "Error") ? "Error" : var)
}
MiniD(Key) {
	global
	IniDelete, % "Saved File.INI", % "KeyList", %Key%
	return
}

[Ridwan]

Ctrl + Backspace isn't supported?
And it always say "Hotkey Exist".

[YoucefHam]

Ctrl + Backspace isn't supported?
And it always say "Hotkey Exist".

Thank you
Code Updated [12/06/2019 17:08:15]

[elModo7]

Wow, super easy to use!
Thanks for sharing

[pgeugene]

Seem like I can't use "Windows" key [#] as hot key

[pgeugene]

Seem like I can't use "Windows" key [#] as hot key

[toinetteper]

Yea, probably because it's special key and windows is overriding it for their shortcuts.