SavePicture() : Save hBitmap as BMP, JPG, GIF, PNG, TIF

[SKAN]

SavePicture( hBM, sFile )

Note: This function offers limited functionality: JPEG quality is fixed at 75% and transparency will not be preserved for PNG.
Saved file will be a BMP if you pass any file extension other than: BMP, JPG, JPEG, GIF, PNG, TIF, TIFF

Code: Select all

SavePicture(hBM, sFile) {                                            ; By SKAN on D293 @ bit.ly/2krOIc9
Local V,  pBM := VarSetCapacity(V,16,0)>>8,  Ext := LTrim(SubStr(sFile,-3),"."),  E := [0,0,0,0]
Local Enc := 0x557CF400 | Round({"bmp":0, "jpg":1,"jpeg":1,"gif":2,"tif":5,"tiff":5,"png":6}[Ext])
  E[1] := DllCall("gdi32\GetObjectType", "Ptr",hBM ) <> 7
  E[2] := E[1] ? 0 : DllCall("gdiplus\GdipCreateBitmapFromHBITMAP", "Ptr",hBM, "UInt",0, "PtrP",pBM)
  NumPut(0x2EF31EF8,NumPut(0x0000739A,NumPut(0x11D31A04,NumPut(Enc+0,V,"UInt"),"UInt"),"UInt"),"UInt")
  E[3] := pBM ? DllCall("gdiplus\GdipSaveImageToFile", "Ptr",pBM, "WStr",sFile, "Ptr",&V, "UInt",0) : 1
  E[4] := pBM ? DllCall("gdiplus\GdipDisposeImage", "Ptr",pBM) : 1
Return E[1] ? 0 : E[2] ? -1 : E[3] ? -2 : E[4] ? -3 : 1  
}

• ErrorLevel

  The function returns following values as result:
  

  1 : OK
  0 : Invalid hBitmap
  -1 : GDI+ not initialised. Call GDIP("Startup") to init.
  -2 : Invalid (save) filepath or no write access to destination path.
  -3 : GdipDisposeImage() failed. Less likely to occur.

SavePicture() requires GDI+ initialized prior to calling it.
GDI+ can be Start.Shut with GDIP("Startup") and GDIP("Shutdown")
Thanks to @tmplinshi for a bug report. Now fixed.

Code: Select all

GDIP(C:="Startup") {                                      ; By SKAN on D293 @ bit.ly/2krOIc9
  Static SI:=Chr(!(VarSetCapacity(Si,24,0)>>16)), pToken:=0, hMod:=0, Res:=0, AOK:=0
  If (AOK := (C="Startup" and pToken=0) Or (C<>"Startup" and pToken<>0))  {
      If (C="Startup") {
               hMod := DllCall("LoadLibrary", "Str","gdiplus.dll", "Ptr")
               Res  := DllCall("gdiplus\GdiplusStartup", "PtrP",pToken, "Ptr",&SI, "UInt",0)
      } Else { 
               Res  := DllCall("gdiplus\GdiplusShutdown", "Ptr",pToken)
               DllCall("FreeLibrary", "Ptr",hMod),   hMod:=0,   pToken:=0
   }}  
Return (AOK ? !Res : Res:=0)    
}

Usage example

Code: Select all

hBM := LoadPicture(A_AhkPath, "GDI+ Icon1 w512 h512")

GDIP("Startup")
SavePicture(hBM, A_ScriptDir . "\ahk.jpg")
GDIP("Shutdown")

DllCall("DeleteObject", "Ptr", hBM)

Run  % A_ScriptDir . "\ahk.jpg"

The cryptic nested NumPut explained

GdipSaveImageToFile() requires a codec ID for the image type and are as follows:

Code: Select all

ImageCodecBMP  := "{557CF400-1A04-11D3-9A73-0000F81EF32E}"
ImageCodecJPEG := "{557CF401-1A04-11D3-9A73-0000F81EF32E}"
ImageCodecGIF  := "{557CF402-1A04-11D3-9A73-0000F81EF32E}"
ImageCodecEMF  := "{557CF403-1A04-11D3-9A73-0000F81EF32E}"
ImageCodecWMF  := "{557CF404-1A04-11D3-9A73-0000F81EF32E}"
ImageCodecTIFF := "{557CF405-1A04-11D3-9A73-0000F81EF32E}"
ImageCodecPNG  := "{557CF406-1A04-11D3-9A73-0000F81EF32E}"
ImageCodecIcon := "{557CF407-1A04-11D3-9A73-0000F81EF32E}"

I'm breaking the ID to 4 UINTs and encoding them with nested NumPut().
The first UINT is 0x557CF400 for BMP and it increments by 1 for other image types.
The rest of UINTs are same for all image types.
I check the save file path extension and add the appropriated value to this UINT before encoding it.

The following script will automatically Save picture (JPEG) when PrintScreen / Alt+PrintScreen is used for screen capture.

Code: Screen capture demo

Code: Select all

