AutoHotkey Community

Posted: **26 Apr 2015, 04:39**

After reading this thread, the linked script by maestrith, the COM example by sinkfaze, and the MSDN docs about the Windows Image Acquisition Automation Layer i found that the ImageFile object combined with ImageProcess object provide a set of easy-to-use methods to manipulate images. I didn't find other threads about this topic in both forums. So I wrote this little WIA lib. All functions won't overwrite passed objects. Also, the lib doesn't support multiple frames as yet, but I think it could be added.

Change History:

Public Function List:

I don't know whether all functions will work properly on Win XP because I cannot test here.

Lib WIA.ahk:

Code: Select all

; ======================================================================================================================
; WIA - Windows Image Acquisition Automation Layer -> msdn.microsoft.com/en-us/library/ms630827(v=vs.85).aspx
; Function:       Functions for images.
; Namespace:      WIA
; Tested with:    AHK 1.1.22.00 (A32/U32/U64)
; Tested on:      Win 8.1 (x64)
; Changelog:
;     1.0.02.00/2015-05-03/just me     - added WIA_CreateImage()
;     1.0.01.00/2015-04-27/just me     - fixed WIA_ScaleImage() preserve-aspect-ratio handling
;     1.0.00.00/2015-04-26/just me     - initial release
; Credits:
;     maestrith   for Crop.ahk (-> http://www.autohotkey.net/~maestrith/crop/Crop.ahk)
;     sinkfaze    for his COM example (-> http://ahkscript.org/boards/viewtopic.php?f=6&t=77&p=619)
; License:
;     The Unlicense (http://unlicense.org/)
; ======================================================================================================================
; Common function parameters (not mentioned below):
;     ImgObj      -  ImageFile object returned by WIA_LoadImage().
; Common return values (except noted below):
;     A new ImageFile object on success, otherwise False.
; ======================================================================================================================
; Creates a new image.
; Parameters:
;     Px...       -  Number of pixels for the corresponding dimension.
;     ARGBData    -  Array of ARGB color data, one per pixel, to put into the image. The data will be used to create
;                    exactly PxWidth * PxHeight pixels. The alpha value will be ignored.
; ======================================================================================================================
WIA_CreateImage(PxWidth, PxHeight, ARGBData) {
   If !WIA_IsInteger(PxWidth, PxHeight) || !WIA_IsPositive(PxWidth, PxHeight)
      Return False
   DataCount := PxWidth * PxHeight
   Vector := ComObjCreate("WIA.Vector")
   I := 1
   Loop
      For Each, ARGB In ARGBData
         Vector.Add(ComObject(0x3, ARGB))
      Until (++I > DataCount)
   Until (I > DataCount)
   Return Vector.ImageFile(PxWidth, PxHeight)
}
; ======================================================================================================================
; Converts an image into the specified format.
; Parameters:
;     NewFormat   -  New format as one of the string keys of FormatID.
;     Quality     -  Quality used for JPEG compression (1 - 100).
;     Compression -  Compression method used for TIFF compression as one of the string keys of Comp.
; Note:
;     The function also sets the FileExtension property of the new ImageFile object according to the new format.
; ======================================================================================================================
WIA_ConvertImage(ImgObj, NewFormat, Quality := 100, Compression := "LZW") {
   Static FormatID := {BMP: "{B96B3CAB-0728-11D3-9D7B-0000F81EF32E}"
                     , JPEG: "{B96B3CAE-0728-11D3-9D7B-0000F81EF32E}"
                     , GIF: "{B96B3CB0-0728-11D3-9D7B-0000F81EF32E}"
                     , PNG: "{B96B3CAF-0728-11D3-9D7B-0000F81EF32E}"
                     , TIFF: "{B96B3CB1-0728-11D3-9D7B-0000F81EF32E}"}
   Static Comp := {CCITT3: 1, CCITT4: 1, LZW: 1, RLE: 1, Uncompressed: 1}
   If (ComObjType(ImgObj, "Name") <> "IImageFile")
      Return False
   If ((NewFormat := FormatID[NewFormat]) = "")
      Return False
   If Quality Not Between 1 And 100
      Return False
   If (Comp[Compression] = "")
      Return False
   ImgProc := WIA_ImageProcess()
   ImgProc.Filters.Add(ImgProc.FilterInfos("Convert").FilterID)
   ImgProc.Filters[1].Properties("FormatID") := NewFormat
   ImgProc.Filters[1].Properties("Quality") := Quality
   ImgProc.Filters[1].Properties("Compression") := Compression
   Return ImgProc.Apply(ImgObj)
}
; ======================================================================================================================
; Crops an image.
; Parameters:
;     Px...       -  Number of pixels to crop at the corresponding edge.
; ======================================================================================================================
WIA_CropImage(ImgObj, PxLeft, PxTop, PxRight, PxBottom) {
   If (ComObjType(ImgObj, "Name") <> "IImageFile")
      Return False
   If !WIA_IsInteger(PxLeft, PxTop, PxRight, PxBottom) || !WIA_IsPositive(PxLeft, PxTop, PxRight, PxBottom)
      Return False
   If ((ImgObj.Width - PxLeft - PxRight) < 0) || ((ImgObj.Height - PxTop - PxBottom) < 0)
      Return False
   ImgProc := WIA_ImageProcess()
   ImgProc.Filters.Add(ImgProc.FilterInfos("Crop").FilterID)
   ImgProc.Filters[1].Properties("Left") := PxLeft
   ImgProc.Filters[1].Properties("Top") := PxTop
   ImgProc.Filters[1].Properties("Right") := PxRight
   ImgProc.Filters[1].Properties("Bottom") := PxBottom
   Return ImgProc.Apply(ImgObj)
}
; ======================================================================================================================
; Retrieves descriptions of all available filters or the specified filter.
; Might be useful to provide help informations.
; Parameters:
;     FilterName  -  Filter name, omit the parameter or pass an empty string to get the descriptions of all available
;                    filters.
; Return values:
;     A string containing the filter name(s), ID(s), and description(s) on success, otherwise an empty string.
; ======================================================================================================================
WIA_FilterDescriptions(FilterName := "") {
   Static SubTypes := ["Range", "List", "Flag"]
   Static Delimiter := "============================================================"
                     . "========================================`r`n"
   Description := Delimiter
   ImgProc := WIA_ImageProcess()
   For FilterInfo In ImgProc.FilterInfos {
      If (Filtername <> "") {
         If (FilterInfo.Name = FilterName) {
            Description .= FilterInfo.Name . "     (ID: " . FilterInfo.FilterId . ")`r`n`r`n"
                         . FilterInfo.Description . "`r`n" . Delimiter
            Break
         }
      }
      Else
         Description .= FilterInfo.Name . "     (ID: " . FilterInfo.FilterId . ")`r`n`r`n"
                      . FilterInfo.Description . "`r`n" . Delimiter
   }
   Return (Description <> Delimiter ? RTrim(Description) : "")
}
; ======================================================================================================================
; Flips an image.
; Parameters:
;     Mode        -  Flip "Horizontal" or "Vertical"
; ======================================================================================================================
WIA_FlipImage(ImgObj, Mode := "Horizontal") {
   Static Modes := {"Horizontal": 1, "Vertical": 1}
   If !(Modes[Mode]) || (ComObjType(ImgObj, "Name") <> "IImageFile")
      Return False
   ImgProc := WIA_ImageProcess()
   ImgProc.Filters.Add(ImgProc.FilterInfos("RotateFlip").FilterID)
   ImgProc.Filters[1].Properties("Flip" . Mode) := True
   Return ImgProc.Apply(ImgObj)
}
; ======================================================================================================================
; Retrieves the bitmap data of the image.
; Return values:
;     A new Picture object on success, otherwise false.
; Note:
;     To retrieve the HBITMAP handle for the returned object use object.Handle
; ======================================================================================================================
WIA_GetImageBitmap(ImgObj) {
   ; To retrieve the HBITMAP handle for the returned object use object.Handle
   Return (ComObjType(ImgObj, "Name") = "IImageFile") ? ImgObj.Filedata.Picture : False
}
; ======================================================================================================================
; Retrieves the extended properties of the image.
; Parameters:
;     AsString    -  Set to true to get the properties as a string instead of an array.
; Return values:
;     On success: A property string or a property array indexed by the numerical property ID. Each array element
;                 contains an object with the key/value pairs 'Name' and 'Value'.
;     On failure: False
; ======================================================================================================================
WIA_GetImageProperties(ImgObj, AsString := False) {
   If (ComObjType(ImgObj, "Name") <> "IImageFile")
      Return False
   PropObj := []
   For Prop In ImgObj.Properties {
      PropObj[Prop.PropertyID, "Name"] := Prop.Name
      If Prop.IsVector
         Value := "[vector data not emitted]"
      Else If (Prop.Type = 1006) || (Prop.Type = 1007) ; RationalImagePropertyType || UnsignedRationalImagePropertyType
         Value := Prop.Value.Value . " (" . Prop.Value.Numerator . " / " .  Prop.Value.Denominator . ")"
      Else If (Prop.Type = 1002) ; StringImagePropertyType
         Value := """" . Prop.Value . """"
      Else
         Value := Prop.Value
      PropObj[Prop.PropertyID, "Value"] := Value
   }
   If !(AsString)
      Return PropObj
   Else {
      PropString := ""
      For PropID, Prop In PropObj
         PropString .= "ID: " . PropID . " - Name: " . Prop.Name . " - Value: " . Prop.Value . "`r`n"
      Return RTrim(PropString, "`r`n")
   }
}
; ======================================================================================================================
; Loads an image file.
; Parameters:
;     ImgPath     -  Path and name of the image file.
; ======================================================================================================================
WIA_LoadImage(ImgPath) {
   ImgObj := ComObjCreate("WIA.ImageFile")
   ComObjError(0)
   ImgObj.LoadFile(ImgPath)
   ComObjError(1)
   Return A_LastError ? False : ImgObj
}
; ======================================================================================================================
; Rotates an image in steps of 90°.
; Parameters:
;     Mode        -  Direction: "Left" or "Right"
; ======================================================================================================================
WIA_RotateImage(ImgObj, Mode := "Right") {
   Static Modes := {"Left": 270, "Right": 90}
   If !(Mode := Modes[Mode]) || (ComObjType(ImgObj, "Name") <> "IImageFile")
      Return False
   ImgProc := WIA_ImageProcess()
   ImgProc.Filters.Add(ImgProc.FilterInfos("RotateFlip").FilterID)
   ImgProc.Filters[1].Properties("RotationAngle") := Mode
   Return ImgProc.Apply(ImgObj)
}
; ======================================================================================================================
; Saves an image to disk.
; Parameters:
;     ImgPath     -  Path and name of the image file.
; Return values:
;     True on success, otherwise false. The error code is stored in A_LastError.
; Note:
;     The extension of the file name passed in ImgPath must be one of "bmp", "gif", "jpg", "png", or "tif" and match
;     the extension stored in the FileExtension property of the ImageFile object. Otherwise the file won't be stored.
;     Also, the function won't overwrite existing files.
; ======================================================================================================================
WIA_SaveImage(ImgObj, ImgPath) {
   If (ComObjType(ImgObj, "Name") <> "IImageFile")
      Return False
   SplitPath, ImgPath, FileName, FileDir, FileExt
   If (ImgObj.FileExtension <> FileExt)
      Return False
   ComObjError(0)
   ImgObj.SaveFile(ImgPath)
   ComObjError(1)
   Return !A_LastError
}
; ======================================================================================================================
; Scales/resizes an image.
; Parameters:
;     Px...       -  New image width and height in pixels.
; Note:
;     If either PxWidth or PxHeight are zero or negative, the corresponding dimension will be scaled preserving the
;     aspect ratio of the image.
; ======================================================================================================================
WIA_ScaleImage(ImgObj, PxWidth, PxHeight) {
   If (ComObjType(ImgObj, "Name") <> "IImageFile")
      Return False
   If !WIA_IsInteger(PxWidth, PxHeight) || ((PxWidth < 1) && (PxHeight < 1))
      Return False
   KeepRatio := (PxWidth < 1) || (PxHeight < 1) ? True : False
   ImgProc := WIA_ImageProcess()
   ImgProc.Filters.Add(ImgProc.FilterInfos("Scale").FilterID)
   ImgProc.Filters[1].Properties("MaximumWidth") := PxWidth > 0 ? PxWidth : PxHeight
   ImgProc.Filters[1].Properties("MaximumHeight") := PxHeight > 0 ? PxHeight : PxWidth
   ImgProc.Filters[1].Properties("PreserveAspectRatio") := KeepRatio
   Return ImgProc.Apply(ImgObj)
}
; ======================================================================================================================
; Stamps the image passed in StampObj onto the image.
; Parameters:
;     StampObj    -  Image object as returned from one of the WIA functions.
;     Px...       -  Distance to the left/top edge of the image in pixels.
; Note:
;     Both PxLeft or PxTop must be positive. Also, (PxLeft + StampObj.Width) and (PxTop + STampObj.Height) must not
;     exceed the image dimensions.
; ======================================================================================================================
WIA_StampImage(ImgObj, StampObj, PxLeft, PxTop) {
   If (ComObjType(ImgObj, "Name") <> "IImageFile") || (ComObjType(StampObj, "Name") <> "IImageFile")
      Return False
   If ((PxLeft + StampObj.Width) > ImgObj.Width) || ((PxTop + StampObj.Height) > ImgObj.Height)
      Return False
   ImgProc := WIA_ImageProcess()
   ImgProc.Filters.Add(ImgProc.FilterInfos("Stamp").FilterID)
   ImgProc.Filters[1].Properties("ImageFile") := StampObj
   ImgProc.Filters[1].Properties("Left") := PxLeft
   ImgProc.Filters[1].Properties("Top") := PxTop
   Return ImgProc.Apply(ImgObj)
}
; ======================================================================================================================
; For internal use!!!
; ======================================================================================================================
WIA_ImageProcess() {
   Static ImageProcess := ComObjCreate("WIA.ImageProcess")
   While (ImageProcess.Filters.Count)
      ImageProcess.Filters.Remove(1)
   Return ImageProcess
}
; ======================================================================================================================
WIA_IsInteger(Values*) {
   If Values.MaxIndex() = ""
      Return False
   For Each, Value In Values
      If Value Is Not Integer
         Return False
   Return True
}
; ======================================================================================================================
WIA_IsPositive(Values*) {
   If Values.MaxIndex() = ""
      Return False
   For Each, Value In Values
      If (Value < 0)
         Return False
   Return True
}

WIASample.ahk:

Code: Select all

#NoEnv
#Include WIA.ahk
; ======================================================================================================================
CommonProps := ["FileExtension", "FormatID", "Height", "Width", "PixelDepth", "HorizontalResolution",
              , "VerticalResolution", "IsAlphaPixelFormat", "IsAnimated", "IsExtendedPixelFormat"
              , "IsIndexedPixelFormat", "FrameCount", "ActiveFrame"]
PicW := 400 ; width of the Pic controls
; ======================================================================================================================
; ImgPath := A_ScriptDir . "\Test.jpeg"  ; image path
ImgPath := ""
Loop, Files, %A_WinDir%\Web\WallPaper\*.jpg, R
   ImgPath := A_LoopFileLongPath
Until (ImgPath <> "")
If (ImgPath = "") {
   MsgBox, 16, Error, Couldn't find a JPG image file!`n`nThe program will exit.
   ExitApp
}
; Load the image
If !(ImgObj := WIA_LoadImage(ImgPath)) {
   MsgBox, 16, Error, Couldn't load %ImagePath%!`n`nThe program will exit.
   ExitApp
}
; ======================================================================================================================
Menu, Show, Add, Common properties, ShowCommonProps
Menu, Show, Add, Extended properties, ShowExtendedProps
Menu, Menubar, Add, Show, :Show
; ======================================================================================================================
Gui, Menu, Menubar
Gui, Margin, 20, 20
Gui, Color, Black
; Scale the image to a width of PicW pixels and preserve the aspect ratio for the height.
Scaled := WIA_ScaleImage(ImgObj, PicW, 0)
; Get the height
PicH := Scaled.Height
Gui, Add, Text, cWhite, Original scaled to %PicW%x%PicH%:
Gui, Add, Pic, xm y+2 w%PicW% h%PicH% hwndHPIC1 +0x4E
; Get the bitmap data
PicObj := WIA_GetImageBitmap(Scaled)
; Get the HBITMAP handle
HBM := PicObj.Handle
; STM_SETIMAGE message: Set the control's image.
SendMessage, 0x172, 0, %HBM%, , ahk_id %HPIC1%
; Crop 25 percent of the Top, Left, Bottom, and Right of the image.
CropTB := ImgObj.Height // 4
CropLR := ImgObj.Width // 4
Cropped := WIA_CropImage(ImgObj, CropLR, CropTB, CropLR, CropTB)
; Scale the image to a width of PicW pixels and preserve the aspect ratio for the height.
Scaled := WIA_ScaleImage(Cropped, PicW, 0)
; Get the height
PicH := Scaled.Height
Gui, Add, Text, ym cWhite, Cropped scaled to %PicW%x%PicH%:
Gui, Add, Pic, xp y+2 w%PicW% h%PicH% hwndHPIC2 +0x4E
; Get the bitmap data
PicObj := WIA_GetImageBitmap(Scaled)
; Get the HBITMAP handle
HBM := PicObj.Handle
; STM_SETIMAGE message: Set the control's image.
SendMessage, 0x172, 0, %HBM%, , ahk_id %HPIC2%
Gui, Show, AutoSize, %ImgPath%
Return
; ======================================================================================================================
GuiClose:
ExitApp
; ======================================================================================================================
ShowCommonProps:
Properties := ""
For Each, Prop In CommonProps
   Properties .= Prop . " : " . ImgObj[Prop] . "`r`n"
MsgBox, 0, Common Properties, % RTrim(Properties, "`r`n")
Return
; ======================================================================================================================
ShowExtendedProps:
   MsgBox, 0, Extended Properties, % WIA_GetImageProperties(ImbObj)
Return

WIASample_Create.ahk:

WIAFilters.ahk:

This script will show the description of the available filters and their parameters.

Other examples:

License: The Unlicense

Update on 2020-03-06: @robodesign added a WIA_AcquireImage() function.

Update on 2021-03-27: You'll find a link to an extended version of the lib modified by @robodesign here.

Posted: **26 Apr 2015, 15:29**

awesome nice work

Posted: **26 Apr 2015, 15:54**

just me
Nice and useful library. Thank you

Posted: **27 Apr 2015, 10:56**

*Update 1.0.01.00 on 2015-04-27*

Posted: **27 Apr 2015, 14:44**

my XP choked here:
Loop, Files, %A_WinDir%\Web\WallPaper\*.jpg, R

Posted: **28 Apr 2015, 01:23**

This line is part of the sample script and not included in one of the WIA functions. Do you use the latest AHK version? Otherwise you might replace the line with

Code: Select all

Loop, %A_WinDir%\Web\WallPaper\*.jpg, 0, 1

Posted: **28 Apr 2015, 05:01**

I have a similar issue and I use the following version:
AHK Version: 1.1.19.01
Unicode: Yes (32-bit)
Operating System: WIN_XP
Admin Rights: Yes

Posted: **28 Apr 2015, 08:14**

The latest version is 1.1.21.03, otherwise ...

Or you might want to put an image file path manually into ImgPath.

Posted: **16 May 2015, 15:22**

Hi just me,

Congratulations on making an awesome lib!

It took me a while of looking through the msdn before I figured out that your example, WIAFilters.ahk, was the best way to see the filters documentation. It might be useful to note this more prominently so other users look there first.

I appreciate your example here. Maybe you could start a collection of examples or links to examples, similar to what tic did for the Gdip tutorials? I think a collection of useful examples in one place would be good.

Thanks again!

Posted: **17 May 2015, 00:19**

Hi kon,

thanks for your suggestions. Better now?

Posted: **18 May 2015, 12:46**

Thanks

Posted: **07 Nov 2019, 12:10**

Code: Select all

MsgBox % WIA_LoadImage("C:\img.png")

WIA_LoadImage(ImgPath) {
   ImgObj := ComObjCreate("WIA.ImageFile")
   ComObjError(0)
   ImgObj.LoadFile(ImgPath)
   ComObjError(1)
   Return A_LastError ? False : ImgObj
}

returns blank(win10 x64, ahk 1.1.31.1 x64)
is this COM component deleted in windows 10?

Posted: **08 Nov 2019, 11:33**

You might want to search for it in the registry (HKCR).

By the way, the function returns an object reference on success.

Posted: **08 Nov 2019, 12:25**

I have a section, 'COM OBJECT: IMAGES (WIA)', here:

jeeswg's objects tutorial - AutoHotkey Community
https://autohotkey.com/boards/viewtopic.php?f=7&t=29232

One link has install advice, if you need to install it.

Posted: **08 Nov 2019, 13:34**

jeeswg wrote: ↑
08 Nov 2019, 12:25
I have a section, 'COM OBJECT: IMAGES (WIA)', here:

jeeswg's objects tutorial - AutoHotkey Community
https://autohotkey.com/boards/viewtopic.php?f=7&t=29232

One link has install advice, if you need to install it.

There's good advice in the two posts after yours in the thread you linked that would be worth revisiting.

Posted: **08 Nov 2019, 14:12**

nevermind, i thought it returned a pointer for some reason
it does work when u test with IsObject

Posted: **08 Nov 2019, 16:56**

Can it acquire scanner images? It's what it suggests, the name....

Posted: **04 Mar 2020, 07:50**

I managed to implement a working function, for acquiring images from scanners and other devices.

I only tested it with one scanner.

Code: Select all

#include wia.ahk
#include gdip_all.ahk

WIA_AcquireImage() {
   ; returns on success a GDI+ bitmap handle

   wiaDlg := ComObjCreate("WIA.CommonDialog")
   wiaImg := ComObjCreate("WIA.ImageFile")

   dev := wiaDlg.ShowSelectDevice(0, 1)
   If !dev.DeviceID
      Return False

   wiaimg := wiaDlg.ShowAcquireImage(dev.Type)
   PicObj := WIA_GetImageBitmap(wiaImg)
   If (PicObj.Handle)
   {
      pBitmap := Gdip_CreateBitmapFromHBITMAP(PicObj.Handle)
      DeleteObject(PicObj.Handle)
   }

   If StrLen(pBitmap)>3
      Return pBitmap
   Else
      Return False
}

Best regards, Marius.

Posted: **10 Mar 2020, 14:38**

Hi Marius, nice one!
Here's a little mod with a file selection dialog. Needs work, but works just fine for my purposes so far. At the moment all I wanted to do was not leave AHK to grab a single-page scan. Works with a Canano MF-4360 USB and an Epson ES-500W wireless so far.

To do (I know, when pigs fly ...

):
*Multipage
*Image type selection
*Page size selection
*Image scaling
*Convert to PDF
*Add to Excel (scaled)
*Make it look like it was coded by a human
*And so on ...

Code: Select all

#include wia.ahk
#include <GDIP_All>

FileSelectFile, filename, s16, %A_ScriptDir%\default.bmp, Select a BMP to save, Bitmap Files (*.bmp)
SplitPath, filename, OutFileName, , OutExtension, OutNameNoExt
If OutExtension <> ".bmp"
   filename := OutNameNoExt . ".bmp"
else
   filename := filename

WIA_AcquireImage(filename)

Gui, Add, Pic, x0 y0 w695 h900 +0x4E, %filename%
Gui, Show, Autosize, Scanned

return
ExitApp
return

WIA_AcquireImage(filename:="default.bmp") {
   ; returns on success a GDI+ bitmap handle

   wiaDlg := ComObjCreate("WIA.CommonDialog")
   wiaImg := ComObjCreate("WIA.ImageFile")

   wiaimg := wiaDlg.ShowAcquireImage()
   wiaimg.SaveFile(filename)
   PicObj := WIA_GetImageBitmap(wiaImg)
   If (PicObj.Handle)
   {
      pBitmap := Gdip_CreateBitmapFromHBITMAP(PicObj.Handle)
      DeleteObject(PicObj.Handle)
   }

   If StrLen(pBitmap)>3
      Return pBitmap
   Else
      Return False
}

GuiClose:
!Esc::
ExitApp

Regards,
burque505

Posted: **10 Mar 2020, 18:21**

Hey, that's nice!

Glad to hear it's working well.

The function I posted is part of my new "quick picture viewer" version I'm working on. It will also have a complete toolbox for image editing and many optimisations, speed improvements... And multithreading and, and.....

Best regards, Marius.

AutoHotkey Community

WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)

WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)

Re: WIA - Windows Image Acquisition (Automation Layer)

Re: WIA - Windows Image Acquisition (Automation Layer)

Re: WIA - Windows Image Acquisition (2015-04-27)

Re: WIA - Windows Image Acquisition (2015-04-27)

Re: WIA - Windows Image Acquisition (2015-04-27)

Re: WIA - Windows Image Acquisition (2015-04-27)

Re: WIA - Windows Image Acquisition (2015-04-27)

Re: WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)

Re: WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)

Re: WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)

Re: WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)

Re: WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)

Re: WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)

Re: WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)

Re: WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)

Re: WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)

Re: WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)

Re: WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)

Re: WIA - Windows Image Acquisition (1.0.02.00 - 2015-05-03)