WinMoveZ() : Moves, but confines a window to the work area of target monitor

[SKAN]

The function:

Code: Select all

WinMoveZ(hWnd, C, X, Y, W, H, Redraw:=0) { ;  WinMoveZ v0.5 by SKAN on D35V/D361 @ tiny.cc/winmovez 
Local V:=VarSetCapacity(R,48,0), A:=&R+16, S:=&R+24, E:=&R, NR:=&R+32, TPM_WORKAREA:=0x10000
  C:=( C:=Abs(C) ) ? DllCall("SetRect", "Ptr",&R, "Int",X-C, "Int",Y-C, "Int",X+C, "Int",Y+C) : 0
  DllCall("SetRect", "Ptr",&R+16, "Int",X, "Int",Y, "Int",W, "Int",H)
  DllCall("CalculatePopupWindowPosition", "Ptr",A, "Ptr",S, "UInt",TPM_WORKAREA, "Ptr",E, "Ptr",NR)
  X:=NumGet(NR+0,"Int"),  Y:=NumGet(NR+4,"Int")
Return DllCall("MoveWindow", "Ptr",hWnd, "Int",X, "Int",Y, "Int",W, "Int",H, "Int",Redraw)
}

---

WinMoveZ(hWnd, C, X, Y, W, H [, Redraw])
Moves a window like WinMove, but confines the window within the work area of the target monitor.

• What WinMoveZ() will not do? : It will not move a window offscreen
• What WinMoveZ() will do? : Confine a window within the work area of target monitor.
• Which target monitor? : Whichever monitor POINT (X, Y) belongs to
• What if POINT doesn't belong to any monitor? : The monitor nearest to the POINT will house the window.
• Can you explain parameters? : Except second parameter others are passed to MoveWindow which is similar to WinMove
  DllCall("MoveWindow", "Ptr",hWnd, "Int",X, "Int",Y, "Int",W, "Int",H, "Int",Redraw)
• What is the second parameter C required for? : It is like a social distancing (in pixels) to be maintained between cursor hotspot and your POINT (X, Y)
  This parameter should be used only if you're calling WinMoveZ() from a loop/timer, to move a window to follow your mouse. (Try example #2)
  A value of 16 should be good. That is, 16x16 = 256 pixels surrounding the cursor hotspot will be excluded from work area.
• Bordered windows are not moved correctly? : Apparently. I will update the topic if I find my own solution.

• Example #1 : Show a notification at right bottom corner of primary monitor

  Code: Select all

  #SingleInstance, Force
  Gui, New, -Caption +Border +AlwaysOnTop +Disabled +Owner +hWndhWnd
  Gui, Font, s20, Segoe UI
  Gui, Add, Text,, Hello World !
  Gui, Show, Hide
  DetectHiddenWindows, On
  WinGetPos, X, Y, W, H, ahk_id %hWnd%
  WinMoveZ(hWnd, 0, A_ScreenWidth-1, A_ScreenHeight-1, W, H)
  DetectHiddenWindows, Off
  Gui, Show, NA
  Return
  

  
  
• Example #2 : A window follows the mouse while maintaining a 16 pixels distance.

  Code: Select all

  #NoEnv
  #SingleInstance, Force
  CoordMode, Mouse, Screen
  CoordMode, Pixel, Screen
  
  Gui New, -Caption +Border +hWndhWnd +Disabled +AlwaysOnTop
  Gui, Margin, 15, 30
  Gui, Add, Edit, w60 Center, FFFFFF
  Gui, Show
  
  WinGetPos, X, Y, W, H, ahk_id %hWnd%
  PX:=X, PY:=Y
  Loop
  {
    MouseGetPos, X, Y
    If ! (X=PX and Y=PY)                          
      { 
        WinMoveZ(hWnd, 16, X, Y, W, H), PX:=X, PY:=Y
        PixelGetColor, C, %X%, %Y%, RGB
        Gui, Color, % PC:=C
        GuiControl,,Edit1, % Format("{:06X}",C)
      }       
    Sleep 50  
  }
  
  
  F2::Gui +AlwaysOnTop
  Esc:: ExitApp
  

[Cerberus]

This looks very useful! great work. So it says "confine": suppose the window would be placed partly outside the screen, what would happen: Would the window keep the same size but be moved such that it is entirely inside the screen? Or will it be resized at the sides that partly fall outside the window? (I would be really interested in the latter for a script I'm working on.)

[Delta Pythagorean]

With how compact you confine your functions, I'd almost expect you to create a full UI in less than a few lines

[SKAN]

@Cerberus

will it be resized at the sides that partly fall outside the window?

No

Would the window keep the same size but be moved such that it is entirely inside the screen?

Yes. This function is loosely based on the functionality of Tooltip command.
A Tooltip will never go offscreen. for eg: Tooltip, Hello World, % A_ScreenWidth-1, A_ScreenWidth-1
will confine it inside the right bottom of the primary monitor.

Also, if you run the following code on a multi-monitor setup..

Code: Select all

Loop
{
  Tooltip, Hello World
  Sleep 0
}

.. you will notice that the Tooltip is always confined to whichever monitor the mouse cursor is on... without losing its dimensions.
In other words, a Tooltip doesn't seem to span between monitors. It simply jumps over to the monitor the cursor is in.

Thanks for the feedback.

[SKAN]

how compact you confine your functions,

Confine to 11 lines or less.. So that "Expand view" doesn't appear on the [code] box

[SirSocks]

@SKAN you write amazing code! This seems very useful! Thank you so much for sharing your code with the community.
By the way I can't get enough of xstr().

[SKAN]

Thank you @SirSocks

[Cerberus]

Thanks, good to know.

[guest3456]

The function:

Code: Select all

WinMoveZ(hWnd, C, X, Y, W, H, Redraw:=0) { ;  WinMoveZ v0.5 by SKAN on D35V/D361 @ tiny.cc/winmovez 
Local V:=VarSetCapacity(R,48,0), A:=&R+16, S:=&R+24, E:=&R, NR:=&R+32, TPM_WORKAREA:=0x10000
  C:=( C:=Abs(C) ) ? DllCall("SetRect", "Ptr",&R, "Int",X-C, "Int",Y-C, "Int",X+C, "Int",Y+C) : 0
  DllCall("SetRect", "Ptr",&R+16, "Int",X, "Int",Y, "Int",W, "Int",H)
  DllCall("CalculatePopupWindowPosition", "Ptr",A, "Ptr",S, "UInt",TPM_WORKAREA, "Ptr",E, "Ptr",NR)
  X:=NumGet(NR+0,"Int"),  Y:=NumGet(NR+4,"Int")
Return DllCall("MoveWindow", "Ptr",hWnd, "Int",X, "Int",Y, "Int",W, "Int",H, "Int",Redraw)
}

why do you declare the variables with the local keyword, which ends up making the function itself assume-global?

[TAC109]

Not Skan, but it is to avoid possible warnings when #Warn is used in the included script. As all variables are defined either under Local or as parameters to the function, there are no assume-global variables.

Hope this helps.