#NoEnv                                                          ; Screen capture demo for SavePicture()
#SingleInstance, Force                
Hotkey,  PrintScreen, Fullscreen
Hotkey, !PrintScreen, ActiveWindow

Return  ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - -    //    end of auto-execute section 

ActiveWindow:
Fullscreen:

  Critical, On
  hBM := 0
  HotKey, %A_ThisHotKey%, Off
  OldClipboard := ClipboardAll
  Clipboard := ""
  SendInput, % (A_ThisLabel="ActiveWindow" ? "!" : "") . "{PrintScreen}"
  ClipWait, 1, 1
  hBM := CB_hBMP_Get()  
  If (OldClipboard)
    {
        Clipboard := OldClipboard
    }
  Critical, Off

  If ( hBM )
    {
       sFile := A_ScriptDir "\\" A_Now ".jpg"
       GDIP("Startup")
       SavePicture(hBM, sFile) 
       GDIP("Shutdown")
       DllCall( "DeleteObject", "Ptr",hBM )
       If FileExist(sFile)
        {
          SoundBeep
          Run %sFile%
        }     
    }       
  HotKey, %A_ThisHotKey%, On
Return

; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 

CB_hBMP_Get() {                                                      ; By SKAN on D297 @ bit.ly/2L81pmP
Local OK := [0,0,0,0]
	OK.1 := DllCall( "OpenClipboard", "Ptr",0 )
  OK.2 := OK.1 ? DllCall( "IsClipboardFormatAvailable", "UInt",8 ) : 0  ; CF_BITMAP
  OK.3 := OK.2 ? DllCall( "GetClipboardData", "UInt", 2, "Ptr" )   : 0
  OK.4 := OK.1 ? DllCall( "CloseClipboard" ) : 0  
Return OK.3 ? DllCall( "CopyImage", "Ptr",OK.3, "Int",0, "Int",0, "Int",0, "UInt",0x200C, "Ptr" )
          + ( ErrorLevel := 0 ) : ( ErrorLevel := !OK.2 ? 1 : 2 ) >> 2          
}

; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

SavePicture(hBM, sFile) {                                            ; By SKAN on D293 @ bit.ly/2L81pmP 
Local V,  pBM := VarSetCapacity(V,16,0)>>8,  Ext := LTrim(SubStr(sFile,-3),"."),  E := [0,0,0,0]
Local Enc := 0x557CF400 | Round({"bmp":0, "jpg":1,"jpeg":1,"gif":2,"tif":5,"tiff":5,"png":6}[Ext])
  E[1] := DllCall("gdi32\GetObjectType", "Ptr",hBM ) <> 7
  E[2] := E[1] ? 0 : DllCall("gdiplus\GdipCreateBitmapFromHBITMAP", "Ptr",hBM, "UInt",0, "PtrP",pBM)
  NumPut(0x2EF31EF8,NumPut(0x0000739A,NumPut(0x11D31A04,NumPut(Enc+0,V,"UInt"),"UInt"),"UInt"),"UInt")
  E[3] := pBM ? DllCall("gdiplus\GdipSaveImageToFile", "Ptr",pBM, "WStr",sFile, "Ptr",&V, "UInt",0) : 1
  E[4] := pBM ? DllCall("gdiplus\GdipDisposeImage", "Ptr",pBM) : 1
Return E[1] ? 0 : E[2] ? -1 : E[3] ? -2 : E[4] ? -3 : 1  
} 

; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

GDIP(C:="Startup") {                                                 ; By SKAN on D293 @ bit.ly/2L81pmP
  Static SI:=Chr(!(VarSetCapacity(Si,24,0)>>16)), pToken:=0, hMod:=0, Res:=0, AOK:=0
  If (AOK := (C="Startup" and pToken=0) Or (C<>"Startup" and pToken<>0))  {
      If (C="Startup") {
               hMod := DllCall("LoadLibrary", "Str","gdiplus.dll", "Ptr")
               Res  := DllCall("gdiplus\GdiplusStartup", "PtrP",pToken, "Ptr",&SI, "UInt",0)
      } Else { 
               Res  := DllCall("gdiplus\GdiplusShutdown", "Ptr",pToken )
               DllCall("FreeLibrary", "Ptr",hMod),   hMod:=0,   pToken:=0
   }}  
Return (AOK ? !Res : Res:=0)    
}

; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

[tmplinshi]

Hi, just a bug report for 64-bit AutoHotkey:

The return type of LoadLibrary function should be Ptr, otherwise the calling to FreeLibrary function would be fail.

Code: Select all

MsgBox % DllCall("FreeLibrary", "Ptr",hMod) ? "success" : "fail"

[SKAN]

Thank you @tmplinshi
Fixed.

[danrevella]

Hi,
please excuse for boring, I have look at your tool (and also another in fact this post is replicate over), but I am in search of a script who let me capture and save a full windows who is larger then my desktop: f.e my desktop is 1920*1080 but the window I need to capture is 9400*9200, so if i use PrintScreen or Alt-Printscreen, I obtain an image who only show 1920*1080 instead of 9400*9200.
Does exist a possibility to get the full capture window?
Many thanks

[SKAN]

f.e my desktop is 1920*1080 but the window I need to capture is 9400*9200

I don't understand how this is possible?
If I try to resize a given window to be larger than desktop, the window is resized only to the size of desktop.
For example, with single monitor setup sized 1366x768, I am not able to resize notepad window to 6000x4000 ?!

Code: Select all

#NoEnv
#Warn
#SingleInstance, Force

Run Notepad
Winwait ahk_class Notepad
WinMove,,, 0, 0, 6000, 4000

[danrevella]

It is possible: try this an give any resolution you want to a (resizable) window


; [^ = Ctrl] [+ = Shift] [! = Alt] [# = Win]
;WIN+t hotkey

#t::
WinGet, window, ID, A
InputBox, width, Resize window, Enter width:, , 170, 130
if (width != "")
{
InputBox, height, Resize Window, Enter height:, , 170, 130
}
WinGetTitle, Title, A
MsgBox, The active window is "%Title%".

WinGet, id, , %Title%
Result := DllCall("SetWindowPos", "uint", id, "uint", HWND_TOP, "Int", 0, "Int", 0, "Int", width, "Int", height, "UInt", 0x400)

return

[SKAN]

It is possible: try this an give any resolution you want to a (resizable) window

Thanks. Nice test code. Nitpick: You haven't defined the constant HWND_TOP which should be 0.

Your snippet doesn't work for all apps though. Maybe those apps have message handlers to override the resize.
Works when tested with Notepad and AutoHotkey help. AutoHotkey spy reveals the window size correctly.

I tried resizing AutoHotkey help to 2000x2000 (My screen is 1366x768) and took a snaphot with hBM := hWnd_to_hBmp( WinExist("A") )
and saved it with SavePicture().
The function is unable to blit the title bar correctly, in Windows 7. Yet to try in Windows 10.
Please refer the attachment

[guest3456]

It is possible: try this an give any resolution you want to a (resizable) window


; [^ = Ctrl] [+ = Shift] [! = Alt] [# = Win]
;WIN+t hotkey

#t::
WinGet, window, ID, A
InputBox, width, Resize window, Enter width:, , 170, 130
if (width != "")
{
InputBox, height, Resize Window, Enter height:, , 170, 130
}
WinGetTitle, Title, A
MsgBox, The active window is "%Title%".

WinGet, id, , %Title%
Result := DllCall("SetWindowPos", "uint", id, "uint", HWND_TOP, "Int", 0, "Int", 0, "Int", width, "Int", height, "UInt", 0x400)

return

does not work for me. i tried resizing notepad to 9000 width, and it only resized to approx 4800 width, which spanned my two monitors.

you could try PrintWindow() to get the screenshot

[danrevella]

It is possible: try this an give any resolution you want to a (resizable) window

Thanks. Nice test code. Nitpick: You haven't defined the constant HWND_TOP which should be 0.

Your snippet doesn't work for all apps though. Maybe those apps have message handlers to override the resize.
Works when tested with Notepad and AutoHotkey help. AutoHotkey spy reveals the window size correctly.

I tried resizing AutoHotkey help to 2000x2000 (My screen is 1366x768) and took a snaphot with hBM := hWnd_to_hBmp( WinExist("A") )
and saved it with SavePicture().
The function is unable to blit the title bar correctly, in Windows 7. Yet to try in Windows 10.
Please refer the attachment

As I told you, I'm a total beginner in AHK, so please may you post your example with a full working code (also with the necessary dependences?
Many thanks

[danrevella]

does not work for me. i tried resizing notepad to 9000 width, and it only resized to approx 4800 width, which spanned my two monitors.

you could try PrintWindow() to get the screenshot

As I told I'm a newbie, may you gentle tell me about PrintWindow(), is it a native function, or is it a library, may you be so kind to give me the necessary code?
Thanks

[SKAN]

I have to test this in Windows 10.
I'm leaving city and will be back on Monday.

[danrevella]

you told me:
Thanks. Nice test code. Nitpick: You haven't defined the constant HWND_TOP which should be 0.

So may you give me the correction to my code?
See you next week

[jly]

Hello, SKAN:
I get the thumbnail of a file as an HBitmap, add it to a Picture control, and the background of the picture is transparent.
If I save it as a .png file with SavePicture functtion, the background of the image file is black.
How can I make the background of the saved picture transparent?

In the following two figures, the first is the image of the saved png file,
and the second is the image displayed in the picture control.

[SKAN]

If I save it as a .png file with SavePicture functtion, the background of the image file is black.

Yes. This function is compact and too limited, and I have mentioned it in OP.
If you need to save PNG with transparency, you may have to opt for one of the GDIP variants available in our forum.
Thanks.

[jly]

If I save it as a .png file with SavePicture functtion, the background of the image file is black.

Yes. This function is compact and too limited, and I have mentioned it in OP.
If you need to save PNG with transparency, you may have to opt for one of the GDIP variants available in our forum.
Thanks.

OK,thank you very much！